Nombre de bloc(s) ?

[Patrick_35]

Bonjour

 

Logiquement, la routine ci-jointe devrait compter tout les blocs et même ceux qui sont dynamiques

Merci de me confirmer que cela fonctionne correctement (surtout pour les dynamiques)

 

(defun c:lstbl(/ js bllst ent lstbl)
 (if (setq js (ssget "x" (list (cons 0 "INSERT"))))
   (progn
     (setq lstbl
       (mapcar '(lambda (x)
                  (setq x (vlax-ename->vla-object x))
                  (if (vlax-property-available-p x 'EffectiveName)
                    (vla-get-EffectiveName x)
                    (vla-get-Name x)
                  )
                )
                (mapcar 'cadr (ssnamex js))
       )
     )
     (foreach ent lstbl
       (if (not (member ent (mapcar 'car bllst)))
         (setq bllst (append bllst (list (cons ent (length (vl-remove-if-not '(lambda (x) (eq ent x)) lstbl))))))
       )
     )
     (mapcar '(lambda (x) (princ (strcat "\nIl y a " (itoa (cdr x)) " bloc(s) " (car x)))) bllst)
   )
 )
 (princ)
)

 

@+

[Oli553]

Sa marche. Même pour ceux qui ont été déformé (x et y différent)

Version : ACAD 2007 (démo : ENFIN=>Je test sous Vista ce weekend...)

[Patrick_35]

Merci oli553

Je vais pouvoir maintenant intégrer les blocs dynamiques dans la légende

 

@+

[JUJUZAZA]

Bonjour

 

Effectivement, ça fonctionne, super bien sur mes 2 versions 2002 et 2005. Chapô!!!

 

Peux-tu integrer une fonction , pour compter uniquement des blocs commencant par un préfixe,

par exemple le préfixe "Z" ou autre

 

a+

 

 

[Oli553]

Bon, sa me confirme bien un problème de lancement d'excel depuis 2007.

Flûte :casstet:

[Patrick_35]

Peux-tu integrer une fonction , pour compter uniquement des blocs commencant par un préfixe,

par exemple le préfixe "Z" ou autre

 

voili, voilou, c'est fait et ça marche aussi avec le caractère *

 

(defun c:lstbl(/ js bllst ent lstbl)

 (defun InputBox (Titre Message Defaut / users1 valeur)
   (setq users1 (getvar "users1"))
   (acad-push-dbmod)
   (vla-eval (vlax-get-acad-object) (strcat "ThisDrawing.SetVariable \"USERS1\"," "InputBox (\"" Message "\", \"" Titre "\", \"" Defaut "\")"))
   (setq valeur (getvar "users1"))
   (setvar "users1" users1)
   (acad-pop-dbmod)
   valeur
 )

 (if (not (eq (setq js (InputBox "Décompte de blocs" "Veuillez donnez un nom de bloc ou * pour tous" "*")) ""))
   (if (setq js (ssget "x" (list (cons 0 "INSERT") (cons 2 js))))
     (progn
       (setq lstbl
         (mapcar '(lambda (x)
                    (setq x (vlax-ename->vla-object x))
                    (if (vlax-property-available-p x 'EffectiveName)
                      (vla-get-EffectiveName x)
                      (vla-get-Name x)
                    )
                  )
                  (mapcar 'cadr (ssnamex js))
         )
       )
       (foreach ent lstbl
         (if (not (member ent (mapcar 'car bllst)))
           (setq bllst (append bllst (list (cons ent (length (vl-remove-if-not '(lambda (x) (eq ent x)) lstbl))))))
         )
       )
       (mapcar '(lambda (x) (princ (strcat "\nIl y a " (itoa (cdr x)) " bloc(s) " (car x)))) bllst)
     )
   )
 )
 (princ)
)

 

Bon, sa me confirme bien un problème de lancement d'excel depuis 2007.

???

Tu parles de la légende ?

 

@+

[Oli553]

???

Tu parles de la légende ?

 

@+

 

Oui, pardon, j'ai ecris un peu vite, je croyais qu'il parlait de LG. J'essais de faire un essais avec 2006 dans la semaine... :casstet:

[JUJUZAZA]

FORMIDABLE Patrick, tout fonctionne avec mes 2 versions

 

Merci pour ton LISP !!!

 

a+

[ASTERIXII]

Est-il possible de rajouter une fenêtre de selection ?

Merci d'avance

 

[Edité le 30/11/2006 par ASTERIXII]

[BIM G CO]

peux-tu expliciter? ASTERIXII

[ASTERIXII]

Est-il possible de creer une zone de selection a l'ecran,

pour qu'il ne compte pas l'ensemble des blocs du dessin

[Patrick_35]

Salut

Utilise la fonction bcount

 

@+

[ASTERIXII]

bcount ne compte pas tous nos blocs dynamique

[Bred]

Et pour les blocs imbriqués ??? :casstet:

J'ai une routine en autolisp, mais elle est tellement lourde que ça rame trop...

 

.. en vl, ne serait-ce pas plus performant ???

 

[Edité le 21/12/2006 par Bred]

[Oli553]

Et avec l'extraction d'attributs? :casstet:

[ASTERIXII]

Non, la routine de Patrick_35 est bien, mais j'aurais

je voudrais avoir en plus un selection de zone a l'ecran.

[Patrick_35]

Tu vas le trouver modifié ici

 

@+

[ASTERIXII]

Merci à tous, de répondre pour cette urgence