Group

[l56]

Bonjour,

 

A partir d'un nom d'entité du type : (-1 . ),

Comment peut-on savoir si une entité fait partie d'un groupe, et si oui, lequel ?

 

Merci

 

[Matt666]

Pour voir les codes DXF d'une entité, essaye ceci :

(entget (car (entsel)))

Tu groupes deux entités et tu cliques sur l'une d'entre elles...

 

Essais faits avec BricsCAD :

 

Avant :

((-1 . ) (0 . "LINE") (5 . "3674") (67 . 0) (8 . "ARC-STRUCTURE") (62 . 256) (6 . "ByLayer") (370 . -1) (48 . 1.00000) (60 . 0) (39 . 0.000000) (10 8280.70 -9594.15 0.000000) (11 4680.70 -9594.15 0.000000) (210 0.000000 0.000000 1.00000))

Après :

((-1 . ) (0 . "LINE") (5 . "3674") (102 . "{ACAD_REACTORS") (330 . ) (102 . "}") (67 . 0) (8 . "ARC-STRUCTURE") (62 . 256) (6 . "ByLayer") (370 . -1) (48 . 1.00000) (60 . 0) (39 . 0.000000) (10 8280.70 -9594.15 0.000000) (11 4680.70 -9594.15 0.000000) (210 0.000000 0.000000 1.00000))

Changement :

(102 . "{ACAD_REACTORS") (330 . ) (102 . "}")

 

Voilà !

A bientot.

Matt.

 

[Bred]

Salut,

tu trouveras des codes pour travailles sur les groupes ici.

 

dont un code répondant à ta demande j'ai l'impression :

; routine retournant le nom du groupe de l'objet sélectionné
(defun Get-Nom-Groupe (sel / GR GROUPES LST LSTF NG VLA-SEL X)
(if sel
(progn
(setq groupes (vla-get-groups (vla-get-activedocument (vlax-get-acad-object)))
lstF nil)
(vlax-for n groupes
(setq ng (vla-get-name n)
lst nil)
(vlax-for i (vla-item groupes ng)
(setq lst (cons i lst))
)
(setq lstF (append (list (cons ng lst)) lstF))
)
(setq vla-sel (vlax-ename->vla-object sel))
(repeat (setq x (length lstF))
(if (member vla-sel (nth (setq x (1- x)) lstF))
(setq gr (car (nth x lstF)))
)
)
)
)
gr
)

[l56]

Merci à vous , je vais décortiquer tout ça !

a+

[(gile)]

Salut,

 

une piste :

 

;; ename de l'entité
(setq ent (car (entsel)))

;; liste dxf de l'entité
(setq elst (entget ent))

;; présence d'un ou plusieurs réacteurs
(if (equal (assoc 102 elst) '(102 . "{ACAD_REACTORS"))
 (progn
   ;; listes dxf du réacteur "GROUP" s'il existe
   (setq tmp  (cdr (member (assoc 102 elst) elst))
  loop T
   )
   (while (and loop (= 330 (caar tmp)))
     (if (= "GROUP" (cdr (assoc 0 (entget (cdar tmp)))))
(setq glst (entget (cdar tmp))
      loop nil
)
(setq tmp (cdr tmp))
     )
   )
 )
)

;; liste des noms de groupe
(if glst
 (vl-remove-if
   (function (lambda (x) (wcmatch x "`*A*")))
   (mapcar 'cdr
    (vl-remove-if-not
      (function (lambda (x) (= (car x) 3)))
      (entget (cdr (assoc 330 glst)))
    )
   )
 )
)

[Matt666]

Encore des function partout !!

 

Décidément faut vraiment que je regarde de ce coté !

Gile dit :

la fonction function équivaut à la fonction quote (') :

(mapcar (function (lambda ...))) fonctionne comme (mapcar '(lambda ...))

mais elle permet de lier et d'optimiser la fonction dans le compileur Visual LISP comme si c'était une fonction prédéfinie ou un defun.

 

Disons que pour l'instant je vois pas une grande nécessité, mais si toi, tu l'utilises, c'est forcément pas pour rien !

 

A bientot.

Matt.

 

[Matt666]

Par contre, Gile, la fonction "function" n'est pas par défaut dans l'autolisp de BricsCAD... C'est normal ?? Ou c'est toi qui l'a créé ??

[(gile)]

la fonction "function" n'est pas par défaut dans l'autolisp de BricsCAD... C'est normal ??

 

C'est normal, il n'y a pas non plus de compilateur Visual LISP.

[Matt666]

D'accord... Donc function, c'est du vlisp !

 

Ok merci !

 

A bientot.

Matt.

[(gile)]

Donc function, c'est du vlisp !

 

Non, c'est de l'AutoLISP AutoCAD (pour le compilateur.

 

Pour faire vite, avec BricsCAD, tu peux remplacer tous les function par des quote (Rechercher/Remplacer)

[Matt666]

Oui, c'est ce que j'avais compris dans ton explication sur un autre post...

 

Merci !