Quitter sous le calque \"0\"

[jalna]

Bonjour,

 

Je cherche le moyen de quitter mes fichiers et de positionner automatiquement le calque "0"

Comme ca à la prochaine ouverture je suis sur le calque "0".

 

:casstet: C'est juste une histoire de confort (j'aime bien le calque "0") :casstet:

[(gile)]

Salut,

 

Tu peux te faire un bouton avec la macro suivant :

 

^C^Cclayer;0;_close

[jalna]

Ok (gile)

:) Merci et à bientot

[Patrick_35]

Salut

Un lisp qui évite de cliquer sur un bouton et qui active automatiquement le calque 0 lors de la fermeture du dessin

(à charger automatiquement avec chaque dessin)

 

;;;=================================================================
;;;
;;; C0.LSP V1.00
;;;
;;; Quitter un dessin sur le calque 0
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun reacteur_calque_0 (Rea Cde / doc)
 (if (not (eq (getvar "clayer") "0"))
   (progn
     (setq doc (vla-get-activedocument (vlax-get-acad-object)))
     (vla-setvariable doc "clayer" "0")
     (vla-saveas doc (strcat (getvar "dwgprefix")(getvar "dwgname")))
   )
 )
)

(defun effacer_les_reacteurs_0(/ i j n)
 (if (setq i (vlr-reactors :vlr-editor-reactor))
   (progn
     (setq n 1 i (nth n (car i)))
     (while i
       (setq j nil)
       (if (eq (cdr (car (vlr-reactions i))) 'REACTEUR_CALQUE_0)
         (setq j i)
       )
       (if j
         (vlr-remove i)
         (setq n (1+ n))
       )
       (if (setq i (vlr-reactors :vlr-editor-reactor))
         (setq i (nth n (car i)))
       )
     )
   )
 )
)


(defun creer_reacteur_calque_0()
 (effacer_les_reacteurs_0)
 (setq mrea_0 (vlr-editor-reactor nil (list (cons :vlr-beginclose  (function reacteur_calque_0)))))
 (princ "\nQuitter un dessin sur le calque \"0\" ACTIF")
 (princ)
)

(vl-load-com)
(if (not mrea_0)
 (creer_reacteur_calque_0)
)
(princ)

 

ps : la macro est bien, mais si le sdi > 0, le _.close ne fonctionne plus

 

@+