Evenements

[sechanbask]

Bonjour,

Je souhaiterais qu'une application démarre lorsqu'un bloc est changé... j'espère que les grands du VB ou VBA pourront m'aider.

[nazemrap]

Bonjour,

 

je ne suis pas grand.

Je ne sais pas ce que tu envisages par "lorsqu'un bloc est changé"

J 'ai un exemple de code qui lance Excel lorsqu 'on intervient sur un bloc.

Ceci en utilisant l 'évènement "Modified".

Si ça t 'intéresse, fais le moi savoir.

[sechanbask]

oui ça m'intéresse, je veux en fait aider :http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=16673 mais j'arrive pas à rendre le code réactif, je ne sais pas où je dois mettre le code dans module de classe où module classique, etc.

 

J'ai pourtant lu l'aide vba de autocad sur les events mais j'arrive pas à faire marcher les exemples..

 

Merci de m'aider pour l'aider...

[nazemrap]

Hello,

 

voici le code à mettre dans un module de classe, renommé ici "EventClass"

 

 Public WithEvents blocref As AcadBlockReference

Private Sub blocref_Modified(ByVal pObject As IAcadObject)

Dim ExcelAppObj As Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheet As Excel.Worksheet

MsgBox "coucou, déclenchement de l 'évènement qui va ouvrir excel"

'penser à charger la bib des objets xl

Set ExcelAppObj = CreateObject("Excel.application")
Set xlBook = ExcelAppObj.Workbooks.Add
Set xlSheet = xlBook.Worksheets(1)

ExcelAppObj.Application.Visible = True
ExcelAppObj.Windows(1).Visible = True
End Sub

 

 

Voici maintenant le code à mettre dans un module normal

 

 Dim X As New EventClass
Sub bloc_avec_evenement()
Dim bloc As AcadBlock
Dim centerPoint(0 To 2) As Double
Dim insertionPnt(0 To 2) As Double
Dim ray As Double
Dim cercle As AcadCircle
Dim blocins As AcadBlockReference

ray = 10
centerPoint(0) = 0#: centerPoint(1) = 0#: centerPoint(2) = 0#

Set bloc = ThisDrawing.Blocks.Add(centerPoint, "nombloc")
Set cercle = bloc.AddCircle(centerPoint, ray)

insertionPnt(0) = 2#: insertionPnt(1) = 2#: insertionPnt(2) = 0
Set blocins = ThisDrawing.ModelSpace.InsertBlock(insertionPnt, "nombloc", 1#, 1#, 1#, 0)

Set X.blocref = blocins
End Sub

 

Penses à charger la bib excel.

Tu exécutes le code de la seconde partie.

Un bloc est créé, contenant un cercle puis inséré dans la zone graphique.

Lorsque tu déplaceras (par exemple) ce bloc, un message t 'avertiras de l 'ouverture d 'excel.

Excel doit s' ouvrir, avec un classeur.

 

Si pas clair ou mauvais fonctionnement, n 'hésites pas.

 

[sechanbask]

Merci ça marche, je regarde le code et essaie de voir si j'arrive à l'utiliser pour mon application. Je te remercie vivement.