Distances cumulées

[jeanmi66]

Bonjour,

 

j'ai une polyligne composée de 4 tronçons. Je voudrais mesuré le cumul des 3 premiers. Existerait-il une astuce ou commande pour calculer une disctance en cliquant les points successivement ?

 

Merci d'avance.

 

PS: évitons les solutions style "distance totale de la polyligne dans les propriétés, moins le dernier tronçon". Merci

[Fraid]

bonjour,

 

Si tu veux cliquer les pts successivement autant en profiter pour redessiner une polyligne

 

a moin que je n'ai pas tout compris??? :P

[Tramber]

(defun c:didi(/ obj)
 (setq obj(vlax-ename->vla-object(car (entsel))))  
 (princ(vl-princ-to-string(vlax-curve-getDistAtPoint obj(vlax-curve-getClosestPointTo obj (getpoint)))))(princ))

 

Copie ce code dans un fichier *.lsp

Charge ce lisp en tapant APPLOAD et tape DIDI, ca va tout seul

[jeanmi66]

Merci Tramber, je vais essayer ça !

 

A+

[Patrick_35]

Salut

Un petit lisp pour mesurer facilement sur Autocad

 

(defun c:mes (/ pt1 pt2 tot)
 (setq tot 0)
 (if (setq pt1 (getpoint "\nPremier point : "))
   (while (setq pt2 (getpoint pt1 "\nPoint suivant : "))
     (setq tot (+ tot (distance pt1 pt2)))
     (princ (strcat "\n Distance cumulée : " (rtos tot) " --> Distance mesurée : " (rtos (distance pt1 pt2))))
     (setq pt1 pt2)
   )
 )
 (princ)
)

 

@+

 

[Edité le 13/7/2006 par Patrick_35]

[(gile)]

La routine de Tramber respecte scrupuleusement tes données : elle te donneras la distance du début de la polyligne au point spécifié.

 

Si tu veux la distance de la fin de la poly au point sélectionné, il faudra inverser les sommets.

 

Ou, plus simple, sélectionner 2 sommets pour avoir la distance entre les deux :

 

(defun c:di2pt (/ obj)
 (setq	obj (vlax-ename->vla-object
      (car (entsel "\nSélectionnez la polyligne: "))
    )
 )
 (princ (vl-princ-to-string
   (abs	(- (vlax-curve-getDistAtPoint
	     obj
	     (vlax-curve-getClosestPointTo
	       obj
	       (getpoint "\n Premier point: ")
	     )
	   )
	   (vlax-curve-getDistAtPoint
	     obj
	     (vlax-curve-getClosestPointTo
	       obj
	       (getpoint "\n Second point: ")
	     )
	   )
	)
   )
 )
 )
 (princ)
)

 

[Edité le 13/7/2006 par (gile)]