Filtrer des blocs dynamiques

[Ashram_666]

Bonjour,

j'aimerais pouvoir filtrer des bocs dynamiques à l'aide de leurs noms de création, car lorsque le bloc dynamique à subi sa premier manipulation son nom change et devient par exemple "*u12" dans la fenêtre FILTER.

Quelqu'un aurait peut être une idée ou plusieurs??

Merci

[(gile)]

Salut,

 

Un petit LISP pour sélectionner tous les blocs du dessin dont les nom ont été spécifiés.

 

Taper SBN pour lancer la commande, puis entrer les noms de blocs à sélectionner séparés par une virgule.

 

(defun c:sbn (/ str pos lst ss ent obj name)
 (setq	str
 (getstring
   T
   "\Entrez la liste des blocs à sélectionner (séparés par une virgule): "
 )
 )
 (while (setq pos (vl-string-search "," str))
   (setq lst (cons (substr str 1 pos) lst)
  str (substr str (+ 2 pos))
   )
 )
 (setq lst (mapcar 'strcase (cons str lst)))
 (setq ss (ssget "_X" '((0 . "INSERT"))))
 (repeat (setq n (sslength ss))
   (setq ent (ssname ss (setq n (1- n)))
  obj (vlax-ename->vla-object ent)
   )
   (if	(vlax-property-available-p obj 'EffectiveName)
     (setq name (vla-get-EffectiveName obj))
     (setq name (vla-get-Name obj))
   )
   (if	(not (member (strcase name) lst))
     (ssdel ent ss)
   )
 )
 (sssetfirst nil ss)
 (princ)
)