POLY 3D VERS 2D

[lili2006]

Bonjour,

 

Ma question est surement + simple que la réponse. Voilà, est-il possible de transformer une Poly 3D en Poly 2D sans l'exploser ??

 

Merci à ceux qui ont une idée,... :o

[(gile)]

Je ne sais pas si c'est exactement ce que tu cherches, mais voilà un LISP qui crée un polyligne qui est la projection sur le plan XY du SCU courant de la polyligne 3d sélectionnée.

 

;;; 3D2LW -03/06/07-
;;; Crée une lwpolyligne, projection de la polyligne 3d sur le plan XY du SCU courant
(defun c:3d2lw (/ acdoc model ss poly)
 (vl-load-com)
 (setq	acdoc (vla-get-ActiveDocument (vlax-get-acad-object))
model (vla-get-ModelSpace AcDoc)
 )
 (if
   (setq ss (ssget "_:S" '((0 . "POLYLINE") (-4 . "&") (70 . 8))))
    (progn
      (vla-StartUndoMark acdoc)
      (vla-put-Elevation
 (vlax-invoke
   model
   'addLightWeightPolyline
   (apply
     'append
     (mapcar
       '(lambda	(p)
	  (setq p (trans p 0 (trans '(0 0 1) 1 0 T)))
	  (list (car p) (cadr p))
	)
       (3d-coord->pt-lst
	 (vlax-get
	   (setq poly (vlax-ename->vla-object (ssname ss 0)))
	   'Coordinates
	 )
       )
     )
   )
 )
 (caddr (trans (getvar "UCSORG") 0 (trans '(0 0 1) 1 0 T)))
      )
      (initget "Oui Non")
      (if (or (not (setq rep
		   (getkword
		     "\nEffacer la polyligne source ? [Oui/Non] : "
		   )
	    )
       )
       (= rep "Oui")
   )
 (vla-delete poly)
      )
      (vla-EndUndoMark acdoc)
    )
 )
 (princ)
)

;;; 3d-coord->pt-lst Convertit une liste de coordonnées 3D en liste de points
;;; (3d-coord->pt-lst '(1.0 2.0 3.0 4.0 5.0 6.0)) -> ((1.0 2.0 3.0) (4.0 5.0 6.0))

(defun 3d-coord->pt-lst	(lst)
 (if lst
   (cons (list (car lst) (cadr lst) (caddr lst))
  (3d-coord->pt-lst (cdddr lst))
   )
 )
) 

[Edité le 3/6/2007 par (gile)]

 

[Edité le 4/6/2007 par (gile)]

[lecrabe]

 

Hello Gilles

 

Si j'ai bien compris cette routine produit une polyligne 2D identique à la manipulation suivante :

 

Accrocher le XY de la Polyligne 3D pour chaque sommet en passant le paramètre .XY et donc en donnant le Z = ZERO !?

 

Le Decapode

 

 

[lili2006]

Bonjour à tous,

 

Merci pour vos réponses rapides. En fait je souhaite récupérer un plan sous covadis et le retravailler que sous AutoCAD et je me suis rendu compte que je ne pouvais pas la décaler, voilà la raison de ma question. Est-ce possible gile avec ton lisp, je le teste de suite et t'en remercie. lecrabe, c'est une solution tout remettre à z=0 mais quand tu en as des km, bonjour le travail,....

Merci encore à tous les deux. :D

[lili2006]

Re,

 

E,n utilisant ton lisp, (gile), voici le message d'erreur :

 

erreur: no function definition: 3D-COORD->PT-LST

 

Kesako ?? :(

[(gile)]

Oui lecrabe, c'est bien la manipulation décrite, le XY étatnt celui du SCU courant quelque soit celui-ci.

 

Mille excuses lili2006, j'avais oublié de joindre la sous routine. c'est réparé.

[lili2006]

Re,

 

Merci (gile), ça marche au poil !!

 

@+, :P

[Concombre_masque]

_flatten ca marche pas ?

[lili2006]

Bonsoir,

 

_flatten remet bien le "z" à zéro mais on ne peut toujours pas décaler la poly ??

Pas mal sinon.

 

Merci pour cette commande.

[lili2006]

Re,

 

Ce qui est pas mal aussi c'est que la poy 3D reste une poly 3D. En fonction des besoins,...