LSP pour chageur la largeur de polylignes dans un bloc

[hugo200120012]

Je cherche un lisp qui pourai modifie des bloc ( mettre a 0 toutes les polylignes qui sont dans ce bloc)

j'ai un lisp qui met "bylayer" toutes les lignes dans les blocs mais j'arrive pas a le modifier

 

[(gile)]

Salut,

 

Voilà :

 

code corrigé

 

(defun c:plw0 (/ doc)
 (vl-load-com)
 (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (vlax-for b (vla-get-Blocks doc)
   (if	(not (wcmatch (vla-get-name b) "`**_Space*"))
     (vlax-for	o b
(if (vlax-property-available-p o 'ConstantWidth)
  (vla-put-ConstantWidth o 0.0)
)
     )
   )
 )
 (vla-regen doc acAllViewports)
 (princ)
)

 

Si tu veux un "super LISP" pour modifier les propriétés de tous les objets composant des blocs, je te propose Edit_bloc sur cette page

 

[Edité le 17/10/2007 par (gile)]

[LUDWIG]

J'avais un lisp corrigé à l'époque par le débutant (gile) (!!!!!)

 

  ;**********************************************************************************************************************************************************
;Largeur de polyligne à 0
;**********************************************************************************************************************************************************
(defun c:poly0	()
(vl-load-com)
(setq a (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
(vlax-for bl a
(vlax-for ent bl
(if (and (vl-string-search "AcDb" (vla-get-objectname ent))(vl-string-search "Polyline" (vla-get-objectname ent)))
(vla-put-ConstantWidth ent 0)
)
)
)
(vla-regen (vla-get-activedocument (vlax-get-acad-object)) acActiveViewport)
)

 

Le problème est avec les polylignes 3D qui n'ont pas de propriétés constantwitdth... et que je n'ai jamais pris le temps de le corriger.

 

Donc merci pour ce nouveau lisp qui va dès maintenant remplacer l'ancien.

[LUDWIG]

ouch

 

; erreur: type d'argument incorrect: stringp nil 

[(gile)]

Oupss !

 

J'ai laissé trainer une variable qui n'est pas définie, je corrige le code ci dessus.

[LUDWIG]

impec