mon programme lui manque qlq chose

[doua]

rebonjour tout le monde !

 

en fait je ne veux pas laisser tombé mon programme car je crois qu'il lui manque un petit qlq chose que j'ignore :(

 

alors je vous demande encors une fois s'il ya qlq qui connaît bien le vba sous autocad de me donnée un coup de main ça sera gentille de ça part !! :)

 

voilà ou je suis arrivée :

 

nb: j'ai plusieurs blocs posés dans le même espace papier "layout1" il ont le même nom

et différents format a4 a3 .)

 

alors mon programme il cherche le nom du bloc "xxxx" il trouve le 1er il cherche sont point d'insertion (point0,point1) et doit l'imprime mais il ne le fait pas !!!

 

 

voila une copie du programme :

 

'IMPRESSION AUTOMATIQUE

 

Public Sub VerifierBloc()

Dim objBloc As AcadBlock

Dim PlotConfig As AcadPlotConfiguration

Dim objonglets As AcadLayouts

Dim objonglet As AcadLayout

Dim strNomDuBloc As String

Dim nomconfig As String

Dim orige(0 To 2) As Double

Dim x0 As Double

Dim y0 As Double

Dim x1 As Double

Dim y1 As Double

Dim a As Double

Dim b As Double

a = 198

b = 285

Dim point0(0 To 1) As Double

Dim point1(0 To 1) As Double

 

'-----------------------------------------------

Set objonglets = ThisDrawing.Layouts

Set objonglet = objonglets.Item("layout1")

nomconfig = "Plot"

strNomDuBloc = "fiche de lance"

'ReDim Preserve point0(0 To 1)

'ReDim Preserve point1(0 To 1)

For Each objBloc In ThisDrawing.Blocks

If 0 = StrComp(objBloc.Name, strNomDuBloc, 1) Then

 

x0 = objBloc.origin(0)

y0 = objBloc.origin(1)

point0(0) = x0: point0(1) = y0

 

 

x1 = x0 + a

y1 = y0 + b

point1(0) = x1: point1(1) = y1

 

Set PlotConfig = ThisDrawing.PlotConfigurations(nomconfig)

ThisDrawing.ActiveLayout.ConfigName = nomconfig

'ThisDrawing.PlotConfigurations("layout1").ConfigName = nomconfig

'PlotConfig.SetWindowToPlot (point0, point1)

ThisDrawing.ActiveLayout.SetWindowToPlot point0, point1

ThisDrawing.ActiveLayout.GetWindowToPlot point0, point1

ThisDrawing.ActiveLayout.PlotType = acWindow

ThisDrawing.Plot.PlotToDevice

 

 

End If

Next objBloc

 

End Sub

 

 

 

 

 

 

je vous remerci tous

amicalement

 

[Chrisfs]

Bonsoir,

 

For Each objBloc In ThisDrawing.Blocks

...

Next objBloc

 

 

Selon moi, avec cette commande, tu ne "scannes" pas les réferences de blocs de l'espace objet ou papier, mais plutôt la "base de données" des blocs du fichier autocad.

 

pour cela il faut plutôt faire :

 

For Each objBloc in ThisFrawing.Modelspace (ou Paperspace).

 

qui là, va scanner les réferences de blocs insérer dans le dessin.

 

Voila

 

Christophe Rosé

 

[winfield]

Bonsoir,

 

D'après ce que tu m'as dit dernièrement, tes blocs sont tous les un à côté des autres et lors de l'impression tu veux tout imprimer d'un coup. Pourtant ici tu essaies de faire bloc par bloc. :casstet:

Je ne sais pas dans dans les autres langages, mais en VB/VBA tu ne peux pas donner à une variable un nom commençant par un chiffre.

 

 

 

[doua]

salut winfield,

oui c'est ce que je veux "imprimer bloc par bloc "

 

 

salut Chrisfs,

et merci pour l'interêt que tu as donné à mon problème

 

Selon moi, avec cette commande, tu ne "scannes" pas les réferences de blocs de l'espace objet ou papier, mais plutôt la "base de données" des blocs du fichier autocad.

 

pour cela il faut plutôt faire :

 

For Each objBloc in ThisFrawing.Modelspace (ou Paperspace).

on fait quand tu dit scaner tu veux dire imprimer non !

 

parce que moi dans mon dessin il ya plusieurs fiche qui portes le même nom bloc "fiche de lance" ok ! et je veux que mon programme fait une recherche du 1er bloc qu'il trouve = à "fiche de lance" et il m'enregistre ces coordonée pour avoir une fenêtre (x,y) et imprimer.

aprés il passe au 2ème bloc qui est aussi = au "fiche de lance" et mémoriser ces coordonées et l'imprimer et ainsi de suite ...

voilà ce que je veux faire exctement et bien sûr dans la même feuille de presentation .

 

merci de votre aide

[winfield]

Salut,

Je vais essayer de t'aider, mais je suis loin d'être un expert, alors si je dis des bêtises,je vous demande de m'arrêter ( juste m'arrêter, pas me mettre en prison) :p

.............................................................................................................

 

on fait quand tu dit scaner tu veux dire imprimer non !

 

Non pas du tout, comme Chrisfs te l'a dit, For Each............ sert à chercher.

Dans ton code, tu cherches une définition de bloc dans la base de données d'autocad, mais de ce fichier seulement.

La définition du bloc peut exister dans la base, mais inexistant dans le dessin.....s'il est inséré, voir où il est inséré. Est-il inséré dans l'espace objet ? ou dans une présentation ?

Il faut faire attention avec For Each.. car l'objet que tu recherches doit être déclaré en tant que AcadEntity (à moins que la recherche soit faite dans la base d'acad ou dans une sélection qui a déjà été filtré).

 

Ici, la routine va te donner tous les noms des blocs existant du fichier).

............

Dim ObjBloc As AcadBlock

For Each ObjBloc In ThisDrawing.Blocks

MsgBox ObjBloc.Name

Next

............

Ici, la routine va te donner tous les noms des blocs inséré dans l'espace objet), mais ObjBloc est déclaré en tant que AcadEntity, car pendant la recherche, il peut tomber sur tout et n'importe quoi.

............

Dim ObjBloc As AcadEntity

For Each ObjBloc In ThisDrawing.ModelSpace

If ObjBloc.ObjectName = "AcDbBlockReference" Then

MsgBox ObjBloc.Name

End If

Next

End Sub

............

En espérant avoir été clair.

 

Maintenant, j'ai cherché comment faire, mais où je coince c'est que :

la 1ère impression est lancé, la 2ème se lance mais renvoi une erreur (action déjà occupé), et en plus l'impression est lente.

Enfin, voilà ce que j'ai fais.

Sub Imprimer()

Dim ObjEntite As AcadEntity
Dim StrNomBloc As String
Dim ObjOnglets As AcadLayouts
Dim StrNomOnglet As String
Dim PtBas As Variant
Dim PtHaut As Variant
Dim StrImprimante As Variant
Dim StrNomLayout As String
Dim IntI As Integer
Dim StrListe As String
Dim Q As Integer
'Pour avoir le choix de l'onglet à imprimer
'on retourne le n° de l'onglet
StrListe = "N° onglet à imprimer:" & Chr(13)
StrNomBloc = "MonBloc"
StrImprimante = "HP DeskJet 1125C.pc3"

Set ObjOnglets = ThisDrawing.Layouts
For IntI = 0 To ObjOnglets.Count - 1
Set ObjOnglet = ObjOnglets(IntI)
StrListe = StrListe & vbCrLf & "<" & IntI & "> " & ObjOnglet.Name
Next
Q = InputBox(StrListe)
'On active l'onglet choisit
ThisDrawing.ActiveLayout = ObjOnglets(Q)
'On recherche tous les blocs dans l'onglet choisit
'si on en trouve, on récupère l'emprise rectangulaire du bloc pour
'indiquer la zone à imprimer
For Each ObjEntite In ThisDrawing.PaperSpace
If ObjEntite.ObjectName = "AcDbBlockReference" Then
If ObjEntite.Name = StrNomBloc Then
ObjEntite.GetBoundingBox PtBas, PtHaut
ReDim Preserve PtBas(0 To 1)
ReDim Preserve PtHaut(0 To 1)
ThisDrawing.ActiveLayout.SetWindowToPlot PtBas, PtHaut
'echelle d'impression (n'est pas celle de l'objet fenêtre
ThisDrawing.Layouts(Q).SetCustomScale 1, 1
ThisDrawing.ActiveLayout.PlotType = acWindow
'on lance l'impression
ThisDrawing.Plot.PlotToDevice StrImprimante
End If
End If
Next
End Sub

Je me demande s'il faudrait pas créer des vues et imprimer ces vues. Qu'en pensez-vous ?

[winfield]

Cette fois je crois que c'est bon, le problème venait de la variable BackGroundPlot.

Voilà ce que ça donne :

 Sub Imprimer()

   Dim ObjEntite As AcadEntity
   Dim StrNomBloc As String
   Dim ObjOnglets As AcadLayouts
   Dim StrNomOnglet As String
   Dim PtBas As Variant
   Dim PtHaut As Variant
   Dim StrImprimante As Variant
   Dim StrNomLayout As String
   Dim IntI As Integer
   Dim StrListe As String
   Dim Q As Integer
   Dim CompteurBloc As Integer
   Dim sysVarName As String
   Dim VarDataOrigine As Variant
   Dim VarDataTemp As Variant
   
   StrListe = "N° onglet à imprimer:" & Chr(13)
   StrNomBloc = "MonBloc"
   StrImprimante = "DWF6 ePlot.pc3"
   'StrImprimante = "HP DeskJet 1125C.pc3"
   CompteurBloc = 0
   sysVarName = "BACKGROUNDPLOT"
   'Lecture de la valeur de BackGroundPlot
   VarDataOrigine = ThisDrawing.GetVariable(sysVarName)
   VarDataTemp = 0
   
   'Pour avoir le choix de l'onglet à imprimer
   'on retourne le n° de l'onglet
   Set ObjOnglets = ThisDrawing.Layouts
   For IntI = 0 To ObjOnglets.Count - 1
       Set ObjOnglet = ObjOnglets(IntI)
       StrListe = StrListe & vbCrLf & "<" & IntI & "> " & ObjOnglet.Name
   Next
   On Error Resume Next
   Q = InputBox(StrListe)
   'vérification de l'existance de l'onglet choisit
   If Q > IntI - 1 Then
       MsgBox "Cet onglet n'existe pas"
       Exit Sub
   End If
   'si aucun onglet choisit
   If Err = 13 Then
       Err.Clear
       Exit Sub
   End If
   'On active l'onglet choisit
   ThisDrawing.ActiveLayout = ObjOnglets(Q)
   'Changement de valeur de BackGroundPlot à zéro
   ThisDrawing.SetVariable sysVarName, VarDataTemp
   'On recherche tous les blocs dans l'onglet choisit
   'si on en trouve, on récupère l'emprise rectangulaire du bloc pour
   'indiquer la zone à imprimer
   For Each ObjEntite In ThisDrawing.PaperSpace
       If ObjEntite.ObjectName = "AcDbBlockReference" Then
           If ObjEntite.Name = StrNomBloc Then
               CompteurBloc = CompteurBloc + 1
               ObjEntite.GetBoundingBox PtBas, PtHaut
               ReDim Preserve PtBas(0 To 1)
               ReDim Preserve PtHaut(0 To 1)
               ThisDrawing.ActiveLayout.SetWindowToPlot PtBas, PtHaut
               'echelle d'impression (n'est pas celle de l'objet fenêtre
               ThisDrawing.Layouts(Q).SetCustomScale 1, 1
               'On centre le tracé
               ThisDrawing.ActiveLayout.CenterPlot = True
               ThisDrawing.ActiveLayout.PlotType = acWindow
               'on lance l'impression
               ThisDrawing.Plot.PlotToDevice StrImprimante
           End If
       End If
   Next
   If CompteurBloc = 0 Then
       MsgBox "Il n'y a pas de bloc " & StrNomBloc & " dans cette onglet."
   End If
   'on remet la valeur de départ à BackGroundPlot
   ThisDrawing.SetVariable sysVarName, VarDataOrigine
End Sub

Si vous avez des remarques ou suggestions, je suis tout yeux

[doua]

salut winfield,

 

vraiment je te remercie pour ta précieuse aide !! :D

 

je vais le tester et je te tiendrais au courant ok !

 

je m'excuse je t'ai pas répondu trés vite car je ne me suis pas connécter de puis mnt une semaine !!! :o

 

merci encors winfield

 

amicalement

doua

[doua]

merci bien winfield,

mais j'ai encors de question s'il te plait

 

 

 

 

A) sysVarName = "BACKGROUNDPLOT"

'Lecture de la valeur de BackGroundPlot

VarDataOrigine = ThisDrawing.GetVariable(sysVarName)

VarDataTemp = 0

 

B) 'si aucun onglet choisit

If Err = 13 Then

Err.Clear

Exit Sub

End If

 

C) 'Changement de valeur de BackGroundPlot à zéro

ThisDrawing.SetVariable sysVarName, VarDataTemp

 

D) 'On recherche tous les blocs dans l'onglet choisit

'si on en trouve, on récupère l'emprise rectangulaire du bloc pour

'indiquer la zone à imprimer

 

E) ObjEntite.GetBoundingBox PtBas, PtHaut

ReDim Preserve PtBas(0 To 1)

ReDim Preserve PtHaut(0 To 1)

 

 

 

s'il te plait il ya des instructions que j'ai pas bien saisie :

 

bon pour:

A) c'est quoi ce mot "BackGroundPlot" (tu sais dans la ligne " VarDataOrigine = ThisDrawing.GetVariable(sysVarName") le programme ce bloque, alors j'ai mis cette ligne hors lecture je ne sais pas est-ce que j'ai bien fait ou non !

 

B) If Err = 13 Then (le 13 il sinifi quoi???

 

C) ThisDrawing. SetVariable sysVarName, VarDataTemp ça sinifi quoi aussi !!

 

D)en fait là d'aprés ce que j'ai comprie il selectionne la zone rectangulaire de tout le bloc quelque soit sa forme (A4,A3,A1..) Paysage ou portrait! non !!!

 

parceque j'ai inserer une fiche format A3 il l'a pas imprimer !!*

 

E) j'ai pas comprie l'instruction "GetBoundingBox "

 

 

merci infinement !!

 

[winfield]

Bon apparemment ma réponse va être trop longue, alors je la coupe en deux............bavard ?? Moi ???? ;)

 

Avec quel version autocad travailles-tu ? Si c'est antérieur à 2004 (sûr), ça peut pas marcher; pour 2004, je ne sais pas....peut pas le tester.

 

BackGroundPlot est une variable. Comme je te l'ai dit, je suis loin d'être un expert, je n'ai pas compris à quel niveau ça "joue" exactement mais c'est ce que j'ai trouvé pour résoudre le problème.

L'erreur 13, c'est si par exemple, t'as l'inputBox d'afficher et au lieu de rentrer une valeur, tu fais échappe ou Annuler...comme ça attend une valeur et qu'il n'y en a pas.....ça génère une erreur, qui est l'erreur n°13 (svp ne me demande pas plus de précision....j'ai l'impression de me retrouver à l'école à une interro surprise :o ;) )

Dim sysVarName As String

Dim VarDataOrigine As Variant

Dim VarDataTemp As Variant

sysVaName = caractère==> ici le nom de la variable

VarDataOrigine et VarData Temp = c'est du pareil au même ==> une valeur ( valeur de la variable BackGroundPlot ), on lis la valeur au début, on la change (ou confirme) pour ne pas avoir de surprise,on fait le travaille et on remet la valeur de départ....je trouvais que ça faisait plus pro...on met le bazar, bé faut ranger après ;) .

[winfield]

D)en fait là d'aprés ce que j'ai comprie il selectionne la zone rectangulaire de tout le bloc quelque soit sa forme (A4,A3,A1..) Paysage ou portrait! non !!!

Tout à fait, c'est vrai que j'ai pas pensé mais pas du tout à ça :mad: . Pour compenser tu peux paramétrer l'impression de chaque onglet, virer des trucs du genre

ThisDrawing.Layouts(Q).SetCustomScale 1, 1

'On centre le tracé

ThisDrawing.ActiveLayout.CenterPlot = True

ThisDrawing.ActiveLayout.PlotType = acWindow

puisque ce sera paramétré :casstet: ....mais bon, ça montre que j'ai pas pensé à tout :( .parceque j'ai inserer une fiche format A3 il l'a pas imprimer !!*

[winfield]

Ma réponse doit vraiment être longue, mais longue.....n'ayons pas peur des mots, ça merdoi carrément là au niveau de l'affichage :mad:

parceque j'ai inserer une fiche format A3 il l'a pas imprimer !!*

Tu veux dire une feuille ? Si c'est ça c'est bizarre, à moins qu'effectivement tu sois avec une version antérieure à 2004........

GetBoudingBox ! pour exemple, on va parler d'objet graphique.

Tu sais qu'un triangle peut-être inscrit ou circonscrit à un cercle. Bé là c'est la même chose sauf que c'est un rectangle à la place du cercle. Chaque objet entre dans une boite (rectangulaire). Et sous AutoCAD, quand tu dessines un rectangle avec l'outil rectangle, que fais-tu ? Tu ne donnes que 2 points qui représentent les limites...essaye de transcrire ça sur un tableau (les matrices)....c'est idem

Voilà, j'ai étalé ma science.........Mais si qqn trouve que j'ai dit des bêtises, je lui serai gré de bien vouloir le(s) signaler, je continurais à apprendre. Merci

[winfield]

Voir

 

http:// http://www.cadxp.com/sujetXForum-8722.htm

http://www.cadxp.com/sujetXForum-8723.htm

 

[Invité Patrick]

Veuillez lire la FAQ des forums SVP pour utiliser correctement le BBcode, sinon, là, CADxp ne va plus ressembler à grand chose sous peu... merci.

[doua]

:D salut winfield,

 

Avec quel version autocad travailles-tu ? Si c'est antérieur à 2004 (sûr), ça peut pas marcher; pour 2004, je ne sais pas....peut pas le tester.

 

j'utilise Autocad 2004 ! :casstet:

 

ne me demande pas plus de précision....j'ai l'impression de me retrouver à l'école à une interro surprise

 

non pas du tout ;) c'est juste que je suis débutante en programmation, et il ya une seule personne qui peux me donner un coup de main mais malheureusement il est toujour en déplacement :casstet:

donc s'il yavait pas ce fabuleux forum .....!

 

essaye de transcrire ça sur un tableau (les matrices)....c'est idem

 

j'ai tous saisie sauf ça que veut tu dire par transcrire sur.....!

 

 

.....Pour compenser tu peux paramétrer l'impression de chaque onglet, virer des trucs du genre citation extraite du message original:

ThisDrawing.Layouts(Q).SetCustomScale 1, 1

'On centre le tracé

ThisDrawing.ActiveLayout.CenterPlot = True

ThisDrawing.ActiveLayout.PlotType = acWindow

 

puisque ce sera paramétré ....

 

 

ça veux dire que si j'enlève ça j'aurai la possibilité d'imprimer toute les formats que je veux ?!

 

on fait winfield, je suis vraiment désolée de te cassé la tête avec mes questions , mais bon je veux comprendre ce que je fait et je te remercie de l'effort que tu fourni pour me guider et aussi le temps que tu perd pour m'eclaircire ....! merciiiiiiiiiiiiiiiii ;)

 

dit winfield, on fait on a changer notre 1er programme (pas ton programme !!)

 

et j'aimerai bien que tu le voie car il m'imprime tous les blocs mais vide

je m'explique :

 

le nombre de fiche blocs inserer dans layout1 =égale au nombre de feuille imprimée et ça je n'arrive pas trouver la cause alors stp .....

 

 

voila notre programme :

Option Explicit

Public Sub VerifierBloc()
Dim PlotConfig As AcadPlotConfiguration
Dim strNomDuBloc, nomconfig As String
Dim a, b, x0, y0, x1, y1 As Double
Dim point0(0 To 1), point1(0 To 1) As Double
Dim objInsertion As AcadBlockReference
Dim intType(0 To 1) As Integer
Dim varData(0 To 1) As Variant
Dim objSelection As AcadSelectionSet

a = 198
b = 285
nomconfig = "Plot"
strNomDuBloc = "fiche de lance"
intType(0) = 0: varData(0) = "INSERT"
intType(1) = 2: varData(1) = strNomDuBloc




On Error Resume Next

Set objSelection = ThisDrawing.SelectionSets.Add("Temp")
   If Err Then
       Err.Clear
Set objSelection = ThisDrawing.SelectionSets("Temp")
   End If
   
objSelection.Select acSelectionSetAll, , , intType, varData

For Each objInsertion In objSelection

           If 0 = StrComp(objInsertion.Name, strNomDuBloc, 1) Then
       
                   x0 = objInsertion.InsertionPoint(0)
                   y0 = objInsertion.InsertionPoint(1)
                   point0(0) = x0: point0(1) = y0

                   x1 = x0 + a
                   y1 = y0 + b
                   point1(0) = x1: point1(1) = y1

Set PlotConfig = ThisDrawing.PlotConfigurations(nomconfig)

       ThisDrawing.ActiveLayout.ConfigName = nomconfig
       ThisDrawing.ActiveLayout.SetWindowToPlot point0, point1
       ThisDrawing.ActiveLayout.GetWindowToPlot point0, point1
       ThisDrawing.ActiveLayout.PlotType = acWindow
       ThisDrawing.Plot.PlotToDevice

           End If
           
Next objInsertion

End Sub

 

 

 

merci winfield,:D

amicalement

 

[winfield]

"c'est juste que je suis débutante en programmation"

En tant que débutant je te souhaite la bienvenue chez : les débutants.

 

Que veux-tu dire par "il m'imprime tous les blocs mais vide" .........je suis largué.

 

"intType(0) = 0: varData(0) = "INSERT"

intType(1) = 2: varData(1) = strNomDuBloc"

 

Tu passes par les codes DXF mais...c'est quoi "INSERT" ???? Je connais pô

 

Sans parler de INSERT ,tu passes par les codes DXF pour faire une sélection et tu compares les noms des blocs pour identifier à nouveau si c'est le bon bloc ou pas ?!! ...Tu fais 2 fois le boulot.

(je suis étonné que personne de plus compétent de moi ne se soit manifesté....)

[doua]

:D bonsoir winfield,

 

on fait moi aussi ça m' a étonné qu'il ya qu'une personne qui m'as vraiment aider !! :casstet:

 

 

dit winfield, ton programme il marche trés trés bien sauf qu'il ya un autre département ici "société" qui utilise tous les formats , est ce qu'on peut pas avoir une instruction qui prend la fiche est vérifié si il est = égale au standard des formats (A0-A1-A2-A3-A4)

et si jamais elle trouve qu'il sort du standard il le sort automatiquement en format A4 quelque soit ça forme ??

 

je demande trop hein....! et bien tu m'excusera winfield, si je te casse la tête mais vraiment avec ton aide et tes explications j'apprend des choses ....!! ;)

 

amicalement

doua

[winfield]

"est ce qu'on peut pas avoir une instruction qui prend la fiche est vérifié si il est = égale au standard des formats (A0-A1-A2-A3-A4)

et si jamais elle trouve qu'il sort du standard il le sort automatiquement en format A4 quelque soit ça forme ??"

 

Je pense que c'est faisable, bien que je me demande encore l'interêt de tout ça. Imprimer 1 ou 100 fois le même bloc, puisqu'on peut demander le nombre de copie....à moins bien sûr que ce ne soit des blocs avec...

 

Mais excuse moi de ne pas me pencher sur la question tout de suite, en ce moment, je n'ai malheureusement pas beaucoup de temps libre.

 

Regarde les structures de décision et les fonctions (je pense que je jouerai avec une fonction, surtout si tu as plusieurs "projet" nécessitant ce genre d'information, mais bon...ce n'est que mon avis).

 

Continu de lire du code et de tenter de le comprendre, même si tu as l'impression que c'est réservé à une élite. La notion d'élite est très subjective...

[doua]

salut winfield,

 

Je pense que c'est faisable, bien que je me demande encore l'interêt de tout ça. Imprimer 1 ou 100 fois le même bloc, puisqu'on peut demander le nombre de copie....à moins bien sûr que ce ne soit des blocs avec...

 

on faite ce bloc represente pour moi juste une catouche qui contient des fenêtres que ces dérniers représente des détaille d'une pièce

"que ça soit dans la charpente ou la mécanique ".

 

qu'on doit fournir ces détails au département fabrication donc les formats des cartouches (dite bloc"fiche lancement")

peuvent être variés A1....A(n) suivant le détail de la pièce!

 

 

Mais excuse moi de ne pas me pencher sur la question tout de suite, en ce moment, je n'ai malheureusement pas beaucoup de temps libre.

 

c'est pas grave en fait tu m'as déja baucoup aider merci encors winfield,et je te souhaite une trés bonne continuation dans ton travaille ... ;) !!!

 

amicalement

doua