autilisp vers latex

[Invité ingoenius]

Salut je cherceh de faire generet du code pour latex a autolisp , dejà c'ets un peu bizarre, mais venons a nous,

 

je sois mettre en page environ 200 pages, dans lequelles il faut un code tipe

 

 \imgloc{Pupitre_bras.jpg}

ou le nom de li'mage doit etre pris dans un repertoire avec toutes les images, comment je paut faire prendre a autolisp un par un les nom de tous le fichiers du repertoire cible

 

 C:\Documents and Settings\mingenuo\Desktop\impression_BOOK_MAX

 

e faire mettre a chaque iteration de la boucle le bon nome de fichiers dans le code??

 

e faire generer toutes le lignes de code vers un fichier .txt danl le meme dossier?

 

 

c'est possible?

merci a vous ;-)

[(gile)]

Salut,

 

Si j'ai bien compris :

 

;;; GetFile Retourne le (ou les) chemin()s des fichiers dans
;;; les répertoires et sous-répertoires de chemin spécifié.
;;; Accepte les caractères génériques

;; ElpanovEvgeniy
(defun GetFile (f p)
 (apply (function append)
 (cons (if (vl-directory-files p f)
	 (mapcar (function (lambda (x) (strcat p "\\" x)))
		 (vl-directory-files p f)
	 )
       ) ;_ if
       (mapcar (function (lambda (x) (GetFile f (strcat p "\\" x))))
	       (vl-remove ".."
			  (vl-remove "." (vl-directory-files p nil -1))
	       )
       ) ;_ mapcar
 ) ;_ cons
 ) ;_ apply
)

(defun c:test (/ flst file)
 (if
   (setq flst
   (mapcar
     'vl-FileName-Base
     (GetFile
       "*.jpg"
       "C:\\Documents and Settings\\mingenuo\\Desktop\\impression_BOOK_MAX"
     )
   )
   )
    (progn
      (setq file
      (open
	"C:\\Documents and Settings\\mingenuo\\Desktop\\impression_BOOK_MAX\\Test.txt"
	"w"
      )
      )
      (foreach	f flst
 (write-line (strcat "\imgloc{" f ".jpg}") file)
      )
      (close file)
    )
 )
 (princ)
) 

[Invité ingoenius]

é praticamente perfetto ;-)

riusciresti a far fare il caffé da autocad;

 

unica modifica che ho apportato é

qui verso la fine ho aggiunto una antislash "\\imgloc......."

perché cosi' non me la metteva nel file txt

 

 

)
(write-line (strcat "\imgloc{" f ".jpg}") file)
)

 

é possibile scegliere tramite il selettore dei file la directori sorgente

(dove ci sono le immagini e dove generare il file txt) ??

 

mille grazie

 

[(gile)]

(defun c:test (/ flst file)
 (if (and
(setq file
       (getfiled "Sélectionnez un fichier dans le répertoire à traiter"
		 ""
		 ""
		 0
       )
)
(setq flst
       (mapcar
	 'vl-FileName-Base
	 (GetFile
	   "*.jpg"
	   (vl-FileName-Directory file)
	 )
       )
)
     )
    (if (setq file (getfiled "Créer un fichier" "" "txt" 1))
      (progn
 (setq file (open file "w"))
 (foreach f flst
   (write-line (strcat "\\imgloc{" f ".jpg}") file)
 )
 (close file)
      )
    )
 )
 (princ)
) 

[Invité ingoenius]

merci (Gile) ;-)

 

maintenant je cherche d'avancer pour le reste

 

 

 

 

 

PS

je n'ai toujours pas pu trouver le livre sur le visuallisp en francais

 

il ya pas des photocopies? un fichier electronique ou autres?? meme sur ebay on trouve pas

et dans les libraires il est amrque comme indisponible ;-(