conversion polyligne 3D en 2D

[ares_ulis]

Bonjour à tous,

 

Je cherche le moyen de transformer des polylignes 3D en polylignes 2D. J'ai déjà essayer la fonction FLATTEN mais celle ci me met tout mon dessin avec Z=0.000; j'ai également essayé avec le logiciel 3D turbo Nt ms il n'est pas assez puissant pour AutoCAd 2007 :( .

 

Si quelqu'un pouvait me dire si il existe un lsp ou un logiciel gratuit pour faire ceci ca serait très gentil.

 

Merci pour vos réponses. :)

 

Ares_ulis

[lili2006]

Bonsoir à toutes et tous,

 

Bienvenu ares_ulis

 

(Gile) , un des spécialistes du lisp de ce forum avait répondu à mon problème (qui était donc le même que le tien de ce jour !) de la façon suivante :

 

;;; 3D2LW -03/06/07-
;;; Crée une lwpolyligne, projection de la polyligne 3d sur le plan XY du SCU courant
(defun c:3d2lw (/ acdoc model ss poly)
(vl-load-com)
(setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object))
model (vla-get-ModelSpace AcDoc)
)
(if
(setq ss (ssget "_:S" '((0 . "POLYLINE") (-4 . "&") (70 . 8))))
(progn
(vla-StartUndoMark acdoc)
(vla-put-Elevation
(vlax-invoke
model
'addLightWeightPolyline
(apply
'append
(mapcar
'(lambda (p)
(setq p (trans p 0 (trans '(0 0 1) 1 0 T)))
(list (car p) (cadr p))
)
(3d-coord->pt-lst
(vlax-get
(setq poly (vlax-ename->vla-object (ssname ss 0)))
'Coordinates
)
)
)
)
)
(caddr (trans (getvar "UCSORG") 0 (trans '(0 0 1) 1 0 T)))
)
(initget "Oui Non")
(if (or (not (setq rep
(getkword
"\nEffacer la polyligne source ? [Oui/Non] : "
)
)
)
(= rep "Oui")
)
(vla-delete poly)
)
(vla-EndUndoMark acdoc)
)
)
(princ)
)

;;; 3d-coord->pt-lst Convertit une liste de coordonnées 3D en liste de points
;;; (3d-coord->pt-lst '(1.0 2.0 3.0 4.0 5.0 6.0)) -> ((1.0 2.0 3.0) (4.0 5.0 6.0))

(defun 3d-coord->pt-lst (lst)
(if lst
(cons (list (car lst) (cadr lst) (caddr lst))
(3d-coord->pt-lst (cdddr lst))
)
)
)  

 

Et pour moi, pas de soucis.

 

Bon courage.

 

 

[thierry.garré]

Bonsoir,

 

 

en direct d'Annaba (Algérie) , puique l'on est dans le forum COVADIS

 

COVADIS 3D/POLYLIGNE 3D/CONVERTIR EN POLYLIGNES 2D

 

OU

 

 

COV EDITION/POLYLIGNES/POLYLIGNES 3D ->POLYLIGNE 2D

 

 

et rebonsoir....

[ares_ulis]

Bonjour à tous le monde,

 

Merci pour vos réponses elles m'ont été d'une grande aide. Ca a marché comme sur des roulettes!!! :)

 

ares_ulis