reduction de texte de cote

[Fraid]

bonjour,

 

Pour une raison d'encombrement j'aimerai que les cotes qui font moins de 0.10 soit reduite en supprimant 0.0

 

exemple: 0.07 deviendrai 7

 

je ne trouve rien dans les options des style de cotes

y a t'il un truc que je n'ai pas vu??

 

merci

 

[bonuscad]

Je pense que le seul moyen est de créer un autre style de cote qui serait une copie de celui employé et auquel tu change juste (dans l'onglet "unités principales") le facteur d'échelle dans "l'échelle de mesure": ici un facteur de 100 serait approprié.

Tu change aussi la précision des unités de mesure en la passant à zéro (pas de décimales)

 

Une fois ce style créé tu change manuellement ou par une routine les cotes voulues.

 

Si tu veux faire une routine, je pense qu'il faut tester l'interdistance entre les points d'attaches, et si celui-ci est inférieur à 1, changer le style de cote....

[Fraid]

merci pour ta reponse

 

Mais malheureusement la charte graphique du client m'impose un seul style de cote

:P

 

J'ai deja pris le risque de la modifier

 

je pense que je vais rester avec ma selection rapide

c'est generalement des cloison de 7 ou de 5

 

c'etait surtout pour savoir si j'avais rater quelque chose dans la gestion des style de cote que je trouve assez lourde

 

merci

[fanion]

Tu peus aussi directement changer le facteur d'echelle de la fenetre de prop. et ensuite copier les prop. de la cote, le tous sans changer de style.

Peut etre qu'un lispeur pourrait automatiser le tous? ;)

[Fraid]

bien vu fanion

 

il faut aussi que je supprime les zeros de la fin

 

avec selection rapide des cotes inferieurs a 0.1

c'est vrais que cela doit etre lispable

 

il faut aussi qu'elle est _aidimtextmove egal a 2

pour que je puisse les deplacer aisement car elle se trouve toujours sur la cloison donc illisible

et ça, je ne l'ai pas trouver dans la fenetre de proprietes :exclam:

[bonuscad]

Une occasion pour moi d'explorer les fonctions (vla) ;)

 

((lambda ( / obj_vla)
(vl-load-com)
(setq obj_vla (vlax-ename->vla-object (car (entsel))))
(vla-put-LinearScaleFactor obj_vla 1000)
(vla-put-PrimaryUnitsPrecision obj_vla 0)
(vla-put-SuppressLeadingZeros obj_vla -1)
(prin1)
))

 

Tu peux encore creuser la chose...

[Fraid]

merci bonuscad

 

mais cela ne fontionne pas si je les selectionne avant

je suis donc obliger de les selectionner une par une :P

a moins que tu me sorte l'incantation permetant de selectionner automatiquement les cotes inferieur a 0.10 ;)

[bonuscad]

A toi d'ajuster si ça ne convient pas

 

((lambda ( / js n ent obj_vla)
(setq js
	(ssget "_X"
		(list
			(cons 0 "DIMENSION")
			(cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
			(cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
		)
	)
)
(cond
	(js
		(vl-load-com)
		(setq n -1)
		(repeat (sslength js)
			(setq ent (ssname js (setq n (1+ n))))
			(setq obj_vla (vlax-ename->vla-object ent))
			(if (< (vla-get-Measurement obj_vla) 1.0)
				(progn
					(vla-put-LinearScaleFactor obj_vla 1000)
					(vla-put-PrimaryUnitsPrecision obj_vla 0)
					(vla-put-SuppressLeadingZeros obj_vla -1)
				)
			)
		)
	)
)
(prin1)
))

[Fraid]

genial

 

j'ai juste mis LinearScaleFactor a 100

 

c'est impeccable

 

:D

[bonuscad]

L'inconvénient de cette méthode, bien qu'elle fonctionne bien, et que si tu met à jour ta cotation; tes modifications sont perdues.

 

C'est pour cela que je pense quand même que la solution du nouveau style est plus fiable.

 

Mais bon la mise à jours avec le lisp peut être vite faites, mais ne pas oublier que ce fichier t'a été demander par un tiers et qu'il rique de ne plus retrouver ce genre de cotation s'il est manipuler par d'autre par la suite, sur un autre poste.

 

Je tenais à le souligner.... à toi de voir...