Changer calque hachure

[LUDWIG]

Bonjour,

 

J'ai un lisp qui permet de supprimer toutes les hachures d'un dessin, même dans les blocs :

 

 (defun c:effhatch ()
(vl-load-com)
(setq a (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
(vlax-for bl a
(vlax-for ent bl
(if (= (vla-get-objectname ent) "AcDbHatch")
(vla-delete ent)
)
)
)
(vla-regen (vla-get-activedocument (vlax-get-acad-object)) acActiveViewport)

 

Je voudrais l'adapter pour qu'il ne sélectionne que les hachures "solides", qu'il les passe en couleur ducalque et qu'il les mette sur un calque "hachure". Quelqu'un pourrait m'aider ?

 

[Edité le 4/4/2007 par LUDWIG]

[(gile)]

Salut,

 

Ton LISP ne devait fonctionner que pour les hachures dans les blocs.

En voici un autre qui, pour toutes les hachures "SOLID" du dessin (y compris dans des blocs), met les hachures sur le calque "hachures" en couleur "DuCalque".

 

Edit : ajout d'un groupe d'annulation.

 

(defun c:layhatch (/ doc ss n ent a bl)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vl-load-com)
 (if (tblsearch "LAYER" "hachure")
   (progn
     (vla-StartUndoMark doc)
     (setq a (vla-get-blocks doc)
     )
     (vlax-for	bl a
(vlax-for ent bl
  (if (and (= (vla-get-objectname ent) "AcDbHatch")
	   (= (vla-get-PatternName ent) "SOLID")
      )
    (progn
      (vla-put-Layer ent "hachure")
      (vla-put-color ent acByLayer)
    )
  )
)
     )
     (vla-regen doc acActiveViewport)
     (vla-EndUndoMark doc)
   )
   (alert "Le calque \"hachure\" n'existe pas.")
 )
 (princ)
)

[Edité le 4/4/2007 par (gile)]

 

[Edité le 4/4/2007 par (gile)]

[Patrick_35]

Ton LISP ne devait fonctionner que pour les hachures dans les blocs.

Et non (gile)

Fait un

(vla-get-name (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) 0))

Et c'est l'espace objet :o

Maintenant, si tu prends l'item 1, tu trouveras le premier onglet de présentation ;)

 

Pour répondre à Ludwig, le lisp devra aussi modifier les blocs ou seulement ce qui est sur le dessin ?

 

@+

[(gile)]

Hé oui, bien sûr !

Les espaces objet et papier sont considérés comme des blocs. :calim:

 

J'ai modifié le code en conséquence, merci encore.

[LUDWIG]

merci les pros !

 

J'avais cherché de mon côté et trouvé le vla-get-patternName, mais je ne savais pas quelles étaient les méthodes pour changer la couleur et le calque.

 

Patrick_35, c'est bien ça que je cherchais : que les hachures solides, qu'elles soient dans un bloc ou non, soient affectées par le lisp.

 

Merci encore

[BIM G CO]

Voici une version du programme qui permet de gérer les hachures créé avec ALLPLAN (expérience avec un architecte)

 

 (defun c:LayerSolidHathInBlocks	(/ doc ss n ent a bl)
;http://www.cadxp.com/sujetXForum-14601.htm
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vl-load-com)
 (if (not (tblsearch "LAYER" "Hachures à cacher"))
   (entmake (list (cons 0 "LAYER")
	   (cons 100 "AcDbSymbolTableRecord")
	   (cons 100 "AcDbLayerTableRecord")
	   (cons 2 "Hachures à cacher")
	   '(70 . 3)
	   '(62 . -7)
	   (cons 6 "Continuous")
	   '(290 . 0)
	   )))
 (vla-StartUndoMark doc)
 (setq	a (vla-get-blocks doc)
 )
 (vlax-for bl a
   (vlax-for ent bl
     (if (and (= (vla-get-objectname ent) "AcDbHatch")
       (or (= (vla-get-PatternName ent) "SOLID,_I")
                  (= (vla-get-PatternName ent) "SOLID"))
  )
(progn
  (vla-put-Layer ent "Hachures à cacher")
  (vla-put-color ent acByLayer)
)
     )
   )
 )
 (vla-regen doc acActiveViewport)
 (vla-EndUndoMark doc)

 (princ)
)

 

Le programme suivant liste tous les noms des hachures.

 (defun c:QuiSOLID	(/ doc ss n ent a bl)
;http://www.cadxp.com/sujetXForum-14601.htm
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vl-load-com)
 (vla-StartUndoMark doc)
 (setq	a (vla-get-blocks doc)
 )
 (vlax-for bl a
   (vlax-for ent bl
     (if (= (vla-get-objectname ent) "AcDbHatch")
(print (vla-get-PatternName ent)
)
     )
   )
 )
 (vla-EndUndoMark doc)

 (princ)
)

 

[Edité le 19/5/2007 par Maximilien]