deplacement zoom clavier

[amero]

Salut a tous

Merci de votre reponse je connais les commandes zoom et pan

 

maisje souhaite savoir comment utiliser les fleches clavier de deplacement (c'est a dire aller de G a D sur ecran avec cellec ci)

idem comment faire tourner orbite avec fleches clavier

 

idem zoom

 

Merci de votre aide

 

[Tramber]

Ca n'est pas prévu, il faut faire appel à des développements (programmes) ou éventuellement des astuces dans les touches de raccourcis. Mais ca ne marchera pas avec Orbite3D.

[bonuscad]

Par développement on pourrait faire un truc comme ceci:

 

Cela ne fonctionne qu'avec la pavé numérique et celui-ci étant en "NumLock".

 

Cela pourait-il corespondre à ton souhait?

 

;48 = 0
;...= ...
;57 = 9
;43 = +
;45 = -
;42 = *
;47 = /
;46 = .
((lambda ( / pc dd)
(setvar "cmdecho" 0)
(while (and (setq key (grread T 4 0)) (not (member key '((2 13) (2 32)))))
	(setq pc (getvar "VIEWCTR") dd (* (getvar "VIEWSIZE") 0.125))
	(cond
		((eq (cadr key) 42)
			(command "'_.zoom" "_all")
		)
		((eq (cadr key) 43)
			(command "'_.zoom" "1.25X")
		)
		((eq (cadr key) 45)
			(command "'_.zoom" "0.75X")
		)
		((eq (cadr key) 46)
			(command "'_.zoom" "1")
		)
		((eq (cadr key) 47)
			(command "'_.zoom" "_extent")
		)
		((eq (cadr key) 48)
			(command "'_.zoom" "_c" (mapcar '(lambda (x y / ) (* (+ x y) 0.5)) (getvar "VSMIN") (getvar "VSMAX")) "")
		)
		((eq (cadr key) 49)
			(command "'_.-pan" pc (polar pc (* pi 0.25) dd))
		)
		((eq (cadr key) 50)
			(command "'_.-pan" pc (polar pc (* pi 0.5) dd))
		)
		((eq (cadr key) 51)
			(command "'_.-pan" pc (polar pc (* pi 0.75) dd))
		)
		((eq (cadr key) 52)
			(command "'_.-pan" pc (polar pc 0.0 dd))
		)
		((eq (cadr key) 53)
			(command "'_.zoom" "_c" (mapcar '(lambda (x y / ) (* (+ x y) 0.5)) (getvar "VSMIN") (getvar "VSMAX")) "1x")
		)
		((eq (cadr key) 54)
			(command "'_.-pan" pc (polar pc pi dd))
		)
		((eq (cadr key) 55)
			(command "'_.-pan" pc (polar pc (* pi 1.75) dd))
		)
		((eq (cadr key) 56)
			(command "'_.-pan" pc (polar pc (* pi 1.5) dd))
		)
		((eq (cadr key) 57)
			(command "'_.-pan" pc (polar pc (* pi 1.25) dd))
		)
		((eq (car key) 2) (princ " *** Touche non valable! *** "))
	)
)
(setvar "cmdecho" 1)
))

[bonuscad]

Salut,

 

Après la question posée en privé, je réponds ici car la réponse concerne ce message et pourrait être reposée.

 

Pour essayer, sans faire quoi que ce soit comme modification à AutoCAD.

-> faire un copier-coller depuis la 1ère paranthèse ((lambda ....)) à la dernière.

-> mettre la ligne de commande d'autocad "active" par un click dans la barre de commande

-> coller directement dans cette barre active et valider la dernière parenthèse par "Entrée".

Cela te permettra d'essayer la fonction 1 fois, si tu veux la relancer, tu recolles en ligne de commande.

(en effet la fonction Lambda est supprimé de la mémoire après execution)

 

Si cela t'interesse pour l'avoir en permanence tu fais un coller dans le bloc-note

Tu modifie "((lambda" en "(defun c:qz" par exemple, (mnémonique de Quick Zoom pour la ligne de commande)

Tu supprimes la dernière paranthèse (il y a une paranthèse en moins dans la modif ci dessus)

et tu enregistres sous QZ.LSP et tu pourras l'utiliser comme tout autres lisps (le chargé et l'executer)