verr vers unverr

[Fraid]

Bonjour patrick35

 

suite a ton dernier post avec tes lisp

j'ai voulu modifier verr1.01 pour qu'il me deverouille les fenetres

je pensait betement qu'il falait remplacer TRUE par FALSE

(vlax-put-property fen "displaylocked" :vlax-false)

 

et non cela ne marche pas :casstet:

[Patrick_35]

Salut Fraid

L'idée est bonne, sauf que tu as oublié de regarder du coté des codes dxf. Il est vrai que c'est un mélance autolisp/vlisp et que c'est à mes débuts en vlisp

 

Bon, voici la fonction

 

@+

 

;;;=================================================================
;;;
;;; UNVERR.LSP V1.00
;;;
;;; Déverrouiller toutes les fenêtres des présentations
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun c:unverr(/ fen n sel tot)
 (vl-load-com)
 (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))
 (if (setq sel (ssget "x" (list (cons 0 "VIEWPORT"))))
   (progn
     (setq n 0 tot 0)
     (while (ssname sel n)
       (setq fen (vlax-ename->vla-object (ssname sel n)))
       (if (eq (vlax-get-property fen "displaylocked") :vlax-true)
         (progn
           (vlax-put-property fen "displaylocked" :vlax-false)
           (setq tot (1+ tot))
         )
       )
       (setq n (1+ n))
     )
     (princ (strcat "\n"  (itoa tot) " fenêtre(s) de déverrouillée(s)"))
   )
   (princ "\nPas de fenêtres")
 )
 (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
 (princ)
)

(princ "\nUNVERR.LSP chargé. Tapez UNVERR pour l'exécuter")
(princ)

[Fraid]

merci patrick

 

le code dxf n'est pas facile a interpreter comme sa d'un coup d'oiel

je n'ais donc pas vu que tu selectionnais avant les fenetres deveroullées

je pensait que tu les selectionnais toutes :P