decomposer polyligne

[Fraid]

bonjour,

 

Dans le meme esprit que raccorder sans joindre

j'aimerai decomposer (pas exploser) une polyligne (sans arc) selon ces grips tout en gardant son epaisseur.

 

Amis lisper merci

[bonuscad]

Pour découper une/des LwPolylignes à chacun de ses sommets en conservant toutes ses propriétés.

Fonctionne aussi avec les PolyArcs (tant qu'à faire) ;)

(defun c:break_lw ( / js i ent dxf_obj dxf_43 dxf_38 dxf_39 dxf_10 dxf_40 dxf_41 dxf_42 dxf_39 dxf_210 n)
(initget "Toutes Sélection _All Select")
(if (eq (getkword "\nLWPolylignes à couper à chaque sommets? [Toutes/Sélection] : ") "All")
	(setq
		js
			(ssget "_X" 
				(list
					(cons 0 "LWPOLYLINE")
					(cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
					(cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
				)
			)
		i -1
	)
	(setq
		js
			(ssget
				(list
					(cons 0 "LWPOLYLINE")
					(cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
					(cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
				)
			)
		i -1
	)
)
(cond
	(js
		(repeat (sslength js)
			(setq dxf_obj (entget (setq ent (ssname js (setq i (1+ i))))))
			(if (cdr (assoc 43 dxf_obj))
				(setq dxf_43 (cdr (assoc 43 dxf_obj)))
				(setq dxf_43 0.0)
			)
			(if (cdr (assoc 38 dxf_obj))
				(setq dxf_38 (cdr (assoc 38 dxf_obj)))
				(setq dxf_38 0.0)
			)
			(if (cdr (assoc 39 dxf_obj))
				(setq dxf_39 (cdr (assoc 39 dxf_obj)))
				(setq dxf_39 0.0)
			)
			(setq
				dxf_10 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) dxf_obj))
				dxf_40 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 40)) dxf_obj))
				dxf_41 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 41)) dxf_obj))
				dxf_42 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 42)) dxf_obj))
				dxf_210 (cdr (assoc 210 dxf_obj))
			)
			(if (not (zerop (boole 1 (cdr (assoc 70 dxf_obj)) 1)))
				(setq
					dxf_10 (append dxf_10 (list (car dxf_10)))
					dxf_40 (append dxf_40 (list (car dxf_40)))
					dxf_41 (append dxf_41 (list (car dxf_41)))
					dxf_42 (append dxf_42 (list (car dxf_42)))
					n (cdr (assoc 90 dxf_obj))
				)
				(setq n (1- (cdr (assoc 90 dxf_obj))))
			)
			(repeat n
				(entmake
					(list
						(cons 0 "LWPOLYLINE")
						(cons 100 "AcDbEntity")
						(assoc 67 dxf_obj)
						(assoc 410 dxf_obj)
						(assoc 8 dxf_obj)
						(if (assoc 62 dxf_obj) (assoc 62 dxf_obj) (cons 62 256))
						(if (assoc 6 dxf_obj) (assoc 6 dxf_obj) (cons 6 "BYLAYER"))
						(if (assoc 370 dxf_obj) (assoc 370 dxf_obj) (cons 370 -1))
						(cons 100 "AcDbPolyline")
						(cons 90 2)
						(cons 70 (boole 1 (cdr (assoc 70 dxf_obj)) 128))
						(cons 38 dxf_38)
						(cons 39 dxf_39)
						(cons 10 (car dxf_10))
						(cons 40 (car dxf_40))
						(cons 41 (car dxf_41))
						(cons 42 (car dxf_42))
						(cons 10 (cadr dxf_10))
						(cons 40 (cadr dxf_40))
						(cons 41 (cadr dxf_41))
						(cons 42 (cadr dxf_42))
						(assoc 210 dxf_obj)
					)
				)
				(setq dxf_10 (cdr dxf_10) dxf_40 (cdr dxf_40) dxf_41 (cdr dxf_41) dxf_42 (cdr dxf_42))
			)
			(entdel ent)
		)
		(print (sslength js)) (princ " LWpolyligne(s) coupée(s) à ses sommets.")
	)
)
(prin1)
)

 

[Edité le 25/7/2006 par bonuscad]

[Fraid]

merci

 

grace a vous je me construit un super autocad

[lecrabe]

 

ReBonsoir

 

Encore un BRAVO pour Bonuscad, je viens de tester sa routine avec des polylignes 2D assez farfelues au niveau des épaisseurs, sur lesquelles je fais donc un BREAK_LW puis un PEDIT Joindre et OH MIRACLE ? je retrouve bien la polyligne de DEPART !!! :) :D :cool:

 

Encore MERCI, Le Decapode "breakant"