point base de bloc

[benard]

Bonjour,

 

J'ai plusieurs blocs, donc le point de base n'est pas à 0,0,0

est-il possible de mettre ce point de base à 0,0,0

sur plusieurs blocs rangés dans un répertoire?

[LUDWIG]

Si j'ai bien compris, quand tu insères les blocs de ton répertoire, le point d'insertion des blocs n'est pas le point "0,0,0" du fichier du bloc. A priori, pour chaque fichier bloc, tu dois changer le point de base en utilisant la commande "base". Si tu en as beaucoup, tuy peux tenter de te mettre au script.

[Patrick_35]

Salut

 

Quelque chose de ce style ?

 

(defun c:rbase(/ cdl des dwg fic lst rep tot)
 (setq cdl (vlax-create-object "Shell.Application") tot 0)
 (and (setq rep (vlax-invoke cdl 'browseforfolder 0 "Sélectionnez le répertoire à traiter" 512 ""))
   (progn
     (setq rep (vlax-get-property (vlax-get-property rep 'self) 'path))
     (foreach dwg (setq lst (vl-directory-files rep "*.dwg"))
(if (setq fic (open (strcat rep "\\" dwg) "a"))
  (progn
    (close fic)
    (setq des (vla-open (vla-get-documents (vlax-get-acad-object)) (strcat rep "\\" dwg)))
    (vlax-invoke des 'setvariable "INSBASE" '(0.0 0.0 0.0))
    (vla-close des :vlax-true)
    (setq tot (1+ tot))
  )
  (princ (strcat "\nLe fichier " rep "\\" dwg " est déjà ouvert."))
)
     )
     (princ (strcat "\nModification de " (itoa tot) "/" (itoa (length lst))" fichier(s)."))
   )
 )
 (vlax-release-object cdl)
 (princ)
)

 

@+