[Résolu] somme de cotes

[Fruity]

Bonjour a tous!

je voulais savoir si quelqu'un pouvait me faire une macro (ou lisp ou autre chose du moment que ca fonctionne) avec laquelle je pourrais avoir le total de plusieurs cotes selectionnées.

Parceque additionner a la main en suivant le plan, c'est un peu long...

Merci d'avance!

 

ps: il faudrait que cet outil fonctionne quelques soient les scu des cotes.

 

[Edité le 2/4/2007 par open-mind]

[Bred]

Salut,

Un petit lisp rapide mais qui ne prends que les valeurs réelle, non forcée, des cotes.

 

(defun c:adcot (/ SEL SOM VAL X)  
(setq sel (ssget '((0 . "DIMENSION")))
     x 0
     som 0)
(repeat (sslength sel)
 (setq val (cdr (assoc 42 (entget (ssname sel x))))
som (+ som val)
x (+ 1 x)
)
 )
 (alert (strcat "\n Addition des cotes Sélectionnées (réelle) : " (rtos som) " ."))
 (princ)
 )

[Bred]

La même chose que précedement, mais celui ci donne le résultat réel des côtes, puis si il y a lieu donne le résultat avec les cotes forcées.

- A tester -

 

; additionne cotes sélectionnés
(defun c:adcot2 (/ CALC SEL SOM SOMF VAL VALF X)  
(setq sel (ssget '((0 . "DIMENSION")))
     x 0
     som 0
     somF 0
     calc 0)  
(repeat (sslength sel)
 (setq val  (cdr (assoc 42 (entget (ssname sel x))))
valF (atof (cdr (assoc 1 (entget (ssname sel x)))))
som (+ som val)		
)
 (if (not (equal valF 0.0))
   (setq somF (+ somF valF)
  calc (+ calc val))
   )
 (setq x (+ 1 x))
 )
 
 (alert (strcat "\n Addition des cotes Sélectionnées (réelle) : " (rtos som) " ."))
 (if (not (equal calc 0))(alert (strcat "\n Addition des cotes Sélectionnées (Marquée) : " (rtos (+ (- som calc) somF)) " .")))
	 
 (princ)
 )

[Fruity]

ok

c'est genial, ca fonctionne! et quelle reactivité!

merci beaucoup!

 

ps: j'ai pas testé le 2eme par contre...