Aller au contenu

honte à toi


Big666

Messages recommandés

Ho

 

Avis au dessinateur qui a fait son DOE en plaçant tous les calques sur calque commun.

 

Je ne parle pas d’un petit projet, même belle et bien d’un collège fait en 2015.

 

Écoute bien

 

JE te hais.

 

.

 

 

Nous vivons tous dans le ventre d'un chien géant

Tout le monde le sait mais personne ne dit rien du tout

 

ultra Vomit

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

J'ai DEJA eu des DWGs avec tres peu de calques !

 

Mais avec une routine Lisp j'ai eclate toutes les entites sur N calques differents

avec des noms bases sur le nom du calque d'origine

 

TRES PRATIQUE pour analyser / valider un DWG !!

 

Ensuite on peut "chopper" facilement les objets avec une couleur ou type de ligne ou epaisseur forcee

(par la selection rapide) et encore re-organiser ...

 

Bye, lecrabe

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Ou encore pour t'aider à faire un tri grossier par type d'entité

((lambda ( / AcDoc js typ_obj)
 (setq
AcDoc (vla-get-activedocument (vlax-get-acad-object))
js (ssget "_X")
 )
 (cond
(js
 	(vlax-for obj (vla-get-activeselectionset AcDoc)
   	(if (not (tblsearch "LAYER" (setq typ_obj (vla-get-ObjectName obj))))
     	(vla-add (vla-get-layers AcDoc) typ_obj)
   	)
   	(vla-put-Layer obj typ_obj)
 	)
)
 )
))

On pourrait encore imaginer d'approfondir avec les couleurs et les type de lignes forcés...

Choisissez un travail que vous aimez et vous n'aurez pas à travailler un seul jour de votre vie. - Confucius

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Pour completer Grand Maitre Bruno !

 

Tu trouveras ci-dessous une vieille routine de Olivier ...

 

A tester ... SVP tu nous diras si c OK sur ton AutoCAD "moderne" !?

 

MERCI Olivier, Bye, lecrabe (Puise dans mon stock de 2000 routines)

 

 


;; Par Olivier
;; Tri et Transfert des objets sur un calque specifique
;; en fonction soit de la Couleur, soit du Type de Ligne, soit de l Epaisseur 
;; http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=30358#pid131528

(defun C:TRIOBJ ( / JEU I NBJEU CHOIX ELT ELTLST COULEUR CALQUE EPAISSEUR TYPELIGNE) 

 ;; Couleur = 62
 ;; Type de ligne = 6
 ;; Epaisseur = 370 

 (setq JEU (ssget))
 (initget 1 "Couleur Typedeligne Epaisseur")
 (setq CHOIX (getkword "\nType de traitement par [Couleur/Typedeligne/Epaisseur] "))
 (setq I 0  NBJEU (sslength JEU)) 

 (repeat NBJEU
   (setq ELT (ssname JEU I))
   (setq I (1+ I))
   (setq ELTLST (entget ELT)) 

   ;; SI couleur forcée & Traitement des couleurs
   (if (and (= CHOIX "Couleur") (setq COULEUR (cdr (assoc 62 ELTLST))))
     (progn
     (if (<= COULEUR 9)
(setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_C00" (itoa COULEUR)))
(if (<= COULEUR 99)
	  (setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_C0" (itoa COULEUR)))
  (setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_C"  (itoa COULEUR)))
)
     )
     (if (not (tblsearch "LAYER" CALQUE)) (command "_-LAYER" "_New" CALQUE ""))
     (setq ELTLST (subst (cons 8 CALQUE) (assoc 8 ELTLST) ELTLST))
     (entmod ELTLST)
     )
   ) 

   ;; SI Type de ligne forcée & Traitement des types de ligne
   (if (and (= CHOIX "Typedeligne") (setq TYPELIGNE (cdr (assoc 6 ELTLST))))
     (progn
     (setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_" TYPELIGNE))
     (if (not (tblsearch "LAYER" CALQUE)) (command "_-LAYER" "_New" CALQUE ""))
     (setq ELTLST (subst (cons 8 CALQUE) (assoc 8 ELTLST) ELTLST))
     (entmod ELTLST)
     )
   ) 

   ;; SI épaisseur forcée & Traitement des épaisseurs
   (if (and (= CHOIX "Epaisseur") (setq EPAISSEUR (cdr (assoc 370 ELTLST))))
     (progn
     (if (<= EPAISSEUR 9)
(setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_00" (itoa EPAISSEUR)))
(if (<= EPAISSEUR 99)
	  (setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_0" (itoa EPAISSEUR)))
  (setq CALQUE (strcat (cdr (assoc 8 ELTLST)) "_"  (itoa EPAISSEUR)))
)
     )
     (if (not (tblsearch "LAYER" CALQUE)) (command "_-LAYER" "_New" CALQUE ""))
     (setq ELTLST (subst (cons 8 CALQUE) (assoc 8 ELTLST) ELTLST))
     (entmod ELTLST)
     )
   ) 

 )
)

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

2eme cadeau par Patrick_35

 

La routine qui trie et "eclate" les entites sur N calques ...

 

A tester ... SVP tu nous diras si c OK sur ton AutoCAD "moderne" !?

 

MERCI Patrick, Bye, lecrabe (Puise dans mon stock de 2000 routines)

 

 

;;
;; Tri des entites par calque et transfert dans des sous-calques
;; Si Calque nomme A alors --> A__TEXT, A__2LINE, A__HATCH, A__POLYLINE, etc
;; 
;; Par Patrick_35 le 23/03/2009 pour Patrice 
;; 
;; Nouvelle version 1.1 qui separe XREF & BLOC et fonctionne sur AutoCAD >= 2000
;;

(defun c:TRI (/ doc ent lay lck nom ori pro sel tot txt)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (if (ssget "x")
   (progn
     (vlax-for ent (setq sel (vla-get-activeselectionset doc))
(cond
  ((and (eq (vla-get-objectname ent) "AcDbBlockReference")
	(vlax-property-available-p ent 'path)
    )
    (setq nom "Xref")
  )
  (T
    (setq txt (substr (vla-get-objectname ent) 5)
	  tot 2
    )
    (while (and (> (vl-string-elt txt tot) 90)
		(< tot (1- (strlen txt)))
	   )
      (setq tot (1+ tot))
    )
    (and (eq (1- (strlen txt)) tot)
      (setq tot (1+ tot))
    )
    (setq nom (substr txt 1 tot))
  )
)
(setq ori (vla-item (vla-get-layers doc) (vla-get-layer ent))
      lck (vla-get-lock ori)
)

;;	(or (wcmatch (vla-get-layer ent) (strcat "* - " nom))
;;	    (and (vl-catch-all-error-p (setq lay (vl-catch-all-apply 'vla-item (list ;; (vla-get-layers doc) (setq txt (strcat (vla-get-layer ent) " - " nom))))))

(or (wcmatch (vla-get-layer ent) (strcat "*__" nom))
    (and (vl-catch-all-error-p (setq lay (vl-catch-all-apply 'vla-item (list (vla-get-layers doc) (setq txt (strcat (vla-get-layer ent) "__" nom))))))

	 (setq lay (vla-add (vla-get-layers doc) txt))
	 (foreach pro '('color 'freeze 'layeron 'linetype 'lineweight 'material 'plottable 'viewportdefault)
	   (and (vlax-property-available-p lay (eval pro))
	     (vlax-put lay (eval pro) (vlax-get ori (eval pro)))
	   )
	 )
    )
    (vla-put-lock lay :vlax-false)
    (vla-put-lock ori :vlax-false)
    (vla-put-layer ent txt)
    (vla-put-lock lay lck)
    (vla-put-lock ori lck)
)
     )
     (princ (strcat "\nTravail sur " (itoa (vla-get-count sel)) " objet(s)."))
     (vla-delete sel)
   )
   (princ "\nDessin vide.")
 )
 (vla-endundomark doc)
 (princ)
)


Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

hello

 

deplace les entites en fonction de leurs type d'entite, couleur, epaisseur de ligne, type de ligne

 

apres j'avoue on ne sait plus trop quoi est quoi.

 

Phil

 

 

 

(defun c:mdfc ()
 (vl-load-com)
 (setvar "cmdecho" 0)
 (setvar "dimzin" 0)
 (setvar "osmode" 0)
 (prompt "\nCLIQUER SUR LES OBJETS A DEPLACER DE CALQUE :")
 (setq entites nil)
 (while (null entites) (setq entites (ssget)))
 (setq compt 0)
 (setq com (sslength entites))
 (while (< compt com)
   (progn (setq ent1 (ssname entites compt))
          (setq code1 (cdr (assoc -1 (entget ent1))))
          (setq ena1 (vlax-ename->vla-object code1))
          (setq typeobjet (vla-get-objectname ena1))
          (setq proper1 (vlax-get-property ena1 'truecolor))
          (setq colorr (vlax-get-property proper1 'colorindex))
          (setq ligntype (vla-get-linetype ena1))
          (setq eplign (vla-get-lineweight ena1))
          (setq calquenew (strcat "CALQUE " typeobjet " " (rtos colorr 2 0) " " ligntype " " (rtos eplign 2 0) "ep"))
          (if (or (= colorr 256) (= colorr 0))
            (setq colorr 7)
          )
          (if (= (tblsearch "layer" calquenew) nil)
            (vl-cmdf "-calque" "n" calquenew "co"
                     colorr calquenew "in" calquenew "")
          )
          (vla-put-layer ena1 calquenew)
          (vlax-put-property proper1 'colorindex 256)
          (vlax-put-property ena1 'truecolor proper1)
          (vla-put-lineweight ena1 -1)
          (setq compt (1+ compt))
          (prompt (strcat "\rENTITE DEPLACEE : " (rtos compt 2 0) " SUR : " (rtos com 2 0) " "))
   )
 )
)












(defun c:mdfc_meme_calque ()
 (vl-load-com)
 (setvar "cmdecho" 0)
 (setvar "dimzin" 0)
 (setvar "osmode" 0)
 (prompt "\nCLIQUER SUR LES OBJETS A DEPLACER DE CALQUE :")
 (setq entites nil)
 (while (null entites) (setq entites (ssget)))
 (setq compt 0)
 (setq com (sslength entites))
 (while (< compt com)
   (progn (setq ent1 (ssname entites compt))
          (setq code1 (cdr (assoc -1 (entget ent1))))
          (setq ena1 (vlax-ename->vla-object code1))
          (setq typeobjet (vla-get-objectname ena1))
          (setq calqueorigine (vla-get-layer ena1))
          (setq proper1 (vlax-get-property ena1 'truecolor))
          (setq colorr (vlax-get-property proper1 'colorindex))
          (setq ligntype (vla-get-linetype ena1))
          (setq eplign (vla-get-lineweight ena1))
          (setq calquenew (strcat calqueorigine " " typeobjet " " (rtos colorr 2 0) " " ligntype " " (rtos eplign 2 0) "ep"))
          (if (or (= colorr 256) (= colorr 0))
            (setq colorr 7)
          )
          (if (= (tblsearch "layer" calquenew) nil)
            (vl-cmdf "-calque" "n" calquenew "co" colorr calquenew "in" calquenew "")
          )
          (vla-put-layer ena1 calquenew)
          (vlax-put-property proper1 'colorindex 256)
          (vlax-put-property ena1 'truecolor proper1)
          (vla-put-lineweight ena1 -1)
          (setq compt (1+ compt))
          (prompt (strcat "\rENTITE DEPLACEE : " (rtos compt 2 0) " SUR : " (rtos com 2 0) " "))
   )
 )
)

Autodesk Architecture 2023 sous windows 11 64

24 pouces vertical + 30 pouces horizontal + 27 pouces horizontal

Lien vers le commentaire
Partager sur d’autres sites

  • 1 an après...

Un projeteur qui envoi un plan avec tout dans un seul calque ... hmmm le bonheur ...

 

Quoi que j'ai personnellement parfois reçu un "ordre" de ma hiérarchie demandant d'exploser et de "pourrir" mon fichier DWG avant un envoi ...

Bon j'en ai d'autres qui m'ont aussi parfois demandé des fichiers covadis avec mes fichiers de profils type, mes bibliothèques de bloc dynamique, etc ...

 

Il faut de tout pour faire un monde :P

AutoCAD Map 3D 2023 (26.0.37.2 base T.53.0.0)
Covadis 18.0 + AutoPiste
Windows 11 Famille v.21H2 - 64 bits

Toujours à l'affût des bonnes astuces

Lien vers le commentaire
Partager sur d’autres sites

Quoi que j'ai personnellement parfois reçu un "ordre" de ma hiérarchie demandant d'exploser et de "pourrir" mon fichier DWG avant un envoi ...

 

Il faudra qu'on m'explique, un jour, quelles sont les véritables motivations de ce genre de pratiques mesquines...

Pour ce qui est des blocs dynamiques, ça peut se comprendre qu'on ait pas envie de donner des blocs dynamiques super chiadés où on a passé du temps dessus. Mais de là à pourrir un fichier entier...

J'ai même appris qu'il y en a qui vont jusqu'à pousser le vice en faussant légèrement le SCU pour fausser le plan.

En fait, ce n'est pas le SCU, c'est faire une légère rotation en Z du plan avec un faible degré.

Steven________________________________________

Pour le taf; Windows (et ses emmerdes) sinon pas d'AutoCAD.

Pour le perso Linux Mint et pas de problèmes. Mais pas d'AutoCAD.

En rêve; AutoCAD sous Linux.

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Quand on tombe sur des PROFITEURS VICIEUX !

 

Pourquoi pas TOUT exploser ou du moins le maximum !

 

Mais pas beaucoup plus (A Mon Avis) !?

 

LA SANTE (Stay Safe), Bye, lecrabe "triste"

Automne 2020, la retraite

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

à dire vrai.

 

J'en crois pas mes yeux de tant de ?§§§§§§§§§§§/////

 

 

Mais cela expliquerait l'état de certain plan fait par des prestataires.

 

pour exemple j'ai un fichier d'un bâtiment qui est peut être le plus important de mon département le conseil départemental.un site très compliqué.les plans un pousse au suicide.pour refaire:20 000 € et plus

comme il n'y a pas de sous!au passage c'est les sous de tous le monde.

 

 

 

 

Nous vivons tous dans le ventre d'un chien géant

Tout le monde le sait mais personne ne dit rien du tout

 

ultra Vomit

Lien vers le commentaire
Partager sur d’autres sites

J'ai même appris qu'il y en a qui vont jusqu'à pousser le vice en faussant légèrement le SCU pour fausser le plan.

En fait, ce n'est pas le SCU, c'est faire une légère rotation en Z du plan avec un faible degré.

 

J'ai un ami qui a failli être licencié il y a quelques années à cause de ce genre de manipulation.

 

Pour faire simple, le fichier avait une légère rotation en Z fait avec un point de pivot sur une station topo.

Mon pote a refait un levé ... mais par manque de rigueur il a gardé le levé initial du client comme référence après avoir vu que tous les éléments levés était les mêmes en X/Y que ceux de son levé ... J'ignore encore, et lui aussi, pourquoi il ne s'est pas donné la peine de contrôle les Z ... surtout que ça prenait 5 secondes ...

 

Forcement derrière le projet du client ne collait pas du tout, les Deblais / Remblais était minimisé par rapport au Réel ...

 

Ils ne l'ont pas viré car il a été prouvé que le fichier de base du client était faux ... Mais un petit avertissement pour son manque d'autocontrôle.

 

(1ère règle du Géomètre : toujours se contrôler !)

AutoCAD Map 3D 2023 (26.0.37.2 base T.53.0.0)
Covadis 18.0 + AutoPiste
Windows 11 Famille v.21H2 - 64 bits

Toujours à l'affût des bonnes astuces

Lien vers le commentaire
Partager sur d’autres sites

(1ère règle du Géomètre : toujours se contrôler !)

Non, ça c'est la première règle de tout professionnel, quelque-soit son métier. Ou du moins ça le devrait.

Je suis dysorthographique alors lâchez-moi les basques avec ça, je fait déjà de mon mieux.
Membre d'Extinction Rebellion, car pour sauver le monde il n'est jamais trop tard, amour et rage !
Pour écrire un vraie point médian (e·x·e·m·p·l·e) [Alt + 0183] ou ajout d'un raccourci clavier personnalisé (ex. [AltGr + ;])

Utilisateur d'AutoCAD 2021 sous Windows 10

Lien vers le commentaire
Partager sur d’autres sites

Bonjour,

 

Oui, je confirme il faut se contrôler !!! Ma règle d'or que j'applique tous les jours, ce sont 3 lettres : P O C ...

 

. P - PREVOIR

. O - ORGANISER

 

. C - CONTROLER

 

 

Pour tous les PLANS même mes anciens plans j'applique une PROCEDURE complète de vérification, de nettoyage, etc. La vérification des entités en Z en fait partie...

 

En Formation, comme je le dis à chaque fois, à mes gentils stagiaires : TOUS LES PLANS QUE VOUS RECEVEZ SONT SUSPECTS !!!!!!!!!!!!!! Il faut les vérifier...

 

Sinon, pour remercier ce cochon de dessineux, il y a la bonne vieille méthode d’antan : le GOUDRON et LES PLUMES...

5341-3.jpg

 

 

Christian

Formateur, Consultant Expert AutoCAD, REVIT MEP, INVENTOR, télécharger , des Outils AutoCAD...

cad123 @ wanadoo.fr (enlever les espaces de part et d'autre de @)

Lien vers le commentaire
Partager sur d’autres sites

Bonjour.merci pour vos réponse

 

Du coup une idée une lumière mes apparue. Hallelujah.

-------------------------------------------------------------------------------------------------------

Nous pourrions lister toutes les petites fumisteries que peut faire un dessinateur.

En faire une charte un code d'honneur. Pas un truc a la franc maçonne ou illuminati ou je ne sais quoi...------

Puis les remèdes à ces actes de mécréant. (pardon)------

Et c'est ainsi que Cadxp vaccina les plans de salopard sans conscience professionnelle.------

Bon si ça vous semble faisable, ça ferait l'objet d'une nouvelle rubrique---------

Code d'honneur , les contres fumisterie ou (?)

 

 

Nous vivons tous dans le ventre d'un chien géant

Tout le monde le sait mais personne ne dit rien du tout

 

ultra Vomit

Lien vers le commentaire
Partager sur d’autres sites

Et c'est ainsi que Cadxp vaccina les plans de salopard sans conscience professionnelle.------

 

Attention ... ils sont forcement parmi nous ! laugh.gif

AutoCAD Map 3D 2023 (26.0.37.2 base T.53.0.0)
Covadis 18.0 + AutoPiste
Windows 11 Famille v.21H2 - 64 bits

Toujours à l'affût des bonnes astuces

Lien vers le commentaire
Partager sur d’autres sites

Nous pourrions lister toutes les petites fumisteries que peut faire un dessinateur.
Quoi que j'ai personnellement parfois reçu un "ordre" de ma hiérarchie demandant d'exploser et de "pourrir" mon fichier DWG avant un envoi ...

Attention, car certains aussi obéissent à leur supérieur qui prodiguent des ordres sans trop savoir eux non plus ce qu'ils disent.

Du moment que le pdf leur convient et que cela aille vite.

Lien vers le commentaire
Partager sur d’autres sites

bonjour,

 

La plupart des plans ne sont pas réalises par des dessinateurs , voir même c’est le stagiaire qui si colle

Je ne te parle pas de sabotage mais de mauvaise connaissance du logiciel . (ex ; combien connaisse la cde « eTransmit », le pourvoir caméléon de la couche 0 lors de la création du bloc ,etc…. )

 

Merci aussi aux exports des divers logiciels (juste à voir l’aspect du pdf par rapport au même dwg )

 

Sans parler des truc spéciaux (ex : objet « trace » ou « aec »)

 

Les Chartes graphiques = SUPER truc que si il y a un gendarme !?

 

Pour moi , environ 25 ans d’Autocad avec utilisation des blocs , xrefs ,1 couleur = 1 calque, rien de forcé.

 

Le tout balayer par 1.5 ans de Revit (ex: export Revit vers dwg resultat un calque « p-pipe » avec X couleurs X lignes X épaisseurs)

Lien vers le commentaire
Partager sur d’autres sites

Bonjour à tous,

je souhaiterai tempérer un peu le haro sur les plans foireux.Moi le premier, quand je reçoit des plans de ce type, je gueule, évidemment.Et oui, les maîtres d'ouvrages devraient avoir des fichiers nickels, ils ont payé pour ça !

 

Maintenant, nous faisons tous des prestations intellectuelles, rémunérée plus ou moins bien, et dont un des seuls résultats concrets est notre charte graphique.Montée souvent pendant plusieurs années, agrémentée régulièrement par des blocs (et notamment dynamiques carrément chiadés pour certains), types de lignes, types de hachures, routines et j'en passe.C'est un travail de quasiment tous les jours.

Et bien je suis désolé, mais lorsque l'on doit diffuser des plans à des "confrères" dont on sait que le boulot qui est produit laisse vraiment à désirer, et bien oui, il m'est arrivé de saborder un DWG pour ne pas laisser de trace du passage dans ma boite.Alors j'en suis pas au point où tout passe sous le calque '0' en forcé, mais très honnêtement, la commande 'BURST' est un inévitable lorsque je suis dans ce cas, accompagné de tous les types de ligne en Continuous, toutes les hachures en Solid, et renommage des calques.

 

Nous savons tous qu'il n'est pas possible, ou très difficilement, de protéger un DWG. Tous nos efforts sont donc à découvert.On a déjà du mal à faire confiance en certains maîtres d'ouvrages peu scrupuleux qui diffusent à tout va les fichiers qu'on leur confie...

Donc voilà, ceci étant dit, je ne plaide pas la cause de ceux qui travaillent n'importe comment sans complexe, je dis juste que derrière un plan foireux peut se cacher un bon technicien qui a envie de protéger un peu son bébé.En espérant ne pas m'attirer les foudres des cadxpiens qui me sont chers !

Rémy

 

 

Lien vers le commentaire
Partager sur d’autres sites

Bonjour,

 

Incroyable, il y a plus de bonne gens que de fumiste.

 

J'ai pratiquement fini mon calvaire, mais j'ai un autre DOE fantastique à mettre à la charte.

 

il faut que j'en face une méthode des plus logique. Et satisfaire le démon du toujours plus vite.

Merci pour toute vos réponse.

 

 

Nous vivons tous dans le ventre d'un chien géant

Tout le monde le sait mais personne ne dit rien du tout

 

ultra Vomit

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité