Cotation type topo

merna · le 31 août 2007

Bonjour à tous

Je cherche un moyen de coter que je n'arrive pas à faire avec autocad.

Je souhaiterai faire une cotation un peu comme celle des levés d'intérieur de Covadis (pour ceux qui connaissent) que je n'ai plus (suite à changement de poste...).

C'est à dire la cote entourée simplement de 2 blocs flèches accrochés aux sommets comme suit:

http://img251.imageshack.us/img251/1898/capture3kh7.png

Dans Autocad 2007, je n'ai pas réussi à enlever les lignes de cotes sans enlever les flèches avec.

Voila ayant de nombreuses cotations à faire j'aimerai savoir si qqun connait un lisp s'approchant de ça.

Merci.

lili2006 · le 31 août 2007

Bonsoir,

Petite précision :

Cette demande fait suite à ce post !

[Edité le 31/8/2007 par lili2006]

lili2006 · le 31 août 2007

Re,

En créant un bloc flèche et en fonction de ce que j'ai écrit sur le post cité plus haut, voici le corrigé du 1er TD sur AutoCAD que je donne à mes étudiants : (C'est une île levé à l'équerre optique):

C'est à peu prés ce que tu recherches, non ?

[Edité le 31/8/2007 par lili2006]

merna · le 31 août 2007

Oui ça a l'air d'être ça.

lili2006 · le 31 août 2007

Re,

Si tu veux créer un style de cotes depuis cette représentation. Ici, il s'agit que d'une flèche et du texte et ensuite, je montre aux étudiants les différents paramètres de cotes,...

http:// http://cjoint.com/?iFwmy8kakM

Pour info : Avant de rentrer dans les subtilités d'AutoCAD (Création style de cotes, Cartouche avec attributs, multifenêtrage pour gel/degel de calques, écritures espace papier des variables, réglage des facteurs de lignes,...),ce dossier sert de base et je l'exploite à titre d'exemple au fur et à mesure de l'enseignement.

Bon courage.

[Edité le 31/8/2007 par lili2006]

winfield · le 31 août 2007

Salut,

je ne sais pas comment ça se passe avec ton modèle (désolé, j'ai la flegme de charger). Je faisais ça avec un bloc et il ne restait plus qu'à paramétrer les flèches dans les Styles de cotations. Nos méthodes sont peut-être similaire voir identique, mais donner un truc tout "cuit" peut paraitre bien sur le moment, mais à long terme ...c'est mieux avec la notice. ;)

(gile) · le 31 août 2007

Salut,

Comme on est dans un forum LISP, je suppose que merna attend une réponse en LISP (les autres réponses auraient dues être postées dans l'autre sujet, non ?).

Je propose donc un petit LISP qui semble répondre à ta demande (si j'ai bien compris).

En l'état :

L'utilisateur clique sur le premier et second point d'origine de la cote puis sur le côté où positionner la cote par rapport aux points précedents.

Le texte de cote est écrit dans le sens du premier point vers le second.

Le LISP fonctionne dans l'espace objet et les SCU aprallèles au SCG.

Il crée le bloc flèche s'il n'existe pas encore dans le dessin.

Les propriétés de la cote crée (taille, unités, décimales) sont celles du type de cote courant (DIMSCALE, DIMTXT, DIMLUNIT, DIMDEC).

http://img174.imageshack.us/img174/3096/cottopost8.png

(defun c:cot-topo (/ AcDoc ModSp Blocks scl p1 p2 mid ang p3 cw bl pl ang ref tmp txt)
 (vl-load-com)
 (setq	AcDoc  (vla-get-ActiveDocument (vlax-get-acad-object))
ModSp  (vla-get-ModelSpace AcDoc)
Blocks (vla-get-Blocks AcDoc)
scl    (if (zerop (getvar "DIMSCALE"))
	 (getvar "DIMTXT")
	 (* (getvar "DIMSCALE") (getvar "DIMTXT"))
       )
 )
 (initget 1)
 (setq p1 (getpoint "\nSpécifiez le premier point d'origine: "))
 (initget 1)
 (setq	p2  (getpoint p1 "\nSpécifiez le second point d'origine: ")
mid (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.0)) p1 p2)
 )
 (initget 1)
 (setq	p3 (getpoint mid "\nSpécifiez la position de la cote : ")
cw (clockwise-p p1 p2 p3)
p3 (polar mid
	  ((if cw - +) (angle p1 p2) (/ pi 2))
	  (* 2 scl)
   )
 )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
 ;; Création du bloc s'il n'existe pas
 (if (vl-catch-all-error-p
(vl-catch-all-apply
  'vla-item
  (list Blocks "cotation-type-topo")
)
     )
   (progn
     (setq bl (vla-add	Blocks
		(vlax-3d-point '(0 0 0))
		"cotation-type-topo"
       )
    pl (vlax-invoke
	 bl
	 'addLightWeightPolyline
	 (list 0.0 0.0 2.0 -2.0 3.0 -2.0)
       )
     )
     (vla-setBulge pl 0 (- (sqrt 2) 1))
     (vla-setWidth pl 1 (/ 1.0 3) 0)
     (vla-put-Layer pl "0")
   )
 )
 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

 (vla-StartUndoMark AcDoc)
 (foreach p '(p1 p2 p3 mid)
   (set p (trans (eval p) 1 0))
 )
 (setq	ang (angle p1 p2)
 ref (vla-InsertBlock
      ModSp
      (vlax-3d-point p1)
      "cotation-type-topo"
      scl
      scl
      1.0
      ang
    )
 )
 (if (not cw)
   (progn
     (setq tmp (vla-mirror ref (vlax-3d-point p1) (vlax-3d-point p2)))
     (vla-delete ref)
     (setq ref tmp)
   )
 )
 (vla-mirror ref (vlax-3d-point mid) (vlax-3d-point p3))
 (setq	txt (vla-addText
      ModSp
      (rtos (distance p1 p2)(getvar "DIMLUNIT") (getvar "DIMDEC"))
      (vlax-3d-point p3)
      scl
    )
 )
 (vla-put-Alignment txt 10)
 (vla-put-TextAlignmentPoint txt (vlax-3d-point p3))
 (vla-rotate txt (vlax-3d-point p3) ang)
 (vla-EndUndoMark AcDoc)
 (princ)
)


;;; Clockwise-p Retourne T si les points p1 p2 et p3 tournent dans le sens horaire

(defun clockwise-p (p1 p2 p3)
 ()

[Edité le 31/8/2007 par (gile)]

lili2006 · le 1 septembre 2007

Bonjour à tous,

Oups, je me suis trompé,....

Comme on est dans un forum LISP, je suppose que merna attend une réponse en LISP (les autres réponses auraient dues être postées dans l'autre sujet, non ?).

. Je pensais être encore sur l'autre sujet, désolé!

A part cela, j'ai testé (gile) et c'est plutôt pas mal. A mon goût les textes sont un peu loin des éléments à coter (flêche peut-être plus petite,...?). Ce qui est fort, c'est l'adaptation du style de texte. Le même plan avec les deux styles superposés sur deux cotes :

(gile) · le 1 septembre 2007

Une nouvelle version :

- le texte est plus proche de l'élément à coter

Edit : Fonctionne aussi dans les SCU non parallèles au SCG.

(defun c:cot-topo (/	 AcDoc Blocks	   scl	 Space p1    p2
	   mid	 ang   p3    cw	   bl	 pl    ang   ref
	   tmp	 txt
	  )
 (vl-load-com)
 (if (= 1 (getvar "CVPORT"))
   (alert
     "Cette commande ne peut être utilisée que dans l'espace objet."
   )
   (progn
     (setq AcDoc  (vla-get-ActiveDocument (vlax-get-acad-object))
    Blocks (vla-get-Blocks AcDoc)
    Space  (vla-get-ModelSpace AcDoc)
    scl	   (if (zerop (getvar "DIMSCALE"))
	     (getvar "DIMTXT")
	     (* (getvar "DIMSCALE") (getvar "DIMTXT"))
	   )
     )
     (initget 1)
     (setq p1 (getpoint "\nSpécifiez le premier point d'origine: "))
     (initget 1)
     (setq p2	(getpoint p1 "\nSpécifiez le second point d'origine: ")
    mid	(mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.0)) p1 p2)
     )
     (initget 1)
     (setq p3 (getpoint mid "\nSpécifiez la position de la cote : ")
    cw (clockwise-p p1 p2 p3)
    p3 (polar mid
	      ((if cw - +) (angle p1 p2) (/ pi 2))
	      scl
       )
     )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     ;; Création du bloc s'il n'existe pas
     (if (vl-catch-all-error-p
    (vl-catch-all-apply
      'vla-item
      (list Blocks "cotation-type-topo")
    )
  )
(progn
  (setq	bl (vla-add Blocks
		    (vlax-3d-point '(0 0 0))
		    "cotation-type-topo"
	   )
	pl (vlax-invoke
	     bl
	     'addLightWeightPolyline
	     (list 0.0 0.0 2.0 -1.0 3.0 -1.0)
	   )
  )
  (vla-setBulge pl 0 (- (sqrt 5) 2))
  (vla-setWidth pl 1 (/ 1.0 3) 0)
  (vla-put-Layer pl "0")
)
     )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     (setq zdir (trans '(0 0 1) 1 0 T))
     (vla-StartUndoMark AcDoc)
     (foreach p '(p1 p2 p3 mid)
(set p (trans (eval p) 1 0))
     )
     (setq ang	(angle (trans p1 0 zdir) (trans p2 0 zdir))
    ref	(vla-InsertBlock
	  Space
	  (vlax-3d-point p1)
	  "cotation-type-topo"
	  scl
	  scl
	  1.0
	  ang
	)
     )
     (vla-put-Normal ref (vlax-3d-point zdir))
     (if (not cw)
(progn
  (setq
    tmp	(vla-mirror ref (vlax-3d-point p1) (vlax-3d-point p2))
  )
  (vla-delete ref)
  (setq ref tmp)
)
     )
     (vla-mirror ref (vlax-3d-point mid) (vlax-3d-point p3))
     (setq txt	(vla-addText
	  Space
	  (rtos	(distance p1 p2)
		(getvar "DIMLUNIT")
		(getvar "DIMDEC")
	  )
	  (vlax-3d-point p3)
	  scl
	)
     )
     (vla-put-StyleName (getvar "DIMTXSTY"))
     (vla-put-Alignment txt 10)
     (vla-put-TextAlignmentPoint txt (vlax-3d-point p3))
     (vla-rotate txt (vlax-3d-point p3) ang)
     (vla-put-Normal txt (vlax-3d-point zdir))
     (vla-EndUndoMark AcDoc)
   )
 )
 (princ)
)

;;; Clockwise-p Retourne T si les points p1 p2 et p3 tournent dans le sens horaire

(defun clockwise-p (p1 p2 p3)
 ()

[Edité le 1/9/2007 par (gile)]

lili2006 · le 1 septembre 2007

Re,

Je pense que là, on approche la perfection. Dommage, je n'ai pas covadis sous le coude. Il me semble que les flêches sont un chouia + petite, mais bon, faut tout de même pas exagérer, je pense que cette mouture va correspondre aux besoins de merna . Aprés tout, c'est lui le demandeur,...

Merci encore (gile) pour ce travail qui risque d'interesser d'autres personnes sur ce forum !

Comparaisons des trois techniques :(Oups, sur la droite, j'ai oublié de supprimer les flêches de la 1er cotation avec la première mouture,...)

(gile) · le 1 septembre 2007

lili2006,

Tu as du aussi oublier de purger l'ancien bloc "cotation-type-topo", le nouveau, aligné avec le texte n'a donc pas été créé

Premiére version :

http://img169.imageshack.us/img169/3779/cottopo1xm2.png

Deuxième version :

http://img169.imageshack.us/img169/3310/cottopo2vq2.png

bonuscad · le 1 septembre 2007

Salut (gile)

Ton code ne passe pas sous 2005.

Ca bloque à ce niveau:

(vla-get-Blocks AcDoc)
; erreur: Erreur Automation Pas de base de données

De mon coté j'ai essayé avec (entmake) pour créer le style de cotation, mais il me reste quelque problème de validation de certaines options (les blocs flèche personnalisés et le style de texte) qui ne sont pas pris en compte, je suis obligé de revenir dans le style pour les valider manuellement car il sont présent dans les liste de choix. Donc .... je ne propose pas encore.

lili2006 · le 1 septembre 2007

Re,

Absolument exact (gile), donc rien à redire, ce type de cotation semble tout à fait adapter à la représentation topo.

Merci encore.

merna · le 1 septembre 2007

Bonjour à tous j'ai essayé et ça correspond ce que je cherche.

Merci à tous et spécialement à Gile pour le lisp. Je n'ai plus qu'à préparer mes échelles courantes pour l'échelle de cote désirée.

C'est cool.

A plus.

(gile) · le 1 septembre 2007

Une version, pur AutoLISP, qui devrait marcher dans toutes les versions d'AutoCAD (et ses clones) et qui fonctionne aussi quelque soit le SCU courant (j'ai aussi modifé celle ci-dessus dans ce sens).

(defun c:cot-topo (/ p1 p2 mid ang p3 scl cw bl pl ang ref tmp txt)
 (if (= 1 (getvar "CVPORT"))
   (alert
     "Cette commande ne peut être utilisée que dans l'espace objet."
   )
   (progn
     (initget 1)
     (setq p1 (getpoint "\nSpécifiez le premier point d'origine: "))
     (initget 1)
     (setq p2	(getpoint p1 "\nSpécifiez le second point d'origine: ")
    mid	(mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.0)) p1 p2)
     )
     (initget 1)
     (setq p3	(getpoint mid "\nSpécifiez la position de la cote : ")
    scl	(if (zerop (getvar "DIMSCALE"))
	  (getvar "DIMTXT")
	  (* (getvar "DIMSCALE") (getvar "DIMTXT"))
	)
    cw	(clockwise-p p1 p2 p3)
    p3	(polar mid
	       ((if cw  -  +) (angle p1 p2) (/ pi 2))
	       scl
	)
     )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     ;; Création du bloc s'il n'existe pas
     (if (null (tblsearch "BLOCK" "cotation-type-topo"))
(progn
  (entmake
    (list '(0 . "BLOCK")
	  '(100 . "AcDbEntity")
	  '(8 . "0")
	  '(100 . "AcDbBlockBegin")
	  '(2 .  "cotation-type-topo")
	  '(70 . 2)
	  '(10 0.0 0.0 0.0)
    )
  )
  (entmake
    (list '(0 . "LWPOLYLINE")
	  '(100 . "AcDbEntity")
	  '(8 . "0")
	  '(100 . "AcDbPolyline")
	  '(70 . 0)
	  '(90 . 3)
	  '(10 0.0 0.0)
	  (cons 42 (- (sqrt 5) 2))
	  '(10 2.0 -1.0)
	  (cons 40 (/ 1.0 3))
	  '(41 . 0.0)
	  '(10 3.0 -1.0)
    )
  )
  (entmake
    (list '(0 . "ENDBLK") '(8 . "0"))
  )
)
     )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     (setq zdir (trans '(0 0 1) 1 0 T)
    inv	 (trans '(0 0 -1) 1 0 T)
     )
     (foreach p '(p1 p2 p3 mid)
(set p (trans (eval p) 1 zdir))
     )
     (setq ang (angle p1 p2))
     (entmake
(list '(0 . "INSERT")
      '(2 . "cotation-type-topo")
      (cons 10 p1)
      (cons 41 scl)
      (cons 42 scl)
      (cons 50 ang)
      (cons 210 zdir)
)
     )
     (setq ref (entget (entlast)))
     (if (not cw)
(progn
  (foreach p '(p1 p2)
    (set p (trans (eval p) zdir inv))
  )
  (entmod
    (setq ref (subst (cons 10 p1)
		     (assoc 10 ref)
		     (subst (cons 50 (angle p1 p2))
			    (assoc 50 ref)
			    (subst (cons 210 inv)
				   (assoc 210 ref)
				   ref
			    )
		     )
	      )
    )
  )
)
     )
     (foreach p '(p1 p2)
(set p (trans (eval p) zdir inv))
     )
     (entmake
(subst (cons 10 p2)
       (assoc 10 ref)
       (subst (cons 50 (angle p2 p1))
	      (assoc 50 ref)
	      (subst (cons 210 (mapcar '- (cdr (assoc 210 ref))))
		     (assoc 210 ref)
		     ref
	      )
       )
)
     )
     (entmake
(list '(0 . "TEXT")
      (cons 10 p3)
      (cons 40 scl)
      (cons 1
	    (rtos (distance p1 p2)
		  (getvar "DIMLUNIT")
		  (getvar "DIMDEC")
	    )
      )
      (cons 50 ang)
      (cons 7 (getvar "DIMTXSTY"))
      '(72 . 1)
      (cons 11 p3)
      '(73 . 2)
      (cons 210 zdir)
)
     )
   )
 )
 (princ)
)

;;; Clockwise-p Retourne T si les points p1 p2 et p3 tournent dans le sens horaire

(defun clockwise-p (p1 p2 p3)
 ()

bonuscad · le 1 septembre 2007

J'ai réussi à achever la définition par (entmake)

Ceci va créer automatiquement un style de cotation (donc associatif, s'y on veut)

Il essaye de faire ce qui est demandé, mais pour voir vraiment le résultat, IL FAUT faire un aperçu de tracé

Ce style est défini et courant, il suffit de lancer une commande de cotation.

Copier ce qui suit directement en ligne de commande pour essayer.

(progn
(if (not (tblsearch "STYLE" "cotes-levées"))
(entmake
'(
(0 . "STYLE")
(100 . "AcDbSymbolTableRecord")
(100 . "AcDbTextStyleTableRecord")
(2 . "cotes-levées")
(70 . 0)
(40 . 0.0)
(41 . 1.0)
(50 . 0.0)
(71 . 0)
(42 . 2.5)
(3 . "simplex.shx")
(4 . "")
)
)
)
    (if (not (tblsearch "BLOCK" "cotes_levées1"))
      (progn
 (entmake
   '((0 . "BLOCK") (8 . "0") (2 . "cotes_levées1") (70 . 2) (4 . "") (8 . "0") (6 . "ByBlock") (370 . -2) (10 0.0 0.0 0.0))
 )
(entmake
'(
(0 . "LWPOLYLINE")
(100 . "AcDbEntity")
(67 . 0)
(410 . "Model")
(8 . "0")
(62 . 256)
(6 . "ByBlock")
(370 . -2)
(100 . "AcDbPolyline")
(90 . 3)
(70 . 0)
(38 . 0.0)
(39 . 0.0)
(10 -2.5 0.0)
(40 . 0.25)
(41 . 0.0)
(42 . 0.247582)
(10 -0.567325 1.01948)
(40 . 0.822061)
(41 . 0.0)
(42 . 0.117565)
(10 0.0 2.5)
(40 . 0.0)
(41 . 0.0)
(42 . 0.117565)
(210 0.0 0.0 1.0)
)
)
 (entmake '((0 . "ENDBLK") (8 . "0") (8 . "0") (6 . "ByBlock") (370 . -2)))
      )
   )
    (if (not (tblsearch "BLOCK" "cotes_levées2"))
      (progn
 (entmake
   '((0 . "BLOCK") (8 . "0") (2 . "cotes_levées2") (70 . 2) (4 . "") (8 . "0") (6 . "ByBlock") (370 . -2) (10 0.0 0.0 0.0))
 )
(entmake
'(
(0 . "LWPOLYLINE")
(100 . "AcDbEntity")
(67 . 0)
(410 . "Model")
(8 . "0")
(62 . 256)
(6 . "ByBlock")
(370 . -2)
(100 . "AcDbPolyline")
(90 . 3)
(70 . 0)
(38 . 0.0)
(39 . 0.0)
(10 -2.5 0.0)
(40 . 0.25)
(41 . 0.0)
(42 . -0.247582)
(10 -0.567325 -1.01948)
(40 . 0.822061)
(41 . 0.0)
(42 . -0.117565)
(10 0.0 -2.5)
(40 . 0.0)
(41 . 0.0)
(42 . -0.117565)
(210 0.0 0.0 1.0)
)
)
 (entmake '((0 . "ENDBLK") (8 . "0") (8 . "0") (6 . "ByBlock") (370 . -2)))
      )
   )
(if (not (tblsearch "DIMSTYLE" "cotes-levées"))
(entmake
'(
(0 . "DIMSTYLE")
(100 . "AcDbSymbolTableRecord")
(100 . "AcDbDimStyleTableRecord")
(2 . "cotes-levées")
(70 . 0)
(3 . "")
(4 . "")
(5 . "")
(6 . "cotes_levées1")
(7 . "cotes_levées2")
(40 . 1.0)
(41 . 2.5)
(42 . 0.625)
(43 . 0.0)
(44 . 1.25)
(45 . 0.0)
(46 . 0.0)
(47 . 0.0)
(48 . 0.0)
(140 . 2.5)
(141 . 2.5)
(142 . 0.0)
(143 . 0.0393701)
(144 . 1.0)
(145 . 0.0)
(146 . 1.0)
(147 . 0.625)
(71 . 0)
(72 . 0)
(73 . 0)
(74 . 0)
(75 . 1)
(76 . 1)
(77 . 0)
(78 . 0)
(170 . 0)
(171 . 3)
(172 . 1)
(173 . 1)
(174 . 1)
(175 . 0)
(176 . 255)
(177 . 0)
(178 . 0)
(270 . 2)
(271 . 2)
(272 . 2)
(273 . 2)
(274 . 3)
(275 . 0)
(280 . 0)
(281 . 0)
(282 . 0)
(283 . 0)
(284 . 8)
(285 . 0)
(286 . 0)
(287 . 5)
(288 . 0)
)
)
)
(command "_.-dimstyle" "_restore" "cotes-levées")
(setvar "DIMTXSTY" "cotes-levées")
(setvar "DIMBLK1" "cotes_levées1")
(setvar "DIMBLK2" "cotes_levées2")
)

(gile) · le 1 septembre 2007

Encore une fois, BRAVO !!!

là ce sont de "vraies cotes", pas un bidouillage comme ce que j'ai fait ;)

bonuscad · le 1 septembre 2007

Merci,

Mais il se peut que cette solution ne convienne pas à la demande, en effet si c'est vraiment un croquis et que les dimensions soient forcées, ben... il faudra éditer les cotes.

Alors ta routine reste une solution (d'ailleurs la seconde version fonctionne sous 2005). ;)

fabdo · le 3 septembre 2007

Bonjour à tous,

Je n'ai pas encore testé, mais juste une question, est-il possible de gérer les décimales: je veux dire que pour une cote qui serait de 14.8 obtenir 14.80?

Merci à tous.

rebcao · le 3 septembre 2007

Je me suis amusé à faire ça simplement avec deux styles de Cote avec une version LT 2005

http://www.rebcao.fr/cadxp/cote_TOPO_arc.png

Christian

bonuscad · le 3 septembre 2007

est-il possible de gérer les décimales: je veux dire que pour une cote qui serait de 14.8 obtenir 14.80?

variable "DIMDEC" à 2, mais aussi s'assurer que "DIMZIN" est < à 8, voir l'aide... pour de plus amples renseignements.

bonuscad · le 3 septembre 2007

avec deux styles de Cote avec une version LT 2005

Dis moi Christian, tu saisis deux fois les points d'attaches ou tu fais ça avec une macro diesel?

mdsv31 · le 3 septembre 2007

Dans les cotations, si ont crées une flêches utilisateur, es que c'est possible?

@+

MDSV41

bonuscad · le 3 septembre 2007

Dans les cotations, si ont crées une flêches utilisateur, es que c'est possible?

C'est exactement ce que je propose a travers (entmake), je crée 2 blocs qui sont attribués aux flèches.

Donc le style que j'ai proposé est tout à fait modifiable et aurait pu être crée manuellement par le style de cotation.

rebcao · le 3 septembre 2007

Pour l'instant tout ça c'est sans Macro... Mais une ou plusieurs Macros seraient nécessaqires pour optimiser l'ensemble ! ;)

en fait j'utilise la méthode par sélection et je reste sur place

Christian

PS : certaines images sont un peu trop larges dans ce sujet ! :( Si chacun pouvait réduire son image ? Merci ;)

[Edité le 3/9/2007 par rebcao]

Connexion

Cotation type topo

Messages recommandés

merna

lili2006

lili2006

merna

lili2006

winfield

(gile)

lili2006

(gile)

lili2006

(gile)

bonuscad

lili2006

merna

(gile)

bonuscad

(gile)

bonuscad

fabdo

rebcao

bonuscad

bonuscad

mdsv31

bonuscad

rebcao

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante