Autocad vers Photoshop

[grandsteak44]

Bonjour,

Pour passer au rendu de fichiers autocad sur photoshop ma methode est la suivante :

Je cree un EPS pour chacun des calques autocad a partir d'une imprimante postcript puis sur photoshop je pixelise chacun des fichiers EPS et je les compile dans un fichier photoshop. Cette methode me permet de retrouver ma structure de calques d' autocad sur photoshop.

Je m'adresse aux specialistes du lisp pour leur demander s'ils n'ont pas dans leurs cartons un petit programme qui permetrait d'automatiser la phase de creation des EPS ; a savoir pour chacun des calques presents dans le fichier autocad creer un fichier EPS qui porte le nom du calque.

Je ne sais pas si c'est complique mais ca ferait gagner du temps a tous ceux qui ont souvent ce genre de manip' a faire.

D'avance merci pour vos reponses et commentaires.

[jalna]

Salut

 

D'abord j'ai pas de réponse mais j'aimerais savoir à quoi te sert de passer sous photoshop, car tu as peut etre d'autres moyens...

 

Bon week end

[bonuscad]

Une procédure qui date un peu ... mais déjà une bonne base s'il faut modifier quelque trucs

 

(defun epserr (ch)
(cond
	((eq ch "Function cancelled") nil)
	((eq ch "quit / exit abort") nil)
	((eq ch "console break") nil)
	(T (princ ch))
)
(command "_.undo" "_end")
(if (<= sv_und 3) (command "_.undo" "_control" "_one"))
(command "_.undo" "1")
(setq *error* olderr)
(setvar "expert" drap)
(setvar "textfill" fill_txt)
(setvar "filedia" dia_file)
(setvar "cmdecho" 1)
(princ)
)
(defun c:layer2eps ( / curr_layer next_layer name_layer drap sv_und olderr fill_txt dia_file name_file typ_plot pt1 pt2 name_view unit_plot scale_plot format_page prefix_folder)
(setvar "cmdecho" 0)
(setq drap (getvar "expert"))
(setq fill_txt (getvar "textfill"))
(setq dia_file (getvar "filedia"))
(setvar "textfill" 1)
(setvar "filedia" 0)
(setvar "expert" 5)
(if (<= (setq sv_und (getvar "undoctl")) 3)
	(command "_.undo" "_control" "_all")
)
(command "_.undo" "_group")
(setq olderr *error* *error* epserr)
(setq name_file (getfiled "Créer un fichier PosScript" "0" "eps" 33))
(initget "Affichage Etendue Limites Vue Fenêtre _Display Extent Limits View Window")
(if (not (setq typ_plot (getkword "\nQue tracer: Affichage, Etendue, Limites, Vue ou Fenêtre : ")))
	(setq typ_plot "Display")
)
(cond
	((eq typ_plot "Window")
		(initget 9)
		(setq pt1 (getpoint "\nSpécifiez le premier coin: "))
		(initget 9)
		(setq pt2 (getcorner pt1 " Spécifiez le coin opposé: "))
	)
	((eq typ_plot "View")
		(while (null (tblsearch "VIEW" (setq name_view (getstring T "\nNom de la vue: "))))
			(princ (strcat "\nLa vue " name_view " n'a pas été trouvée.\n*Incorrect*"))
		)
	)
)
(initget "Pouce Millimètre _Inches Millimeter")
(if (not (setq unit_plot (getkword "\nEntrez les unités [Pouces/Millimètres] : ")))
	(setq unit_plot "Millimeter")
)
(setq scale_plot (getstring "\nEntrez l'échelle de tracer sous la forme 1=2 ou F pour ajuster à la page: "))
(textscr)
(princ "\nValeurs standard pour le format de sortie")
(princ "\nFormat          Largeur    Hauteur")
(princ "\nA                  8.00      10.50")
(princ "\nB                 10.00      16.00")
(princ "\nC                 16.00      21.00")
(princ "\nD                 21.00      33.00")
(princ "\nE                 33.00      43.00")
(princ "\nF                 28.00      40.00")
(princ "\nG                 11.00      90.00")
(princ "\nH                 28.00     143.00")
(princ "\nJ                 34.00     176.00")
(princ "\nK                 40.00     143.00")
(princ "\nA4                 7.80      11.20")
(princ "\nA3                10.70      15.60")
(princ "\nA2                15.60      22.40")
(princ "\nA1                22.40      32.20")
(princ "\nA0                32.20      45.90")
(princ "\nUTILISATEUR       10.75      15.59")
(initget 8 "A B C D E F G H I J K A4 A3 A2 A1 A0 UTILISATEUR _A B C D E F G H I J K A4 A3 A2 A1 A0 USER")
(if (null (setq format_page (getpoint "\nEntrez le format, ou la largeur,hauteur (en Pouces) : ")))
	(setq format_page "A4")
)
(princ "\nReinitialise tous les plans dans la vue courante - Patientez S.V.P. !")
(command "_.-layer" "_thaw" "*" "_unlock" "*" "_set" "0" "_off" "*" "_on" "0" "")
(princ "\nSélectionne le calque 0")
(command "_.psout" name_file (strcat "_" typ_plot))
(cond
	((eq typ_plot "Window") (command pt1 pt2))
	((eq typ_plot "View") (command name_view))
)
(command "_none" (strcat "_" unit_plot) scale_plot)
(if (listp format_page)
	(command (strcat (rtos (car format_page) 2 2) "," (rtos (cadr format_page) 2 2)))
	(command (strcat "_" format_page))
)
(setq
	curr_layer (getvar "clayer")
	next_layer (tblnext "LAYER" T)
)
(if (setq next_layer (tblnext "LAYER"))
	(setq name_layer (cdr (assoc 2 next_layer)))
	(setq name_layer "0")
)
(setq prefix_folder (substr name_file 1 (- (strlen name_file) 5)))
(while (/= curr_layer name_layer)
	(if (/= curr_layer name_layer)
		(progn
			(command "_.-layer" "_off" "*" "_on" name_layer "")
			(princ (strcat "\nSélectionne le calque " name_layer))
			(setq name_file (strcat prefix_folder name_layer ".eps")) 
			(command "_.psout" name_file (strcat "_" typ_plot))
			(cond
				((eq typ_plot "Window")	(command pt1 pt2))
				((eq typ_plot "View") (command name_view))
			)
			(command "_none" (strcat "_" unit_plot) scale_plot)
			(if (listp format_page)
				(command (strcat (rtos (car format_page) 2 2) "," (rtos (cadr format_page) 2 2)))
				(command (strcat "_" format_page))
			)
		)
	)
	(setq next_layer (tblnext "LAYER"))
	(if (null next_layer)
		(setq next_layer (tblnext "LAYER" T))
	)
	(setq name_layer (cdr(assoc 2 next_layer)))
)
(princ "\nTous les calques ont été tracés en fichiers EPS dans l'espace courant.\n Commande terminée...")
(command "_.undo" "_end")
(if (<= sv_und 3) (command "_.undo" "_control" "_one"))
(command "_.undo" "1")
(setq *error* olderr)
(setvar "expert" drap)
(setvar "textfill" fill_txt)
(setvar "filedia" dia_file)
(setvar "cmdecho" 1)
(princ)
)