Gestion des mises en pages

[dr.loveless]

Bonjour,

 

Je me suis fais un plan sur lequel j'ai officialisé toutes les mises en page possibles en fonction des imprimantes et traceurs disponibles dans l'entreprise. Quelqu'un a t-il déjà fais une petite application pour pouvoir importer automatiquement toutes ces mises en pages dans un plan des que celui-ci est ouvert? (y compris les nouveaux plans!)

 

Merci

[Patrick_35]

Salut

Le plus simple est de lancer la commande Traceur, et dans la liste déroulante du nom de la mise en page, tu as importer...

 

@+

[dr.loveless]

Merci Patrock, mais je connais. Ce que je veux c'est trouvé le moyen de le faire automatiquement soit en lisp, soit VBA.

[Patrick_35]

Salut

Par exemple

(defun copier_config_traceur (dessin onglet_base onglet_dest / config dbx lay i j)
 (defun Ouvrir_dessin_dbx(dwg / dbx)
   (if (< (atoi (substr (getvar "ACADVER") 1 2)) 16)
     (setq dbx (vlax-create-object "ObjectDBX.AxDbDocument"))
     (setq dbx (vlax-create-object (strcat "ObjectDBX.AxDbDocument." (substr (getvar "ACADVER") 1 2))))
   )
   (vla-open dbx dwg)
   dbx
 )

 (setq dbx (ouvrir_dessin_dbx dessin))
 (setq config (vla-item (vla-get-layouts dbx) onglet_base)
       lay    (vla-item (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object))) onglet_dest))
 (vla-put-ConfigName lay           (vla-get-ConfigName config))
 (vla-put-CanonicalMediaName lay   (vla-get-CanonicalMediaName config))
 (vla-GetCustomScale config  'i 'j)(vla-SetCustomScale  lay i j)
 (vla-GetWindowToPlot config 'i 'j)(vla-SetWindowToPlot lay i j)
 (vla-put-PlotOrigin lay           (vla-get-PlotOrigin config))
 (vla-put-PaperUnits lay           (vla-get-PaperUnits config))
 (vla-put-PlotHidden lay           (vla-get-PlotHidden config))
 (vla-put-PlotRotation lay         (vla-get-PlotRotation config))
 (vla-put-PlotType lay             (vla-get-PlotType config))
 (vla-put-PlotViewportBorders lay  (vla-get-PlotViewportBorders config))
 (vla-put-PlotViewportsFirst lay   (vla-get-PlotViewportsFirst config))
 (vla-put-PlotWithLineweights lay  (vla-get-PlotWithLineweights config))
 (vla-put-PlotWithPlotStyles lay   (vla-get-PlotWithPlotStyles config))
 (vla-put-ScaleLineweights lay     (vla-get-ScaleLineweights config))
 (vla-put-ShowPlotStyles lay       (vla-get-ShowPlotStyles config))
 (vla-put-StandardScale lay        (vla-get-StandardScale config))
 (vla-put-StyleSheet lay           (vla-get-StyleSheet config))
 (vla-put-UseStandardScale lay     (vla-get-UseStandardScale config))
 (if (not (eq (vla-get-PlotType config) aclayout))
   (vla-put-CenterPlot lay         (vla-get-CenterPlot config))
 )
 (vlax-release-object Dbx)
 (princ)
)

 

(copier_config_traceur "c:/un_dessin_test.dwg" "Un_onglet_origine_fichier_test" "un_onglet_destination_dessin_courant")

 

C'est un code qui ne se sert pas des présentations sauvegardé, mais de ceux qui sont déjà configurées.

Je peux le faire aussi pour ceux qui sont sauvegardés, comme pour l'importation dazns la boite de dialogue du traceur dans Autocad.

 

ps : Je ne fais pas de test pour vérifier que le traceur ainsi que le format papier que j'importe existe dans la config actuel d'Autocad. C’est juste à titre d’exemple

 

@+

[dr.loveless]

Ouahhh rien que çà, je m'attendais à un truc beaucoup plus simple.

 

En tout cas, mille merci, je vais analyser çà.