Aller au contenu

echelle annotative


x_all

Messages recommandés

Bonjour

Je bosse sur mes lots technique avec un fond de plan en Xref (en fait j'en ai 4)L'archi utilise les échelle anotative pour ses nom de pièces, ces noms sont encadrés avec une polyligne.Pour que le texte soit bien cadré dans l'Xref, il faut que je place l’échelle annotative sur 1/200Dans l'espace objet, je règle mon echelle sur cette valeur, et ça marche.Le problème, c'est que j'imprime au 1/50. dans mon espace objet, les texte se replace par défaut au 1/100 (?) il sont donc 2 fois trop gros et sortent du cadre

 

Comment faire revenir les textes à la bonne hauteur?

merci...

 

Lien vers le commentaire
Partager sur d’autres sites

Salut x_all,

 

j'ai jeté un oeil sur les Xrefs, il y a déjà un premier truc qui chie :

tous les Mtext ne sont pas annotatifs

L'annotativité a été forcée sur les textes, elle n'est aps définit dans les styles du texte

 

J'ai cherché un truc pour nettoyer les objets annotatifs mais je n'arrive plus à remettre la main dessus!!!! :/

 

bref, je suis désolé mais je n'ai pas d'autre solution à te proposer, au vu de ton problème, que de choper tous ces textes annotatifs et leur enlever l'annotativité (entre nous l'archi s'est bien chié sur ses objets annotatifs)

 

j'ai oulu t'envoyer un mail mais ça n'a semble-t-il pas marché!! :/

 

Phil

Projeteur Revit Indépendant - traitement des eaux/CVC

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Les objets ANNOTATIFs ca peut etre BIEN !

MAIS ca peut aussi etre une horreur quand cela a ete mal exploite et/ou defini

SANS parler d'objets "moitie/moitie" ...

 

Veuillez trouver ci-apres 2 routines "plus ou moins utiles" ...

 

COMME D'HABITUDE MERCI a GILLES : un Dieu du Lisp/VLisp/etc ...

 

LA SANTE, Bonnes Fetes, Bye, lecrabe (Extraction de mon stock de 2000 routines)

 


;; 
;; Routine: SelAnnot par GC 
;; 
;; GC >>> Noter que pour les lignes de repere non multiple (ancienne mode) 
;; SEUL le texte peut être annotatif, ils sont donc traites dans la categorie "Texte mtexte"
;; (Pas teste en profondeur)
;; 
;; Supprime du jeu de selection les objets non annotatifs 
;; 

(defun filterAnnot (ss / i ent dict)
 (if ss
   (repeat (setq i (sslength ss))
     (setq ent (ssname ss (setq i (1- i))))
     (if (not (setq dict (cdadr (member '(102 . "{ACAD_XDICTIONARY") (entget ent)))))
       (ssdel ent ss)
       (if (not (setq dict (cdr (assoc -1 (dictsearch dict "AcDbContextDataManager")))))
         (ssdel ent ss)
         (if (not (dictsearch dict "ACDB_ANNOTATIONSCALES"))
           (ssdel ent ss)
         )
       )
     )
   )
 )
 ss
)

;; Sélectionne les objet annotatifs par type
(defun c:selannot (/ kw ss fr)
 (initget "Texte Hachure Cotation Repere")
 (setq kw (getkword
            "\nChoisir une option [Texte mtexte/Hachure/Cotation/ligne de Repere multiple] <Texte>: "
          )
       fr (cond
            ((= kw "Hachure") '((0 . "HATCH")))
            ((= kw "Cotation") '((0 . "DIMENSION")))
            ((= kw "Repere") '((0 . "MULTILEADER")))
            (T '((0 . "TEXT,MTEXT")))
          )
 )
 (sssetfirst nil (filterAnnot (ssget fr)))
)

 

 

 
;; 
;; Par GC le 05/02/2010 - Message No 8 - Commande au clavier : ANNOT_REMOVE
;; 
;; La routine ci-dessous supprime l'annotativite des objets selectionnes : 
;; MTEXT, TEXT, DIMENSION, LEADER, MULTILEADER 
;; Je n'ai pas trouve pour les blocs (INSERT) 
;; D'ailleurs l'annotativite des blocs est en lecture seule dans la fenetre des proprietes 
;; 

;; (defun c:RANNOT        (/ n ss ent)
  (defun c:ANNOT_REMOVE  (/ n ss ent)
 (if (setq n  -1
    ss (ssget '((0 . "MTEXT,TEXT,DIMENSION,LEADER,MULTILEADER")))
     )
   (while (setq ent (ssname ss (setq n (1+ n))))
     (gc:RemoveAnnot ent)
   )
 )
 (princ)
)

;;============================================================;;;

;; gc:RemoveAnnot (gile)
;; Supprime l'annotativité de l'entité
;; Retourne la nouvelle liste DXF l'entité (ou nil)
;;
;; Argument : ent (ENAME) le nom de l'entité

(defun gc:RemoveAnnot (ent / elst typ)
 (setq	elst (entget ent '("AcadAnnotative"))
typ  (cdr (assoc 0 elst))
 )
 (cond
   ((member typ '("MTEXT" "TEXT" "DIMENSION" "LEADER"))
    (entmod
      (subst
 '(-3
   ("AcadAnnotative"
    (1000 . "AnnotativeData")
    (1002 . "{")
    (1070 . 1)
    (1070 . 0)
    (1002 . "}")
   )
  )
 (assoc -3 elst)
 elst
      )
    )
   )
   ((= typ "MULTILEADER")
    (setq elst (reverse elst))
    (entmod (reverse (subst '(293 . 0) (assoc 293 elst) elst)))
   )
 )
) 

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

pop pop pop ! c'est Noël !!

 

merci à vous trois, même sans rien dire il y a toujours un peu de (gile) dans un tread de ce forum.

 

Comme je me sert jamais de cette fonction, je me disait que je ne savais pas bien les utiliser... apparemment, je ne suis pas le seul. Au tant tout mettre à plat. ça devrai faire des miracle.. je testerai, mais là, c'est les vacances :)

alors bonne fêtes à tous...

Lien vers le commentaire
Partager sur d’autres sites

  • 5 mois après...

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité