Recherche/remplacer qui boucle

[stephan35]

Bonjour à tous !

 

Voilà une ptit bout de code récupéré qui fonctionnait bien jusqu'à ce que je fasse :

 

 (@Macro_remplace_texte "Tables d'écoutes" "'" "\'" )

 

Et oui il cherche mon ' et le remplace toujours par \' qui contient un ' !!!!

 

Une petite récursivitée non souhaitée .....

 

 

 (defun @Macro_remplace_texte ($source $search $rempl / )
 (while (/= (wcmatch $source (strcat "*"$search"*")) nil)
   (setq $source(vl-string-subst $rempl $search $source))
   )
 $source
)

 

 

Merci à vous !

 

 

 

Bientôt le week-end ..... et avec du soleil ????? (en bretagne ...) :casstet:

 

[Patrick_35]

Salut

Si c'est pour remplacer un caractère par un autre, tu as la fonction (vl-string-translate source-set dest-set str)

 

Et aussi la fonction (vl-string-search pattern string [start-pos])

 

@+

 

[Edité le 6/7/2007 par Patrick_35]

[stephan35]

 Si c'est pour remplacer un caractère par un autre, tu as la fonction (vl-string-translate source-set dest-set str)

Et aussi la fonction (vl-string-search pattern string [start-pos])

 

Et non, c'est vrai qu'avec les guillemets, on ne voit pas bien ....

 

Je cherche à remplacer, plus exactement à rajouter un caractère devant une série d'autres caractère, ex: remplacer dans "oldoldoldoldold-old-old" la partie "old" par "Pold" , ce cas pose problèmes ....

 

Merci

[stephan35]

bon en fouillant un peu j'ai retrouvé ça :

 

 

 (defun @Macro_remplace_texte
      ($string $recherche $remplace / os osl ns nsl chf si sl st $result)
 (setq osl (strlen (setq os $recherche)))
 (setq nsl (strlen (setq ns $remplace)))
 (setq	chf nil
si  1
)
 (while (= osl (setq sl (strlen (setq st (substr $string si osl)))))
   (if	(= st os)
     (progn
(setq $string (strcat (substr $string 1 (1- si))
		      ns
		      (substr $string (+ si osl))
		      )
      )
(setq chf t)
(setq si (+ si nsl))
)
     (setq si (1+ si))
     )
   )
     (setq $result $string)
 )

 

 

Qui peut proposer mieux ?

 

A+

[Bred]

Salut,

... c'est bien parti pour être un challeenge, ça !!! ;)

 

ma proposition :

 

(defun @Macro_remplace_texte ($string $recherche $remplace / txt-f)
 (setq txt-f "")
 (while (vl-string-position (ascii $recherche) $string)
   (if (equal (substr $string 1 3) $recherche)
     (setq $string (vl-string-subst "" $recherche $string)
    txt-f (strcat txt-f $remplace))
     (setq txt-f (strcat txt-f (substr $string 1 1))
    $string (vl-string-subst "" (substr $string 1 1) $string))
     )
   )
 txt-f
 )

 

(@Macro_remplace_texte "oldoldoldoldold-old-old" "old" "Pold") donne : "PoldPoldPoldPoldPold-Pold-Pold"

[stephan35]

C'est un bon début Bred !

 

Mais .......

 

 (if (equal (substr $string 1 3) $recherche)

 

 

Fige déjà une stucture de 1 à 3 charactère dans la méthode de recherche ??????

 

C'est pas bon ça !, ça nous oblige a faire un strlen pour calculer la longueur de la chaine ???

 

 (@macro_remplace_texte "aaaaaapopopopoaaaa" "po" "iiiipo")

 

ne fonctionne donc pas !

 

 

 

 

Commande: (defun @Macro_remplace_texte

(_> ($string $recherche $remplace / os osl ns nsl chf si sl st $result)

(_> (setq osl (strlen (setq os $recherche)))

(_> (setq nsl (strlen (setq ns $remplace)))

(_> (setq chf nil

((_> si 1

((_> )

(_> (while (= osl (setq sl (strlen (setq st (substr $string si osl)))))

((_> (if (= st os)

(((_> (progn

((((_> (setq $string (strcat (substr $string 1 (1- si))

((((((_> ns

((((((_> (substr $string (+ si osl))

((((((_> )

(((((_> )

((((_> (setq chf t)

((((_> (setq si (+ si nsl))

((((_> )

(((_> (setq si (1+ si))

(((_> )

((_> )

(_> (setq $result $string)

(_> )

@MACRO_REMPLACE_TEXTE

 

Commande: (@macro_remplace_texte "aaaaaapopopopoaaaa" "po" "iiiipo")

"aaaaaaiiiipoiiiipoiiiipoiiiipoaaaa"

 

Commande: (@macro_remplace_texte "aaaaaapopopopoaaaa" "po" "|po")

"aaaaaa|po|po|po|poaaaa"

 

Reste inoptimisable ??? ou ce code serait-il déjà optimisé ????

 

 

Je ne vais pas te décourrager Bred ! tu tiens le bon bout !!!!

 

;)

 

[Edité le 6/7/2007 par stephan35]

[Bred]

OK,

comme tu le dis :

ça nous oblige a faire un strlen pour calculer la longueur de la chaine ???

ça n'est pas génant... si ?

 

Résultat :

(defun @Macro_remplace_texte ($string $recherche $remplace / txt-f nb)
 (setq txt-f ""
nb (strlen $recherche))
 (while (vl-string-position (ascii $recherche) $string)
   (if (equal (substr $string 1 nb) $recherche)
     (setq $string (vl-string-subst "" $recherche $string)
    txt-f (strcat txt-f $remplace))
     (setq txt-f (strcat txt-f (substr $string 1 1))
    $string (vl-string-subst "" (substr $string 1 1) $string))
     )
   )
 (strcat txt-f $string)
 )

 

[Edité le 6/7/2007 par Bred]

[Patrick_35]

Si ça devient un challenge ;)

 

(defun @Macro_remplace_texte ($source $search $rempl / loc pos)
 (while (setq loc (vl-string-search $search $source pos))
   (setq $source (vl-string-subst $rempl $search $source pos)
  pos (+ loc (strlen $rempl))
   )
 )
 $source
)

 

(@macro_remplace_texte "aaaaaapopopopoaaaa" "po" "iiiipo") --> aaaaaaiiiipoiiiipoiiiipoiiiipoaaaa

(@Macro_remplace_texte "Tables d'écoutes" "'" "\'" ) --> "Tables d'écoutes"

 

@+

[Bred]

je m'incline encore devant la simplicité de la proposition de Patrick_35 ....

(et comme d'hab, on s'en veut toujours de ne pas avoir trouvé ça, qui est si simple !!!!....)

[stephan35]

Mes respects !!!!

 

A+