Détacher une image

[hiridimah 0]

Comment détacher une image dans plusieurs fichiers DWG automatiquement à l'aide d'un script ou LISP???

[Curlygoth 3]

vba possible ?

[lecrabe 65]

Hello

 

A priori le Script est tres simple !

 

Commande: -XREF

Entrez une option [?/Lier/déTacher/Chemin/TYpechemin/Décharger/Recharger/Superposer/Attacher] : T

Entrez le(s) nom(s) de Xref à détacher: ENTCADRE

 

Puis re-enregistrer puis ouvrir le DWG suivant ...

 

LA SANTE, Bye, lecrabe

[hiridimah 0]

je veux détacher une image dans plusieurs fichiers DWG automatiquement sans ouvrir les fichiers un par un

[Aleck_Ultimate 19]

Nous l'avons bien compris. Ici Lecrabe parle autant de la procédure à suivre manuellement que de l'algorythme à suivre pour le coder. Le fait est que, sauf exception mais ce n'est pas le cas ici, si c'est faisable manuellement en ligne de commande c'est bien plus facile à coder. Non pas que ce soit dans mes compétence pour autant.

[Olivier Eckmann 58]

Bonjour,

 

Avec un script du genre

 

_-IMAGE
_D
NOM_DE_L_IMAGE_A_DETACHER

 

 

Puis Superautoscript pour traiter tout un ensemble de fichier DWG

 

Olivier

[hiridimah 0]

merci mais j'ai pas arrive de télécharger Superautoscript vs pouvez m'aider merci.

[hiridimah 0]

merci Olivier Eckmann si bon

[Fraid 7]

Bonjour,

 

Effectivement, en Lisp ce n'est pas facile

si on ne veut pas ouvrir les dessins, ObjetDBX et VLA oblige.

Donc pour détacher les images des dessins contenus dans un dossier

(vl-load-com)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun c:dtimg (/ axdoc lf dir)
   (if (setq dir (getdir) lf (vl-directory-files dir "*.dwg" 1))
       (foreach f lf
           (vlax-for obj (vla-get-modelspace (setq axdoc (getaxdbdoc (strcat dir f))))
               (if (= (vla-get-objectname obj) "AcDbRasterImage")
                   (vla-delete 
                       (vla-item 
                           (vla-item (vla-get-dictionaries axdoc ) "ACAD_IMAGE_DICT") 
                           (vla-get-name obj)
                       )
                   ) 
               )
           )
           (vla-saveas axdoc (strcat dir f))
           (vlax-release-object axdoc)
       )
   )
(princ)
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun getdir( / shell rep)
 (setq shell (vlax-create-object "Shell.Application")
        rep (vlax-invoke shell 'browseforfolder 0 "Sélectionnez le dossier" 512 "")
 )
 (vlax-release-object shell)
 (strcat (vlax-get-property (vlax-get-property rep 'self) 'path) "\\")
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun getaxdbdoc (filename / axdbdoc release)
 (setq axdbdoc
    (vlax-create-object
      (if (< (setq release (atoi (getvar "ACADVER"))) 16)
        "ObjectDBX.AxDbDocument"
        (strcat "ObjectDBX.AxDbDocument." (itoa release))
      )
    )
 )
 (if (vl-catch-all-apply 'vla-open (list axdbdoc filename))
   (not (vlax-release-object axdbdoc))
   axdbdoc
 )
)

 

Étrangement, la méthode vla-detach ne concerne pas les images

et je n'ai pas réussi à utiliser vla-remove pourtant prévue pour effacer les entrées dans un dictionnaire.

 

Cela détache les images dans l'espace objet.

ATTENTION, pas de retour en arrière possible.