CADxp: exporter les vues - CADxp

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

exporter les vues

#1 L'utilisateur est hors-ligne   stephane.GEFFARD 

  • ceinture jaune
  • Groupe : Membres
  • Messages : 6
  • Inscrit(e) : 28-décembre 04

Posté 22 janvier 2010 - 14:32

Bonjour à tous,
est qu'il existe une manipulation pour exporter les vues d'un fichier à un autre.

Autocad map 2010

Merci

Stéphane
0

#2 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11181
  • Inscrit(e) : 02-septembre 05

Posté 23 janvier 2010 - 15:35

Salut,


Je te propose un LISP.

Deux commandes :

ImportViews : pour importer dans le dessin courant toutes les vues enregistrées du dessin sélectionné (il doit être fermé).


ExportViews : pour Exporter dans le dessin sélectionné (il doit être fermé) toutes les vues enregistrées du dessin courant.


;;; ImportViews (gile)
;;; Importe dans le dessin courant toutes les vues enregistrées
;;; du dessin sélectionné

(defun c:ImportViews (/ filename doc lst)
  (vl-load-com)
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
  (if (setq filename (getfiled "Fichier source" "" "dwg" 0))
    (if (setq doc (gc:GetAxDbDoc filename))
      (progn
        (vlax-for v (vla-get-Views doc)
          (setq lst (cons v lst))
        )
        (if lst
          (progn
            (vlax-invoke doc 'CopyObjects lst (vla-get-Views *acdoc*))
            (vlax-release-object doc)
          )
        )
      )
      (alert
        (strcat
          "\nLe fichier \""
          filename
          "\" est ouvert.\nFermer le avant de relancer ImportViews"
        )
      )
    )
  )
  (princ)
)

;;; ExportViews (gile)
;;; Exporte dans le dessin sélectionné toutes les vues enregistrées
;;; du dessin courant

(defun c:ExportViews (/ filename doc lst)
  (vl-load-com)
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
  (if (setq filename (getfiled "Fichier cible" "" "dwg" 0))
    (if (setq doc (gc:GetAxDbDoc filename))
      (progn
        (vlax-for v (vla-get-Views *acdoc*)
          (setq lst (cons v lst))
        )
        (if lst
          (progn
            (vlax-invoke *acdoc* 'CopyObjects lst (vla-get-Views doc))
            (vla-SaveAs doc filename)
            (vlax-release-object doc)
          )
        )
      )
      (alert
        (strcat
          "\nLe fichier \""
          filename
          "\" est ouvert.\nFermer le avant de relancer ExportViews"
        )
      )
    )
  )
  (princ)
)

;;; gc:GetAxDbDoc
;;; Accéder à un dessin fermé
;;;
;;; Retourne :
;;; un objet IAxDbDocument si le document est trouve
;;; nil si le document n'a pu être trouvé ou s'il est ouvert
;;;
;;; Argument :
;;; Le chemin complet du fichier
;;;
;;; Exemple d'utilisation :
;;; (if (setq doc (gc:GetAxDbDoc filename))
;;;   (progn
;;;     ...
;;;     (vla-SaveAs doc filename)
;;;     (vlax-release-object (car doc))
;;;   )
;;; )

(defun gc:GetAxDbDoc (filename / axdbdoc release)
  (setq axdbdoc
         (vlax-create-object
           (if (< (setq release (atoi (getvar "ACADVER"))) 16)
             "ObjectDBX.AxDbDocument"
             (strcat "ObjectDBX.AxDbDocument." (itoa release))
           )
         )
  )
  (if (vl-catch-all-apply
        'vla-open
        (list axdbdoc filename)
      )
    (not (vlax-release-object axdbdoc))
    axdbdoc
  )
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#3 L'utilisateur est hors-ligne   stephane.GEFFARD 

  • ceinture jaune
  • Groupe : Membres
  • Messages : 6
  • Inscrit(e) : 28-décembre 04

Posté 27 janvier 2010 - 13:36

Merci de ton aide.

Stéphane
0

#4 L'utilisateur est hors-ligne   grandss 

  • ceinture noire
  • Groupe : Membres
  • Messages : 397
  • Inscrit(e) : 09-juillet 07
  • LocationLuxembourg

Posté 18 juillet 2018 - 07:26

Salut,

Malgré tout ce temps, tu m'a encore été d'un grand secours (gile).
Merci.
Autocad MEP 2017
0

#5 L'utilisateur est hors-ligne   Tryks 

  • ceinture orange
  • Groupe : Membres
  • Messages : 29
  • Inscrit(e) : 27-avril 18

Posté 17 avril 2019 - 12:47

Bonjour,

Je m'y connais pas en lips, serait-il possible de prédéfinir l'emplacement du fichier ?
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)