Inverser la sélection

[(gile)]

Il peut être intéressant (d'ailleurs je l'ai fait parceque j'en ai eu besoin) d'inverser une sélection.

 

Voici donc un petit LISP qui le fait, on peut taper inv_sel à la ligne de commande ou mettre la macro ^C^Cinv_sel; dans un bouton, ou dans le menu contextuel "Edition" :

 

http://img149.imageshack.us/img149/1389/invselvw5.png

 

Le LISP :

 

(defun c:inv_sel (/ ssa ssf n e)
 (setq ssa (ssget "_A" '((0 . "~VIEWPORT"))))
 (if (setq ssf (cadr (ssgetfirst)))
   (repeat (setq n (sslength ssa))
     (if (ssmemb (setq e (ssname ssa (setq n (1- n)))) ssf)
(ssdel e ssa)
     )
   )
 )
 (sssetfirst nil ssa)
) 

[BTO]

Bonjour Gile, je viens de m'intéresser à ta suggestion.

 

De manière générale le fait d'utiliser (sssetfirst) avant (sssetfirst nil ss) a une grande incidence si le nombre initial d'entités avec grip est important (plusieurs milliers). Pour chaque entité, on peut aussi supprimer un if et un member, puisqu’on retranche toutes les entités de ssf à ssa. Finalement en partant de ton travail j'arrive à :

 

(defun c:inv_sel2 (/ ssa ssf n)
 (setq ssa (ssget "_A" (list (cons 410 (getvar "ctab")))))
 (if (setq ssf (cadr (ssgetfirst)))
   (repeat (setq n (sslength ssf))
     (ssdel (ssname ssf (setq n (1- n))) ssa)
   )
 )
 (sssetfirst)
 (sssetfirst nil ssa)
)

 

Cordialement,

Bruno Toniutti

[(gile)]

on peut aussi supprimer un if et un member

Bien sûr ! Des fois je ne vois pas mon nez au milieu de ma figure !

 

Je te remercie pour le conseil d'utilisation de (sssetfirst), je ne connaissais pas cette incidence.

 

Merci pour tout.