SSADD

[Matt666]

Salut à tous !

J'ai une rpoblème dans une routine développée dans ce post...

 

Le problème, c'est que la fonction SSADD n'ajoute pas la nouvelle entité à la sélection mais remplace tout pas la nouvelle entité !!!

 

Je ne comprends pas du tout... J'ai bien cherché sur internet, et tout le monde fait comme ça..

 

;;; Génère automatiquement une liste des entités d'une des tables de la bd graphique.
;;; (LSTAB "layer") -> ("0" "structure")
(defun LSTAB (TABL / LB X)
   (if	(member
    (strcase tabl)
    '("APPID"
      "BLOCK"
      "DIMSTYLE"
      "LAYER"
      "LTYPE"
      "STYLE"
      "UCS"
      "VIEW"
      "VPORT"
     )
)
(progn
    (setq lb (cons (cdr (assoc 2 (tblnext tabl T))) lb))
    (while (setq x (cdr (assoc 2 (tblnext tabl))))
	(setq lb (cons x lb))
    )
    (if	(/= (strcase tabl) "BLOCK")
	(setq lb (acad_strlsort lb))
	lb
    )
)
   )
)

;;; Ajoute un texte avec comme valeur le nom du bloc 
;;; à chaque référence de bloc présente dans le dessin
(defun c:mbloc (/ cmdecho attreq ent tout s_set)
   (setq cmdecho (getvar "cmdecho")
  attreq  (getvar "attreq")
   )
   (setvar "cmdecho" 0)
   (setvar "attreq" 0)
   (command "_undo" "d")
   (setq ent (entlast))
   (if	(setq tout (vl-remove-if '(lambda (x) (eq (substr x 1 1) "*"))
			 (lstab "block")
	   )
)
(progn
    (foreach pt	tout
	[b](setq s_set (ssadd)[/b]
	      elts  (cdr (assoc -2 (tblsearch "block" pt)))
	)
	(while elts
	    [b](ssadd elts s_set)[/b]
	    (setq elts (entnext elts))
	)
	(entmake (list
		     (cons 0 "TEXT")
		     (cons 1 pt)
		     (cons 10 (list -0.20 -0.10 0.00))
		     (cons 8 "0")
		     (cons 40 0.05)
		 )
	)
	(if (/= (entlast) ent)
	    [b](ssadd (entlast) s_set)[/b]
	)
	(command "-bloc" pt "o" "0,0,0" s_set "")
    )
    (princ (strcat "\n"
		   (itoa (length tout))
		   " références de blocs modifiées."
	   )
    )
)
   )
   (command "_undo" "f")
   (setvar "attreq" attreq)
   (setvar "cmdecho" cmdecho)
   (princ)
) 

 

Si qqn pouvait m'aider, ça m'arrangerait fortement !

Merci d'avance !

 

A bientot.

Matt.

 

[Edité le 29/9/2007 par Matt666]

[(gile)]

Salut,

 

À première vue la syntaxe utilisée vec ssadd est juste mais si ton code ne fonctionne pas c'est que tu veux ajouter à un jeu de sélection des objets qui ne sont pas des entités graphiques (des objets sélectionnés dans le dessin) mais de définition d'objets récupérés dans une définition de bloc.

 

Sans y regarder de plus près, je dirais que tu as 2 solutions :

- exploser une référence, récupérer les entités graphiques du bloc explosé (setq s_set (ssget "_P")) ajouter la nouvelle entité au jeu de sélection (ssadd ...) et redéfinir le bloc (command ...) ;

- redéfinir le bloc dans la table avec entmake :

(entmake (list '(0 . "BLOCK") ...)) la liste DXF est récupérée avec (entget (tblobjname ...))

un entmake par entité - la liste DXF est récupérée avec (entget (entnext ...))

(entmake '((0 . "ENDBLK"))) pour terminer la définition du bloc.

 

Mais tu tu ne peux pas faire un "mix" des deux comme tu essayais de le faire.

 

[Edité le 29/9/2007 par (gile)]

[Matt666]

ok d'ac merci (Gile) !

Je vais plutôt prendre la première solution... La deuxième je crois que j'aurai du mal à la mettre en place (Seqend ???)...

 

J'essaie ça au plus vite !

 

Merci encore..

Matt.

[Matt666]

Dément ça fonctionne !!!

 

Merci (Gile) !

 

Pour voir la routine, faut aller là !

 

A bientot.

matt.

 

[(gile)]

Il y avais quelques inexactitudes dans le messages ci-dessus (seqend au lieur de endblk...) je l'ai modifié.

 

sinon ce n'est pas difficile, exemple pour un bloc nommé "Bloc" :

 

;; récupérer les noms d'entités
(setq bloc-def (tblobjname "block" "bloc")
     ent (cdr (assoc -2 (entget bloc-def))) 
     )

;; créer le bloc (vide)
(entmake (entget bloc-def))

;; créer les objets composant le bloc
(while ent
 (entmake (entget ent))
 (setq ent (entnext ent))
 )

;; ajouter la nouvelle entité
(entmake (list
(cons 0 "TEXT")
(cons 1 pt)
(cons 10 (list -0.20 -0.10 0.00))
(cons 8 "0")
(cons 40 0.05)
)
 )

;; terminer le bloc	 
(entmake '((0 . "ENDBLK")))