changer couleur XRef

[Barbados16]

Bonjour à tous,

 

j'utilise Autocad 2008 en entreprise, pour créer des plans d'implantations de nos ateliers.

Je teste actuellement une nouvelle méthode de travail avec les XRefs.

 

J'ai un fichier "Ligne 10" qui represente les machines, et dans lequel j'importe en XRefs le plan des batiments (qui contient plusieurs calques).

 

Pour faire ressortir visuelement mes machines, j'aurais souhaité "griser" le plan du batiment. Mais quand je modifie la couleur dans les propriétés rien ne se produit sur mon Xref (je pense que c'est lié aux calques de mon fichier externe ??) :casstet:

 

J'ai cherché toute la matinée sur des forums, je n'ai rien toruvé. :( Quelqu'un peut-il m'aider ?

 

merci d'avance. :)

[lesourd2]

Salut

 

Dans ton fichier original de ton Xref, changes tes couleurs via le gestionnaire des calques, au pire fais une selection totale de ton dessin et attribues ta couleur (DUCALQUE).Enregistres et reinseres ton xref.

 

0@+

[Barbados16]

Merci de ta réponse, mais le soucis c'est que je ne peux pas me permettre de modifier le fichier original de mon Xref. Si je change toutes les couleurs, le fichier original ne sera plus très clair (nombreux calques : murs, fenetres, cloisons, ouvertures, évacuations techniques ....).

 

Il n'y a pas d'autres solutions pour modifier la couleur d'un Xref sans agir sur le fichier original ? (sachant que je veux tout de même conserver la fonction de mise à jour que permet une Xref).

 

Cordialement

 

[(gile)]

Salut,

 

Tu trouveras ici une petite routine LISP qui met tous les calques du dessin en couleur 8 (gris) et toutes les entités en couleur DuCalque.

 

Doublé par le message précédent.

Si la Xref ne te sert que de fond de plan (que tu ne la modifies pas) tu peux faire une copie de l'original mettre la copie en gris en l'insérer.

 

[Edité le 10/10/2007 par (gile)]

[La Lozère]

Salut,

Ce que tu peut faire s'est changer la couleur des calques de l'XREF des bâtiment dans le fichier de tes machine. Ainsi tu ne change pas les couleurs des calques de ton fichier originale mais uniquement celui des machines.

Par contre si tu veux que le fichier concerve les modifications de couleur des xref il faut cocher la case "concerver les modifications des calques des Xref" dans l'onglet "Ouvrir et enregistrer" des "options".

Voilà, ce n'est qu'une idée en passant.

A plus

[Barbados16]

Merci Gile pour ta routine (1ere fois que j'en utilise une). Mais j'ai quelques questions quant à son utilisation pour mon cas personnel.

 

Merci Adat-btp pour m'avoir répondu, c'est justement ce que je cherchais à faire mais celà ne marche pas (exple : je modifie la couleur de mon calque Xref mais sur le plan tour reste de la même couleur.)

 

Gile je voulais savoir si on peut appliquer la routine juste à un seul calque (quand j'éxcecute la routine, elle met en gris tous mes calques de mon dessin courant :(

 

Je vais essayer d'expliciter un peu mieux ce que je voudrais faire :

 

1 Fichier "Batiments" ==> représente les batiments de mon entreprise vides.

 

1 Fichier "Ligne 10" qui représente mes machines seules.

 

J'ai donc mis en Xref mon fichier "batiments dans mon fichier "ligne 10" ainsi je peux modifier ma ligne de production tout en ayant une vue dans le batiment.

 

Ce plan batiment est utilisé par beaucoup de collègues je ne peux donc pas le modifier.

 

Giles tu me suggéres de mettre faire une copie du plan batiment original que je mettrais en niveua de gris pour faire mon fond de plan. Mais si on vient à modifier un mur, il faudra alors que je modifie dans mes 2 fichiers ?

Une autre question, lorsque j'execute la routine, la majorité des éléments passent en gris, mais certains restent dans leur couleur originelle (j'ai pris soin de définir auparavant "couleur du calque" pour tout mon dessin), où est le problème ?

 

Merci pour les réponses que vous m'avez posté.

 

Cordialement.

 

 

 

 

 

 

[Edité le 10/10/2007 par Barbados16]

[Joffoon]

Salut,

 

Moi perso je fais ce que propose Giles en deuxiemement, je fais la copie du fichier original puis je le nettoie (calques obseletes, changement de couleurs des objets/textes etc...) et j'insere ma X-ref.

 

Giles tu me suggérer de mettre faire une copie du plan batiment original que je mettrais en niveua de gris pour faire mon fond de plan. Mais si on vient à modifier un mur, il faudra alors que je modifie dans mes 2 fichiers ?

 

Pas forcement, lorsque tu modifies/changes des éléments sur le fichier de ta X-ref ou copie de X-ref, lorsque tu reprends ton fichier sur lequel tu travail Autocad te proposes de réactualiser ta X-ref en un click.

 

En ce qui concerne la routine, je ne l'ai pas essayée..

 

A+,

 

Joff

[(gile)]

Salut,

 

 

Un petit truc vite fait et pas testé en profondeur.

 

 

Deux commandes :

 

 

- xref-color-set : remplace la couleur de tous les calques de la xref sélectionnée par la couleur spécifiée (il faut que les objets de la xref soient en DuCalque, mais de cette façon on intervient que sur la référence dans le dessin, pas sur le fichier original). Les couleurs originales des calques sont conservées dans un dictionnaire lié à la xref.

 

 

- xref-color-restore permet de restaurer leurs couleurs originales aux calques depuis le dictionnaire même après fermeture et enregistrement du dessin.

 

 

EDIT : j'avais encore oublié le fameux (vl-load-com).

 

 

RE-EDIT : j'ai ajouté une sécurité aucas où xref-color-set serait lancé plusieurs fois de suite, pour être sur de garder les couleurs d'origine.

 

 

(defun c:xref-color-set (/ acdoc xrf col lst)
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (if (and (setq xrf (car (entsel "\nSélectionnez la référence externe: ")))
   (setq xrf (vlax-ename->vla-object xrf))
   (= (vla-get-ObjectName xrf) "AcDbBlockReference")
   (setq col (acad_colordlg 8 nil))
     )
   (progn
     (vla-StartUndoMark acdoc)
     (vlax-for	l (vla-get-Layers acdoc)
(and (wcmatch (vla-get-Name l) (strcat (vla-get-Name xrf) "|*"))
  (setq lst (cons (cons (vla-get-Name l) (vla-get-color l)) lst))
  (vla-put-color l col)
)
     )
     (or (vlax-ldata-get xrf "laycol")
  (vlax-ldata-put xrf "laycol" lst)
     )
     (vla-EndUndoMark acdoc)
   )
 )
 (princ)
)

(defun c:xref-color-restore (/ acdoc xrf lst)
(vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (if (and (setq xrf (car (entsel "\nSélectionnez la référence externe: ")))
   (setq xrf (vlax-ename->vla-object xrf))
   (= (vla-get-ObjectName xrf) "AcDbBlockReference")
   (setq lst (vlax-ldata-get xrf "laycol")) 
     )
   (progn
     (vla-StartUndoMark acdoc)
     (vlax-for	l (vla-get-Layers acdoc)
(if (setq pair (assoc (vla-get-Name l) lst))
  (vla-put-color l (cdr pair))
)
     )
     (vlax-ldata-delete xrf "laycol")
     (vla-EndUndoMark acdoc)
   )
 )
 (princ)
) 

[Edité le 10/10/2007 par (gile)]

 

[Edité le 10/10/2007 par (gile)]

[lesourd2]

Salut

 

Je confirme ce qui est dit par JOFFOON et GILE concernant la maniere de gerer les Xref.

C'est aussi ce que je fais (sans aucun probleme).

 

Il faut toujours faire une copie de ton fichier original et travailler avec une copie.

 

@+

[Joffoon]

Salut Giles,

 

Je viens de tester ta routine et elle fonctionne bien, cependant, après je ne sais pas si cela est possible, mais penses-tu qu'il serait possible de changer aussi des lignes/polylignes qui ne sont pas Ducalque en Ducalque, car les traits n'étant en Ducalque reste de la meme couleur... Je sais que tu as précisé que cela n'était pas le cas, mais est-ce possible, stp??

 

Un petit truc vite fait et pas testé en profondeur.

 

Rien que ça déjà c'est énorme, et encore un gain de temps supplémentaire ou tu n'a meme plus besoin de faire une copie de ta X-ref, ça c'est cool..

 

a+,

 

Joff (sur le c..)

 

[Edité le 10/10/2007 par Joffoon]

[(gile)]

mais penses-tu qu'il serait possible de changer aussi la couleur des lignes/polylignes qui ne sont pas Ducalque en Ducalque, car les traits n'étant en Ducalque reste de la meme couleur...

 

Pas sans intervenir sur le fichier source (comme avec editref), en intervenant sur les calques je fais la même chose que ce que tu peux faire avec le gestionnaire des calques, je n'intercvient que sur la référence insérée dans le dessin.

[Joffoon]

Ok, merci d'avoir répondu^^,

 

Faudrait que tu mettes ta routine dans ta rubrique, je pense qu'elle va pas mal servir celle là ;) .. Ainsi que Move-att, que j'ai decouvert aujourd'hui et qui me fait gagner un temps fou..

 

Bonne soirée et encore bravo..

 

Joff

 

[Edité le 10/10/2007 par Joffoon]

[lesourd2]

Salut

 

Je viens de tester ta routine et elle fonctionne bien

.

 

Là j'ai du louper quelque chose .Chez moi ça ne marche pas.

 

Quand je tapes le code, AutoCAD me demande de selectionner le reference externe; je seletionne et puis là plus rien!

 

Merci par avance pour des infos .

 

@+

[(gile)]

Quand je tapes le code, AutoCAD me demande de selectionner le reference externe; je seletionne et puis là plus rien!

 

Tu devrais avoir une boite dedialogue qui s'ouvre pour te faire choisir une couleur, si tu'n'as même pas ça, essaye de refaire les copier/coller des codes et recharge les.

[lesourd2]

Salut gilles

 

Tu devrais avoir une boite dedialogue qui s'ouvre pour te faire choisir une couleur

Pas de boite de dialogue

 

essaye de refaire les copier/coller des codes et recharge les.

.

 

marche toujours pas .Comprends pas.

 

@+

 

 

[(gile)]

Un message d'erreur ?

 

Je viens de m'apercevoir que j'ai encor oublié le traditionnel (vl-load-com), je modifie les codes.

[rebcao]

j'ai rapidement lu les réponses, il ne semble pas que quelqu'un ait abordé les STYLES de tracé !

 

Tu crées un style de tracé XREF (par exemple) que tu affectes à tous les calques de ta XREF. Le style XREF utilises la couleur 8.

 

au moemnt d'imprimer tu passes en GRIS sans toucher au couleurs de tes calques !

 

Christian

[(gile)]

Salut Christian,

 

La demande n'est pas d'imprimer les xref en gris, mais de les afficher en gris pour travailler dessus à l'écran.

[Barbados16]

Bonjour à tous !!

 

Un grand MERCI pour toutes vos réponses, et MERCI à Gile pour ses routines qui me sont très utiles. Xref-color-set fonctionne très bien sur mon PC.

 

Je souhaitais juste soulever deux autres questions concernant cette routine :

 

Est-il possible d'appliquer cette routine à tous les objets de la reférence externe (pas seulement Ducalque, et sans modifier le fichier original) ?

 

Peut-on gérer les références "imbriquées" (La Xref que je veux griser contient d'autres Xref que je veux également griser) ?

 

Ce sont juste quelques questions de "confort" car la routine de Gile me convient déjà très bien. N'étant pas programmeur et relativement novice sur Autocad, je ne sais pas si cela est faisable.

 

Encore merci à tous.

 

Cordialement.

 

 

 

 

[(gile)]

Salut,

 

 

Est-il possible d'appliquer cette routine à tous les objets de la reférence externe (pas seulement Ducalque, et sans modifier le fichier original) ?

 

Les routines agissent sur les couleurs de calque des références dans le dessin cible, comme tu le ferais en changeant la couleur des calques dans le gestionnaire.

 

Intervenir sur les entités de la référence (ce qui serait équivalent à éxécuter EDITREF) modifierais le fichier source.

 

 

Peut-on gérer les références "imbriquées" (La Xref que je veux griser contient d'autres Xref que je veux également griser) ?

 

 

Je n'ai pas creusé la question, mais vite fait, deux autres LISP (xcol-set et xcol-rest) qui changent les couleurs de tous les calques dépendant des xrefs du dessin (xref imbriquées comprises)

 

 

(defun c:xcol-set (/ acdoc col lst)
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (if (setq col (acad_colordlg 8 nil))
   (progn
     (vla-StartUndoMark acdoc)
     (vlax-for	l (vla-get-Layers acdoc)
(and (wcmatch (vla-get-Name l) "*|*")
     (setq
       lst (cons (cons (vla-get-Name l) (vla-get-color l)) lst)
     )
     (vla-put-color l col)
)
     )
     (or (vlax-ldata-get "all-xref-color" "laycol")
  (vlax-ldata-put "all-xref-color" "laycol" lst)
     )
     (vla-EndUndoMark acdoc)
   )
 )
 (princ)
)

(defun c:xcol-rest	(/ acdoc lst)
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (if (setq lst (vlax-ldata-get "all-xref-color" "laycol"))
   (progn
     (vla-StartUndoMark acdoc)
     (vlax-for	l (vla-get-Layers acdoc)
(if (setq pair (assoc (vla-get-Name l) lst))
  (vla-put-color l (cdr pair))
)
     )
     (vlax-ldata-delete "all-xref-color" "laycol")
     (vla-EndUndoMark acdoc)
   )
 )
 (princ)
) 

[rebcao]

Salut Christian,

 

La demande n'est pas d'imprimer les xref en gris, mais de les afficher en gris pour travailler dessus à l'écran.

 

et le GESTIONNAIRE DE MISE EN PAGE... il permet d'afficher à l'écran l'équivalent de l'aperçu avant impression.

 

Je constate que beaucoup ne maitrise pas du tout ces styles de tracé. Quand je vois que beaucoup parles encore de CTB ou de PC3... :casstet:

 

Christian

 

[Edité le 14/10/2007 par rebcao]

[(gile)]

Je cosntate que beaucoup ne maitrise pas du tout ces styles de tracé. Quand je vois que beaucoup parles encore de CTB ou de PC3...

 

C'est vrai, j'en fais parti. :P

 

Mais si j'ai bien compris ta méthode, cela suppose de travailler avec les styles de tracé nommés (STB) mais aussi de dessiner dans l'espace objet des onglets de présentation.

C'est là une méthode de travail assez peu commune, il me semble. Il va falloir sérieusement bousculer des habitudes !

[lili2006]

Bonjour à toutes et tous,

 

 

mais aussi de dessiner dans l'espace objet des onglets de présentation.

 

Pourquoi ça ?

[(gile)]

Salut lili2006,

 

J'ai essayé la méthode décrite par Rebcao (il est possible que je m'y soit mal pris...)

 

- dans un dessin en mode style de tracé nommé (ex : Xref.stb) avec un style de tracé "Gris" (couleur 8)

 

- dans le gestionnaire des calques : tous les calques dépendant de xref en Style de tracé "Gris"

 

- dans le gestionnaire de mise en page : Table des style de tracé = Xref.stb et cocher "Afficher styles de tracé"

 

Et bien les xrefs insérées s'affichent en gris dans l'espace objet des fenêtres de présentation, pas dans l'onglet objet.

 

 

 

[rebcao]

Eh ben voilà on y arrive...

 

cette option est même très déroutante pour quelqu'un qui tombe dessus par hasard :(

 

J'utilise et je développe beaucoup le sujet des styles de tracé dans mes formations... ;)

 

Christian