Filtre dans chemin de recherche

[stephan35]

Bonjour,

 

Voici un code dans lequel je souhaite rajouter un filtre genre :

"je veux obtenir tous les DWG sauf ceux qui commence par a"

 

(GetFilePath "*.DWG" "a*.DWG" "C:/")

 

Code actuel :

 

(defun GetFilepath (file path)
(apply (function append)
(cons (if (vl-directory-files path file)
(mapcar (function (lambda (x) (strcat path "/" x))) (vl-directory-files path file))
) ;_ if
(mapcar (function (lambda (x) (GetFile file (strcat path "/" x))))
(vl-remove ".." (vl-remove "." (vl-directory-files path nil -1)))
) ;_ mapcar
) ;_ cons
) ;_ apply
)

 

(code piqué chez ev..y)

 

 

 

GetFilepath (file ext path)
...
wcmatch ???

 

 

Un petit casse tête ? :casstet:

 

Merci ...

 

 

[(gile)]

Salut

 

(vl-remove-if-not
 '(lambda (x) (wcmatch (vl-filename-base x) "~a*"))
 (getfile "*.dwg"  "C:")
) 

 

PS : Attention tu as changé le nom de la fonction dans le defun mais pas dans son appel récursif.

[stephan35]

Merci Gile

 

Merveilleux ! Super ! etc. :D

[(gile)]

Une fonction plus "générique", toujours basé sur le code d'Evgeniy

 

exemple :

 

(GetFile "acad*.lsp" "C:\\Program Files\\AutoCAD 2007")

retourne :

("C:\\Program Files\\AutoCAD 2007\\Express\\acadinfo.lsp"

"C:\\Program Files\\AutoCAD 2007\\Support\\acad2007.lsp"

"C:\\Program Files\\AutoCAD 2007\\Support\\acad2007doc.lsp"

"C:\\Program Files\\AutoCAD 2007\\Support\\acadinfo.lsp"

)

 

(GetWcFile "acad*.lsp" "~*2007*" "C:\\Program Files\\AutoCAD 2007")

retourne :

("C:\\Program Files\\AutoCAD 2007\\Express\\acadinfo.lsp"

"C:\\Program Files\\AutoCAD 2007\\Support\\acadinfo.lsp"

)

 

(defun GetWcFile (file pattern path)
 (apply 'append
   (cons
     (if (vl-directory-files path file)
(mapcar	'(lambda (x) (strcat path "\\" x))
	(vl-remove-if-not
    '(lambda (x) (wcmatch (vl-filename-base x) pattern))
    (vl-directory-files path file)
  )
)
     )
     (mapcar '(lambda (x) (GetWcFile file pattern (strcat path "\\" x)))
      (vl-remove ".."
		 (vl-remove "." (vl-directory-files path nil -1))
      )
     )
   )
 )
) 

[stephan35]

Je vais manquer d'ajectifs qualificatifs ....... ;)

 

Merci !