InputBox en LISP (DCL inclus)

[Patrick_35]

(gile)

 

J'ai eu le temps de modifier ton lisp avec la caractère \n

 

 ;; InputBox (gile)
 ;; Ouvre une boite de dialogue pour récupérer une valeur
 ;; sous forme de chaine de caractère
 ;;
 ;; Arguments
 ;; tous les arguments sont de chaines de caractère (ou "")
 ;; box : titre de la boite de dialogue
 ;; msg : message d'invite
 ;; val : valeur par défaut
 ;;
 ;; Retour
 ;; une chaine ("" si annulation)
 ;;
 ;; Modifié par Patrick_35 pour inclure le caractère \n
 ;; comme retour chariot

 (defun InputBox (box msg val / subr temp file dcl_id ret)
   ;; Retour chariot automatique à 50 caractères
   (defun subr (str / pos)
     (cond
((and (< 50 (strlen str))
      (setq pos (vl-string-position 32 (substr str 1 50) nil T))
  )
  (strcat ":text_part{label=\""
	  (substr str 1 pos)
	  "\";}"
	  (subr (substr str (+ 2 pos)))
  )
)
((setq pos (vl-string-search "\n" str))
  (strcat ":text_part{label=\""
	  (substr str 1 pos)
	  "\";}"
	  (subr (substr str (+ 2 pos)))
  )
)
(T
  (strcat ":text_part{label=\"" str "\";}")
)
     )
   )
   ;; Créer un fichier DCL temporaire
   (setq temp (vl-filename-mktemp "Tmp.dcl")
  file (open temp "w")
  ret  ""
   )
   ;; Ecrire le fichier
   (write-line
     (strcat
"InputBox:dialog{key=\"box\";initial_focus=\"val\";spacer;:paragraph{"
(subr msg)
"}spacer;:edit_box{key=\"val\";edit_width=54;allow_accept=true;}
spacer;ok_cancel;}"
     )
     file
   )
   (close file)
   ;; Ouvrir la boite de dialogue
   (setq dcl_id (load_dialog temp))
   (if (not (new_dialog "InputBox" dcl_id))	
     (exit)
   )
   (set_tile "box" box)
   (set_tile "val" val)
   (action_tile
     "accept"
     "(setq ret (get_tile \"val\")) (done_dialog)"
   )
   (start_dialog)
   (unload_dialog dcl_id)
   ;;Supprimer le fichier
   (vl-file-delete temp)
   ret
 )

 

ce qui donne

(inputbox "TEST" "Ligne1\nLigne2\nLigne3" "Génial")

ou encore

(inputbox "TEST" "C'est quand même bien pratique cette petite BD" "YO")

puis

(inputbox "TEST" "Et maintenant une ligne avec 50 caractères au minimum pour vérifier que tout se passe bien" "Mouais")

 

@+

[(gile)]

Super :D