Ne pas effacer les .sv$ en quittant

[mouais.mouais]

Bonjour !

 

Est-il possible de configurer Autocad pour que les fichiers de sauvegarde automatique sv$ ne soient pas effacés lorsque l'on quitte proprement Autocad ?

 

Un collègue ne sauvegardant pas souvent a voulu sortir de l'éditeur de bloc sans enregistrer et a en fait fermé son fichier en refusant l'enregistrement. Résultat, 4h perdues.

Il semble que sur la version précedemment utilisée (R14), ces fichiers n'étaient pas effacés, à la manière des .bak. Ce n'est pas le cas avec la version 2007.

 

Merci pour votre aide !

 

Thomas

[Joffoon]

Salut,

 

As-tu était jeter un coup d'oeil du coté de "C:\Documents and Settings\Collègue\Local Settings\Temp"

 

Normalement Autocad les ranges ici..

 

Si non, dans Autocad, click droit Options, onglet Fichiers puis tu vas sur Emplacement du fichier d'enregistrement automatique et tu redéfinis le chemin..

 

A+,

 

Joff

[mouais.mouais]

Merci pour la réponse, mais ce que je cherche à savoir, c'est s'il est possible qu'autocad n'efface pas ces fichiers lorsque l'on quitte proprement le logiciel. Dans mon cas, ça veut dire que si l'on quitte sans enregistrer un fichier .dwg, il reste un enregistrement automatique .sv$ datant d'il y a quelques minutes dans le répertoire temp définit dans options/Fichiers/...

 

 

[Patrick_35]

Salut

Oui, il va falloir programmer via les réacteurs.

 

@+

[mouais.mouais]

Ah.

 

Du genre :

 

Evenement "fermer sans enregistrer"

faire une copie du sv$

fin évènement

 

C'est ce à quoi tu penses ?

 

Merci !

 

Thomas

[Patrick_35]

Pas exactement ;)

--> Fermer le dessin (évenement :vlr-beginClose du réacteur vlr-dwg-reactor)

--> Vérifier si le dessin n'a pas été modifié (variable dbmod) pour lancer ou pas les copies

--> Copier les SV$ dans un répertoire prédéfini (par exemple avec un vl-file-copy et après avoir vérifié l'espace disque restant du lecteur destinataire)

 

@+

[Patrick_35]

Salut

Je me suis amusé à faire un petit truc sympa

 

(defun deplacer_fichiers_sv$(obj rea / des fic fso lec lst sav tit msgbox)

 (defun MsgBox (Titre Bouttons Message / Reponse WshShell)
   (acad-push-dbmod)
   (setq WshShell (vlax-create-object "WScript.Shell")
  Reponse (vlax-invoke WshShell 'Popup Message 0 Titre (itoa Bouttons)))
   (vlax-release-object WshShell)
   (acad-pop-dbmod)
   Reponse
 )

 (if (> (getvar "dbmod") 0)
   (progn
     (setq fso (vlax-create-object "Scripting.FilesystemObject")
    lec (vl-catch-all-apply 'vlax-invoke-method (list fso 'getdrive (setq des (substr (getvar "dwgprefix") 1 2))))
    sav (vla-get-autosavepath (vla-get-files (vla-get-preferences (vlax-get-acad-object))))
    lst (vl-directory-files sav (strcat (vl-filename-base (getvar "dwgname")) "*.sv$") 1)
    tit "Déplacement des fichiers de sauvegarde (*.sv$)"
    tot 0
     )
     (if (not (vl-catch-all-error-p lec))
(progn
  (foreach fic lst
    (setq tot (+ tot (vlax-get (vlax-invoke fso 'getfile (strcat sav fic)) 'size)))
  )
  (if (< tot (vlax-get lec 'freespace))
    (foreach fic lst
      (if (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list (vlax-invoke fso 'getfile (strcat sav fic)) 'move (getvar "dwgprefix"))))
	(msgbox tit 48 (strcat "\nErreur lors de la tentative de déplacement du fichier\n" fic))
      )
    )
    (msgbox tit 16 (strcat "\nPlus de place disponible sur le lecteur " des))
  )
)
(msgbox tit 16 (strcat "\nErreur d'accès sur le lecteur " des))
     )
   )
 )
 (vlax-release-object fso)
 (princ)
)

(or rea_sv$
 (setq rea_sv$ (vlr-dwg-reactor nil (list (cons :vlr-beginclose (function deplacer_fichiers_sv$)))))
)
(princ)

 

@+