Modification de texte avec préfixe

[CBY]

Bonjour,

 

Je recherche une astuce qui me permettra de préfixer un ensemble de texte.

 

Concraitement, je souhaite transformer tous mes textes d' altitude (de valeur ''Z=112.00") en texte de valeur "RDC ,Z=112.00".

De plus, je dois inserer un saut de ligne entre le RDC et le Z=112.00.

Merci pour vos conseils.

 

 

 

[Bred]

Salut,

essaye ça :

 

(defun c:rdc (/ I SEL TXT TXT-R)
 (setq sel (ssget '((0 . "*TEXT"))))
 (repeat (setq i (sslength sel))
   (setq txt (cdr (assoc 1 (entget (ssname sel (setq i (1- i))))))
  txt-r (strcat "RDC," txt))
   (entmod (subst (cons 1 txt-r) (cons 1 txt) (entget (ssname sel i))))
   )
 (princ (strcat "\n" (rtos (sslength sel)) " Texte(s) modifié(s)."))
 (princ)
)

 

[Edité le 27/6/2007 par Bred]

[CBY]

Bonjour Bred,

 

Merci pour ton aide.

Le fichier fonctionne bien pour le préfixe.

Pour être précis, je travaille sur des entités « texmult »

Pour le saut de ligne, je transforme « RDC, » par « RDC\P »avec la commande rechercher/remplacer d’autocad.

J’ai tenter de remplacer directement dans le fichier : (strcat « rdc, » txt)) Par : (strcat « rdc\P » txt))… Le résultat attendu n’est pas là mais je ne sais expliquer pourquoi (néophyte en programmation).

 

Je recherche également à automatiser une opération de calcul sur texte (textmut) :

A tous mes textes d’altitude ( ex : 123.50), je souhaite affecter un delta de -0.40m et obtenir un texte modifieé de valeur 123.10.

 

Merci.

 

[Bred]

Salut,

J’ai tenter de remplacer directement dans le fichier : (strcat « rdc, » txt)) Par : (strcat « rdc\P » txt))… Le résultat attendu n’est pas là mais je ne sais expliquer pourquoi

presque... (+tu ne peux choisir que les Mtexte maintenant)

(defun c:rdc (/ I SEL TXT TXT-R)
 (setq sel (ssget '((0 . "MTEXT"))))
 (repeat (setq i (sslength sel))
   (setq txt (cdr (assoc 1 (entget (ssname sel (setq i (1- i))))))
  txt-r [b](strcat "rdc\\P" txt)[/b])
   (entmod (subst (cons 1 txt-r) (cons 1 txt) (entget (ssname sel i))))
   )
 (princ (strcat "\n" (rtos (sslength sel)) " Texte(s) modifié(s)."))
 (princ)
)

 

A tous mes textes d’altitude ( ex : 123.50), je souhaite affecter un delta de -0.40m et obtenir un texte modifieé de valeur 123.10.

Essaye ça :

(attention, la valeur selectionné doit être un niveau sans aucun préfixe, sinon la valaur = -0.40)

 

(defun c:alt- (/ ALT ALT-CORR I SEL)
 (setq sel (ssget '((0 . "MTEXT"))))
 (repeat (setq i (sslength sel))
   (setq alt (cdr (assoc 1 (entget (ssname sel (setq i (1- i))))))
  alt-corr (rtos (- (atof alt) 0.40)))
   (entmod (subst (cons 1 alt-corr) (cons 1 alt) (entget (ssname sel i))))
   )
 (princ (strcat "\n" (rtos (sslength sel)) " Niveau(x) modifié(s)."))
 (princ)
)

 

[Edité le 28/6/2007 par Bred]

[CBY]

Bonjour Bred

 

Merci pour ta rapidité et ton efficacité.

Ta réponse comble mes attentes.

 

Bonne journee