Cadres des vues reportées en objet

[LI_In4T!C]

Bonjour,

 

aujourd'hui j'ai à créer tout une suite de présentations au 200ème pour un projet linéaire, ce qui représente donc un nombre X de vues. J'aimerai par un moyen relativement précis reporter dans l'espace objet le cadre des présentations au 200ème que je vais créer, afin de bien me rendre compte du chevauchement de mes différentes vues et de leur agencement.

 

Y-a-t-il un moyen de faire cela?

 

Pour le moment je double clique dans ma présentation et trace approximativement un cadre aux dimensions les plus proches possibles de celles de mon cadre de vue. Mais ce n'est guère précis, et je souhaiterai avoir une méthode un peu plus professionnelle...haaa les joies de l'auto formation...

 

Merci à vous. [Edité le 20/12/2007 par LI_In4T!C]

 

EDIT : Bon ben vous dérangez pas M'sieurs Dames, j'ai trouvé par moi même.

 

Je crée donc une présentation A0 (c'est le format que je souhaite), je dispose la fenêtre afin de cadrer au mieux à la zone imprimable. Une fois cette fenêtre faite, je crée dans l'espace papier une polyligne rectangulaire de dimensions similaire, que je divise par 5 ici pour avoir le cadre au 200eme dans mon espace objet. Il ne me reste alors plus qu'à positionner ces rectangles dans l'espace objet de la manière dont je souhaite cadrer mes vues. Puis à effectuer une zoom fenetre sur ces rectangles dans les fenêtres de mes présentations. Je sais pas si je suis très clair mais pour ceux qui chercheraient comment faire à l'avenir, voilà, c'est dit.

 

[Edité le 20/12/2007 par LI_In4T!C]

[Pieroka]

Il y a la commande "modifier l'espace" (mal traduite de l'anglais...) tout en bas du menu modification. Elle permet de passer un objet, un rectangle polyligne par exemple, de l'espace papier à l'espace objet sans changement d'échelle et inversement.

 

Tu peux également créer une une série de fenêtres qui se suivent. crée ta 1ere fenêtre en papier de ton premier tronçon, puis étires une des poignées vers la droite par exemple et en CRTL+cliquant la fenêtre étirée tu en fais une nouvelle qui colle parfaitement à la première, elles ont un côté commun.

 

 

première fenêtre :

http://shup.com/Shup/15285/1fenetreoz3.png

 

 

Etirer poignée+crtl clic pour créer une fenêtre contigüe à la première.

http://shup.com/Shup/15286/2fenetreij6.png

 

 

et hop :

http://shup.com/Shup/15287/3fenetreiq1.png

[Matt666]

Salut !

 

Pieroka, Pourrais -tu me donner le nom de ta commande, s'il te plait ?

 

Juste pour le fun... :)

;;;************************************************************************
;;; Symboliser la fenêtre en espace objet
(defun c:vrc (/ cmdecho sel n ent ct lg ht zo lst)
   (setq cmdecho (getvar "cmdecho"))
   (setvar "cmdecho" 0)
   (princ "\nSélectionner des fenêtres de présentation...")
   (if (and 
           (eq (getvar "tilemode") 0)
           (setq sel (ssget '((0 . "VIEWPORT"))))
       )
       (progn
           (repeat (setq n (sslength sel))
               (setq 
                   ent (entget (ssname sel (setq n (1- n))))
                   ct (mapcar '+
                       (trans (cdr (assoc 17 ent)) 0 1)
                       (trans (cdr (assoc 12 ent)) 2 1)
                   )
                   lg (cdr (assoc 40 ent))
                   ht (cdr (assoc 41 ent))
                   zo (/
                       (cdr (assoc 45 ent))
                       (cdr (assoc 41 ent))
                   )
                   lst (cons 
                       (cons 
                           (list
                               (- (car ct) (/ (* lg zo) 2))
                               (- (cadr ct) (/ (* ht zo) 2))
                               0.00
                           )
                           (list 
                               (list
                                   (+ (car ct) (/ (* lg zo) 2))
                                   (+ (cadr ct) (/ (* ht zo) 2))
                                   0.00
                               )
                           )
                       ) 
                       lst
                   )
               )
           )
           (setvar "tilemode" 1)
           (foreach pt lst (command "_rectang" "_non" (car pt) "_non" (cadr pt)))
   ))
   (setvar "cmdecho" cmdecho)
   (if (eq (sslength sel) 1)
       (princ "\nUne fenêtre représentée en espace objet.")
       (if (/= (sslength sel) 0)
           (princ (strcat "\n" (itoa (sslength sel)) "fenêtres représentées en espace objet."))
       )
   )
   (princ)
)

 

A bientot.

Matt.

 

EDIT : Corrections apportées par Mister Gile.

 

[Edité le 20/12/2007 par Matt666]

[yusukens82]

Pas mal le LISP (LISP LISP) <acronym class=dict title= Matt666

Juste pour le FUN ? pour moi c'est un gros travail

 

[Edité le 20/12/2007 par yusukens82]

[Matt666]

merci :red:

[Pieroka]

Il y a la commande "modifier l'espace" (mal traduite de l'anglais...) tout en bas du menu modification.

cette commande c'est _chspace.

[(gile)]

Salut Matt,

 

Pas mal, mais...

 

...si tu veux que les rectangles soient positionnés correctement en EO, il faut remplacer :

 

(setq
...
ct (cdr (assoc 12 ent))
...
) 

 

par :

 

(setq
  ...
  ct  (mapcar '+
	      (trans (cdr (assoc 17 ent)) 0 1)
	      (trans (cdr (assoc 12 ent)) 2 1)
      )
  ...
) 

 

et désactiver l'accrochage aux objets quand tu fais les rectangles :

 

(foreach pt lst (command "_rectang" "_non" (car pt) "_non" (cadr pt))) 

 

PS : ceci ne fonctionnant que si les vues dans les fenêtres sont des vues de dessus, pour des vues 3d, il faudrait inégrer la direction de la vue (code de groupe 16) et utiliser entmake plutot que command.[Edité le 20/12/2007 par (gile)]

 

[Edité le 20/12/2007 par (gile)]

[Matt666]

Ah ok ! Merci pour les corrections Gile, je mets à jour le post plus haut !

[yusukens82]

Petite question,

ce LISP est valable pour les rectangles simplement, est ce que c'est compliqué de changer le lisp afin qu'il puisse fonctionner également avec des fenetre déformé (pas forcement rectangle) ??

 

[LI_In4T!C]

Merci pour vos réponses.

:red:

Mais au risque de passer pour un idiot, qu'est ce qu'un LISP?

 

PS: Pieroka, ta méthode est pas mal, mais difficilement applicable dans mon cas où chaque fenêtre a un SCU différent, le projet n'étant pas rectiligne. Mais merci quand même.

 

[Edité le 20/12/2007 par LI_In4T!C]

[Matt666]

:)

Qu'est ce qu'un lisp... La question est de taille... :D

 

Le langage de programmation (auto) lisp permet de personnaliser et custmiser autocad, avec de nouvelles commandes.

 

Lisp = Gain de temps et utilisation facilitée...

 

Qqs liens :

Autocad

Wikipédia

Visual lisp

 

Voilà...

Je vais pas développer, ça pourrait durer longtemps !

 

[Edité le 20/12/2007 par Matt666]

[(gile)]

Salut LI_In4T!C,

 

Il est possible d'être un simple utilisateur de LISP (sans savoir programmer), regardes sur ce sujet pour connaître les procédures d'utilisation.

[lili2006]

Bonsoir à toutes et tous,

 

Pas mal le LISP (LISP LISP) Juste pour le FUN ? pour moi c'est un gros travail

 

J'confirme ! Terrible cet outil.

 

Merci à vous.

[LI_In4T!C]

Merci beaucoup, je vais étudier tout ça...encore faut il en trouver le temps, je crois que Autocad reste un outil, une passion aussi, mais pas ma principale. Ceci explique peut être cela...

 

[Edité le 10/1/2008 par LI_In4T!C]