lenteur A2008

[hugo200120012]

Etes vous confrontés sur certains plans, a une très grande lenteur lors des copier/coller ou insérer blocs sur A2008, alors que le même plans avec A2007 se comporte très bien??

 

[BIM G CO]

Le copier coller de windows de manière général est nocif pour tous les documents même dans Word ou Excel par exemple. J'ai abandonné le copier/coller depuis bien longtemps!

 

Je crée des blocs, des groupes, des références externes mais je m'abstiens d'utiliser DesignCenter qui modifie les variables INSUNITSDEFTARGET et INSUNITDEFSOURCE de manière invisible.

 

[Edité le 11/7/2007 par Maximilien]

[hugo200120012]

Je n’utilise pas moi non plus, le copier/coller, c'était pour faire simple, j’utilise un lisp qui crée un bloc et un autre pour insérer ce bloc aux coordonnés d'origine, et ça marchait depuis autocad 14, jusqu'a A2008 mais voila sur certain plan Avec A2008 c'est hyper lent d'insérer le bloc alors que sur A 2007 c'est instantané

Voila

Une idée??

 

 

 

[fabon]

Il y a un souci flagrant au niveau du copier/coller en ce qui concerne les échelles personnalisées (Format --> Liste des échelles). AutoCAD 2008 rapatrie dans le dessin de destination les échelles non existantes venant du dessin source. Idem pour les XREFS et les WBLOCS, la liste des échelles explose....

[lecrabe]

 

Hello

 

Je ne fais jamais de copier / coller surtout avec AutoCAD :exclam:

et je le déconseille formellement !

 

Passer donc par un WBLOC et surveiller vos unités SVP ! :P

 

Mais d'un autre coté c bien pratique avec Excel, Word, etc ... :)

 

Le Decapode

 

[hugo200120012]

Ok on s'en fou des Copier/coller, le Pb c'est avec l'insertion d'un wbloc, et la c'etait super chiant jusqu'a 2 minutes d'attentes...

 

[lecrabe]

 

Hello

 

Désolé mais je n"ai pas d'AutoCAD 2008 sous la main ...

( J'ai seulement tous les AutoCADs depuis la 2002 jusqu'à la 2007 )

 

Que se paase t-il si le DWG que tu tentes d'insérer a été par exemple sauvegardé en version DWG 2004 voire même en version DWG 2000 !?

 

As tu toujours le problème ?

 

Le Decapode

 

[hugo200120012]

Nan ça dépend du plan archi...

Si il est pollué par je sais pas quoi l'insertion, sur celui ci prend plusieurs minutes, de plus si je prends le plus petit des éléments sur ce plan pollué, et que je l'insère sur un plan neuf c'est le même problème.

Par contre sur la majorité des plans et sur les plans neuf (fichier/nouveau...) il y a pas de problèmes...

 

 

[lecrabe]

 

Hello

 

SVP peux tu sauvegarder le DWG qui pose problème en format DWG2004

et me l'envoyer (si bien sur, il n'est pas top-secret) ?

 

cadxp at hotmail.fr

 

Le Decapode

 

[hugo200120012]

Ce n'est pas utile ca mes mes autres autocads 2007 et 2006 il n'y a pas de pb les insertions sont tres rapides?? ca bloque qu'avec A2008

 

[Goldorak]

Ton matériel n'est peut-être pas assez récent, il faut le faire évoluer. :calim:

 

Sinon j'ai un collègue qui est passé sur 2008 et ça rame aussi selon lui pourtant sur une config toute neuve.

 

Le passage à la 2008 se justifie-t-il vraiment? Parfois il vaut mieux laisser les early-adopters faire jaillir tous les bugs, et puis migrer plus tard une fois que c'est plus propre.

[lecrabe]

 

Bonsoir

 

D'aillleurs un SP1 pour AutoCAD 2008 va bientôt sortir !

 

Il va peut être améliorer les choses ...

 

Le Decapode

 

[hugo200120012]

je viens de le metre c'est tj aussi lent pour inserer ces wbloc

 

[jeff_64]

Bonjour,

 

j'ai moi aussi ce problème mais pas uniquement avec le copier coller.

 

Je m'explique :

- ouverture d'un fichier comportant des xref : environ 8mn (pb avec un autre poste identique)

- mise à jour de xref ou "lier" un xref : environ 8mn

- copier/coller : entre 5 à 15mn

 

Mon poste est récent avril 2007, on l'a masterisé 2 fois, version 2008sp1 d'Autocad.

 

Quand je fais format, liste des échelles, le message est le suivant :

Une exception non gérée s'est produite dans un composant de votre application. Si vous cliquez sur continuer, votre application va ignorer cette erreur et essayer de continuer. L'index se trouve en dehors des limites du tableau

En bas il y a :

Lorsque le débogage juste-à-temps est activé, les exceptions non gérées

seront envoyées au débogueur JIT inscrit sur l'ordinateur

plutôt que d'être gérées par cette boîte de dialogue.

Quand je clic sur continuer, rien ne se passe...

Merci par avance

:( :( :(

[brosseau]

Bonjour, je pense que cela vient des echelles d'annotations qui se cumules avec les copier/coller.

Le remede est simple, tapez:

-modiflistechelle

R pour redéfinir

Q pour quitter.

 

Bonne soirée.

[jeff_64]

Bonjour,

merci pour votre conseil mais j'ai un message d'erreur qui est celui mentionné dans mon message plus haut.

Snif...

 

[brosseau]

Bonjour,

Avez vous bien essayé avec la commande en ligne "tiret du moins en premier"

 

-modiflistechelle

R pour redéfinir

Q pour quitter.

 

Car à la différence de la commande qui ouvre une boite de dialogue, cette commande ne cherche pas à charger la liste et donc ne plante pas!

 

[hugo200120012]

Le bug est connu maintenant il faut appliquer une purger de la liste de echelles

[lesourd2]

Salut à tous

 

Un petit bout de code pour purger le liste des echelles:

 

 

 ;;;permet de supprimer une tres grande liste d'echelles
;;;commande:SCALELISTDELALL
;;; ==========================================================================
;;; File: ScaleListDel.lsp
;;; Purpose: Scale list deletion and management for AutoCAD 2008
;;; Author: Steve Johnson
;;; Date: 13 August 2007
;;; Version: 0.7
;;; Copyright: (c) 2007 cad nauseam (www.cadnauseam.com)
;;; May be distributed and used freely provided this header is retained in full
;;; --------------------------------------------------------------------------
;;; Disclaimer:
;;; This code is supplied as-is and with no warranty whatsoever.
;;; Destruction of annotative objects WILL result from incorrect use.
;;; Use at own risk. No responsibility accepted. Read all notes before use.
;;; --------------------------------------------------------------------------
;;; Commands:
;;;  SCALELISTDEL
;;;   Deletes unused scales except 1:1 using a user-provided wildcard.
;;;  SCALELISTDELALL
;;;   Deletes all unused scales except 1:1.
;;;  SCALELISTDELINCH
;;;   Deletes all unused scales that contain the inch " character.
;;;  SCALELISTDELXREF
;;;   Deletes all unused scales that contain the "_XREF" string.
;;;  SCALELISTDEL_
;;;   Deletes all unused scales that contain the "_" character.
;;;  SCALELISTDELINCHXREF
;;;   Deletes all unused scales that contain either the inch " character or
;;;   the "_XREF" string.
;;;  SCALELISTDELINCH_
;;;   Deletes all unused scales that contain either the inch " or "_"
;;;   characters.
;;;  SCALELISTMETRIC
;;;   Deletes all existing unused scales except 1:1 and sets up metric scales.
;;;  SCALELISTMETRICTEMPLATE
;;;   Deletes all existing scales and sets up metric scales. For use only in
;;;   setting up scales in templates and pre-2008 drawings.
;;;   WARNING: potentially destructive to annotative objects!
;;;  SCALELISTINCH
;;;   Deletes all existing unused scales except 1:1 and sets up inch-based
;;;   scales.
;;;  SCALELISTINCHTEMPLATE
;;;   Deletes all existing scales and sets up inch-based scales. For use
;;;   only in setting up scales in templates and pre-2008 drawings.
;;;   WARNING: potentially destructive to annotative objects!
;;; --------------------------------------------------------------------------
;;; Functions:
;;;  (scaledel_all_unsafe)
;;;   Deletes all scales in the current drawing, including 1:1 and scales in
;;;   use.
;;;   WARNING: potentially destructive to annotative objects!
;;;  (scaledel_wcard_unsafe WCARD-OR-LIST)
;;;   If WCARD-OR-LIST is a wildcard string, deletes scales that match that
;;;   wildcard, excluding 1:1 but including scales in use.
;;;   If WCARD-OR-LIST is a list of scale names, deletes those scales,
;;;   including 1:1 (if listed) and scales in use.
;;;   WARNING: potentially destructive to annotative objects!
;;;  (scaledel_long_xref LONG-SCALE-LIST)
;;;   Cleans up those scales that are too long to delete using the command-line
;;;   (i.e. over 132 characters). These are usually only those created by the
;;;   AutoCAD 2008 pre-SP1 bug that created _XREF_XREF_XREF scales, and this
;;;   is checked before deletion.
;;;  (scaledel_warning)
;;;   Issues a warning and asks user to enter Yes before continuing.
;;;  (scaledel_get_scalelist)
;;;   Returns a list of scales in the drawing.
;;;  (scaledel_all)
;;;   Deletes all scales other than 1:1 and scales in use.
;;;  (scaledel_reset)
;;;   Performs a -SCALELIST Reset command.
;;;  (scaledel_smart_reset)
;;;   Performs a -SCALELIST Reset command if it is likely to reduce the number
;;;   of scales in the list, prior to setting things up.
;;;  (scaledel_wcard WCARD)
;;;   Deletes scales that match WCARD, excluding 1:1 and scales in use.
;;;  (scaledel_create_scales SCALES)
;;;   Creates a set of scales defined in list SCALES.
;;;  (scaledel_create_metric)
;;;   Creates a set of metric scales: see *** in code to adjust list.
;;;  (scaledel_create_inch)
;;;   Creates a set of inch scales: see *** in code to adjust list.
;;; --------------------------------------------------------------------------
;;; Notes:
;;; Other than the SCALELIST*TEMPLATE commands, the commands will not delete
;;; the 1:1 scale, even if it is not in use. This is because if the scale list
;;; is completely cleared, AutoCAD 2008 will automatically recreate it using
;;; its hardwired list when the user picks the "Custom..." item that
;;; remains in the list. Leaving in the 1:1 scale prevents this from happening.
;;; The (scaledel_*_unsafe) functions can be used to delete all scales,
;;; including 1:1 and those in use, if you really need to do so.
;;; --------------------------------------------------------------------------
;;; Later AutoCAD releases:
;;; As AutoCAD 2008's annotative scaling feature needs work, it is quite likely
;;; that future releases of AutoCAD will do things differently. This may result
;;; in this software failing to work correctly, or working with unintended
;;; results. Check carefully before using this software in 2009 and later.
;;; --------------------------------------------------------------------------
;;; WARNING:
;;; Any function that uses the (scaledel_*_unsafe) functions may be DESTRUCTIVE
;;; to any annotative objects in the drawing, because they allow the deletion
;;; of scales that are in use.
;;; ==========================================================================


(if (>= (atof (substr (getvar "ACADVER") 1 4)) 17.1)
 (progn ; Only define these functions if they will work (ie. 2008 or later)


   (prompt "\nLoading ScaleListDel.lsp Version 0.7... ")
;;; --------------------------------------------------------------------------
;;; Commands


   (defun C:SCALELISTDEL (/ wcard)
     (setq wcard (getstring "\nEnter scale name(s) to delete: "))
     (if (/= wcard "")
       (scaledel_long_xref (scaledel_wcard wcard))
     )
     (princ)
   ) ; End C:SCALELISTDEL


   (defun C:SCALELISTDELALL ()
     (scaledel_all)
     (princ)
   ) ; End C:SCALELISTDELXREF


   (defun C:SCALELISTDELXREF ()
     (scaledel_long_xref (scaledel_wcard "*_XREF"))
     (princ)
   ) ; End C:SCALELISTDELXREF


   (defun C:SCALELISTDEL_ ()
     (scaledel_long_xref (scaledel_wcard "*_*"))
     (princ)
   ) ; End C:SCALELISTDEL_


   (defun C:SCALELISTDELINCH ()
     (scaledel_long_xref (scaledel_wcard "*\"*"))
     (princ)
   ) ; End C:SCALELISTDELINCH


   (defun C:SCALELISTDELINCHXREF ()
     (scaledel_long_xref (scaledel_wcard "*\"*,*_XREF"))
     (princ)
   ) ; End C:SCALELISTDELINCHXREF


   (defun C:SCALELISTDELINCH_ ()
     (scaledel_long_xref (scaledel_wcard "*\"*,*_*"))
     (princ)
   ) ; End C:SCALELISTDELINCHXREF


   (defun C:SCALELISTMETRIC ()
     (scaledel_smart_reset)
     (prompt "\nDeleting existing unused scales...")
     (scaledel_long_xref (scaledel_wcard "*"))
     (prompt "\nCreating metric scales...")
     (scaledel_create_metric)
     (princ)
   ) ; End C:SCALELISTMETRIC


   (defun C:SCALELISTMETRICTEMPLATE ()
     (if (= (scaledel_warning) "Yes")
       (progn
         (scaledel_smart_reset)
         (prompt "\nDeleting all existing scales...")
         (scaledel_all_unsafe)
         (prompt "\nCreating metric scales...")
         (scaledel_create_metric)
       )
     )
     (princ)
   ) ; End C:SCALELISTMETRICTEMPLATE


   (defun C:SCALELISTINCH ()
     (scaledel_smart_reset)
     (prompt "\nDeleting existing unused scales...")
     (scaledel_wcard "*")
     (prompt "\nCreating inch scales...")
     (scaledel_create_inch)
     (princ)
   ) ; End C:SCALELISTINCH


   (defun C:SCALELISTINCHTEMPLATE ()
     (if (= (scaledel_warning) "Yes")
       (progn
         (scaledel_smart_reset)
         (prompt "\nDeleting all existing scales...")
         (scaledel_all_unsafe)
         (prompt "\nCreating inch scales...")
         (scaledel_create_inch)
       )
     )
     (princ)
   ) ; End C:SCALELISTINCHTEMPLATE


;;; --------------------------------------------------------------------------
;;; Functions


   (defun scaledel_all_unsafe (/ scale-en-list)
     (foreach item (dictsearch (namedobjdict) "ACAD_SCALELIST")
       (if (= 350 (car item))
         (setq scale-en-list (cons (cdr item) scale-en-list))
       )
     )
     (foreach item scale-en-list
       (entdel item)
     )
   ) ; End scaledel_all_unsafe


   (defun scaledel_wcard_unsafe (WCARD-OR-LIST / scale-list scale)
     (foreach item (dictsearch (namedobjdict) "ACAD_SCALELIST")
       (if (= 350 (car item))
         (setq
           scale-list
           (cons
             (cons (strcase (cdr (assoc 300 (entget (cdr item))))) (cdr item))
             scale-list
           )
         )
       )
     )
     (if (= (type WCARD-OR-LIST) 'STR)
       (foreach item scale-list
         (if
           (and
             (wcmatch (car item) (strcase WCARD))
             (/= (car item) "1:1")
           )
           (entdel (cdr item))
         )
       )
       (foreach item WCARD-OR-LIST
         (if (setq scale (assoc (strcase item) scale-list))
           (entdel (cdr scale))
         )
       )
     )
   ) ; End scaledel_wcard_unsafe


   (defun scaledel_long_xref (LONG-SCALE-LIST / scale-list)
     (foreach scale LONG-SCALE-LIST
       (if (wcmatch (strcase scale) "*_XREF_XREF_XREF*")
         (setq scale-list (cons scale scale-list))
       )
     )
     (if scale-list
       (progn
         (prompt "\nDeleting the following long _XREF scale(s):")
         (foreach scale scale-list
           (prompt (strcat "\n " scale))
         )
         (scaledel_wcard_unsafe scale-list)
       )
     )
   ) ; End scaledel_long_xref


   (defun scaledel_warning ()
     (initget "Yes No")
     (getkword
       (strcat
         "\nThis command will first destroy all existing scales including those in use."
         "\nAre you sure you want to do this? [Yes/No] : "
       )
     )
   ) ; End scaledel_warning


   (defun scaledel_get_scalelist (/ scale-list)
     (foreach item (dictsearch (namedobjdict) "ACAD_SCALELIST")
       (if (= 350 (car item))
         (setq
           scale-list
           (cons (strcase (cdr (assoc 300 (entget (cdr item))))) scale-list)
         )
       )
     )
     scale-list
   ) ; End scaledel_get_scalelist


   (defun scaledel_all ()
     (scaledel_smart_reset)
     (scaledel_long_xref (scaledel_wcard "*"))
   ) ; End scaledel_all


   (defun scaledel_reset (/ cmdecho)
     (setq cmdecho (getvar "CMDECHO"))
     (setvar "CMDECHO" 0)
     (command "_.-SCALELISTEDIT" "_R" "_Y" "_E")
     (setvar "CMDECHO" cmdecho)
   ) ; End scaledel_reset


   (defun scaledel_smart_reset ()
     (if (> (length (scaledel_get_scalelist)) 40)
       (scaledel_reset)
     )
   ) ; End scaledel_smart_reset


   (defun scaledel_wcard (WCARD / scale-list cmdecho long-scale-list)
     (foreach scale (scaledel_get_scalelist)
       (if
         (and
           (wcmatch (strcase scale) (strcase WCARD))
           (/= scale "1:1")
         )
         (setq scale-list (cons scale scale-list))
       )
     )
     (if scale-list
       (progn
         (setq cmdecho (getvar "CMDECHO"))
         (setvar "CMDECHO" 0)
         (command "_.-SCALELISTEDIT")
         (foreach item scale-list
           (if (<= (strlen item) 132)
             (command "_D" item) ; Attempt to delete scale
             (setq long-scale-list (cons item long-scale-list))
           )
         )
         (command "_E")
         (setvar "CMDECHO" cmdecho)
       )
     )
     long-scale-list ; Returns list of scales too long to delete
   ) ; End scaledel_wcard


   (defun scaledel_create_scales (SCALES / scale-list-all cmdecho)
     (setq
       scale-list-all (scaledel_get_scalelist)
       cmdecho (getvar "CMDECHO")
     )
     (setvar "CMDECHO" 0)
     (command "_.-SCALELISTEDIT")
     (foreach scale SCALES
       (if (not (member (strcase (car scale)) scale-list-all))
         (command "_A" (car scale) (cadr scale))
       )
     )
     (command "_E")
     (setvar "CMDECHO" cmdecho)
   ) ; End scaledel_create_scales


;;; --------------------------------------------------------------------------
;; *** Note: several uncommon scales have been commented out.
;; Delete the leading semi-colon to make a scale active.
;; You can comment out an unwanted scale by placing a semi-colon at
;; the start of its line.

   (defun scaledel_create_metric ()
     (scaledel_create_scales
       '(
;          ("10:1" "10:1")
;          ("5:1" "5:1")
;          ("2:1" "2:1")
         ("1:1" "1:1")
         ("1:2" "1:2")
;          ("1:2.5" "1:2.5")
         ("1:5" "1:5")
         ("1:10" "1:10")
         ("1:20" "1:20")
;          ("1:25" "1:25")
         ("1:50" "1:50")
         ("1:100" "1:100")
         ("1:200" "1:200")
;          ("1:250" "1:250")
         ("1:500" "1:500")
         ("1:1000" "1:1000")
         ("1:2000" "1:2000")
;          ("1:2500" "1:2500")
         ("1:5000" "1:5000")
;          ("1:10000" "1:10000")
;          ("1:20000" "1:20000")
;          ("1:25000" "1:25000")
;          ("1:50000" "1:50000")
;          ("1:100000" "1:100000")
;          ("1:200000" "1:200000")
;          ("1:250000" "1:250000")
;          ("1:500000" "1:500000")
         ("1:1 m" "1000:1")
         ("1:2 m" "1000:2")
;          ("1:2.5 m" "1000:2.5")
         ("1:5 m" "1000:5")
         ("1:10 m" "1000:10")
         ("1:20 m" "1000:20")
;          ("1:25 m" "1000:25")
         ("1:50 m" "1000:50")
         ("1:100 m" "1000:100")
         ("1:200 m" "1000:200")
;          ("1:250 m" "1000:250")
         ("1:500 m" "1000:500")
         ("1:1000 m" "1000:1000")
         ("1:2000 m" "1000:2000")
;          ("1:2500 m" "1000:2500")
         ("1:5000 m" "1000:5000")
         ("1:10000 m" "1000:10000")
         ("1:20000 m" "1000:20000")
;          ("1:25000 m" "1000:25000")
         ("1:50000 m" "1000:50000")
;          ("1:100000 m" "1000:100000")
;          ("1:200000 m" "1000:200000")
;          ("1:250000 m" "1000:250000")
;          ("1:500000 m" "1000:500000")
       )
     )
   ) ; End scaledel_create_metric


;;; --------------------------------------------------------------------------
;; *** Note: several uncommon scales have been commented out.
;; Delete the leading semi-colon to make a scale active.
;; You can comment out an unwanted scale by placing a semi-colon at
;; the start of its line.

   (defun scaledel_create_inch ()
     (scaledel_create_scales
       '(
;          ("8:1" "8:1")
;          ("4:1" "4:1")
;          ("2:1" "2:1")
         ("1:1" "1:1")
         ("1/32\" = 1'-0\"" "0.03125:12")
         ("1/16\" = 1'-0\"" "0.0625:12")
         ("3/32\" = 1'-0\"" "0.09375:12")
         ("1/8\" = 1'-0\"" "0.125:12")
         ("3/16\" = 1'-0\"" "0.1875:12")
         ("1/4\" = 1'-0\"" "0.25:12")
         ("3/8\" = 1'-0\"" "0.375:12")
         ("1/2\" = 1'-0\"" "0.5:12")
         ("3/4\" = 1'-0\"" "0.75:12")
         ("1\" = 1'-0\"" "1:12")
         ("1-1/2\" = 1'-0\"" "1.5:12")
         ("3\" = 1'-0\"" "3:12")
         ("6\" = 1'-0\"" "6:12")
         ("1\" = 10'-0\"" "1:120")
         ("1\" = 20'-0\"" "1:240")
         ("1\" = 30'-0\"" "1:360")
         ("1\" = 40'-0\"" "1:480")
         ("1\" = 50'-0\"" "1:600")
         ("1\" = 60'-0\"" "1:720")
         ("1\" = 100'-0\"" "1:1200")
;          ("1\" = 250'-0\"" "1:3000")
;          ("1\" = 500'-0\"" "1:6000")
;          ("1\" = 1000'-0\"" "1:12000")
;          ("1\" = 5280'-0\"" "1:63360")
;          ("1\" = 12000'-0\"" "1:144000")
;          ("1\" = 24000'-0\"" "1:288000")
;          ("1\" = 48000'-0\"" "1:576000")
;          ("1\" = 50000'-0\"" "1:600000")
;          ("1\" = 52800'-0\"" "1:633600")
       )
     )
   ) ; End scaledel_create_inch


   (prompt
     (strcat
       "SCALELISTDEL SCALELISTDELALL SCALELISTDELINCH SCALELISTDELXREF "
       "SCALELISTDEL_ SCALELISTDELINCHXREF SCALELISTDELINCH_ SCALELISTMETRIC "
       "SCALELISTMETRICTEMPLATE SCALELISTINCH SCALELISTINCHTEMPLATE "
       "commands loaded.\n"
     )
   )


 ) ; End progn to test for AutoCAD release
 (prompt "\nRequires AutoCAD 2008 or above.")
)

(princ)

;;; ==========================================================================
;;; End of file ScaleListDel.lsp
;;; ==========================================================================

 

Pensant vous avoir aidés.

 

@+

 

[lili2006]

Bonsoir à toutes et tous,

 

lesourd2, comment fonctionne ce lisp ?

 

En le lancant =>

 

Commande: SCALELISTDEL

Enter scale name(s) to delete:

Commande:

 

Il ne faut tout de même pas toutes les écrires ??

 

J'ai un fichier ou j'en ai surement plus de cent,...

 

Merci d'avance

[sbosarl]

Bonsoir, ouah une usine a gaz (peut être très bien j’ai pas tester)

Le problème si tu insère un nouveau bloc ou une nouvelle xref ta liste d’échelle est de nouveau complété

Moi j’utilise un petit script qui réinitialise la liste au nomment ou je purge le plan

 

(fichier type *.scr)

 -scalelistedit
r
o
q
_-vports
_si
_zoom
_e
_purger
_a
*
n
_qsave
_audit
o
_qsave
_purger
_a
*
n
_qsave

[lesourd2]

Salut

 

lesourd2, comment fonctionne ce lisp

 

Desole j'ai pas testé (pas la v.2008).

 

@+

[lesourd2]

Salut

 

Peut-etre une piste ou une reponse par là.

 

@+

[lili2006]

Bonjour à toutes et tous,

 

Marche super bien ton script sbosarl

 

Merci pour le partage.

[jc1932]

Bonjour tous,

Il marche très bien ce script, mais pour moi, termine bizarrement, en -trim :P

 

Merci