Liaison entre VLISP et HTTP ou FTP

[l56]

Bonjour,

 

Est-il possible, à partir d'un lisp, de savoir si un fichier est présent ou non dans un répertoire se trouvant dans l'arborescence d'un site internet.

 

un truc du genre :

 

(commandelisp "http://www....../...../fichier.txt")

si présent = 1

sinon = 0

 

Merci

[Patrick_35]

Salut

 

Un exemple pour télécharger un fichier sur internet, donc pour tester si le fichier existe.

 

(defun download (url file / adob fso http ok taille tbl)
 (setq http (vlax-create-object "MSXML2.XMLHTTP")
adob (vlax-create-object "ADODB.Stream")
fso  (vlax-create-object "Scripting.FileSystemObject")
 )
 (vlax-invoke-method http 'open "get" url :vlax-false)
 (if (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list http 'send)))
   (princ (strcat "\nLe lien " url " n'est pas valide."))
   (if (eq (vlax-get http 'status) 200)
     (if (vl-catch-all-error-p (setq taille (vl-catch-all-apply 'vlax-invoke (list http 'getResponseHeader "Content-Length"))))
(princ "\nErreur de lecture sur la taille du fichier.")
(if (< (atoi taille) (vlax-get (vlax-invoke fso 'getdrive (substr (vlax-invoke fso 'getabsolutepathname file) 1 1)) 'freespace))
  (progn
    (princ "\nTéléchargement en cours.")
    (princ)
    (if (vl-catch-all-error-p (setq tbl (vl-catch-all-apply 'vlax-get-property (list http "ResponseBody"))))
      (princ "\nImpossible de télécharger le fichier.")
      (if (not (vl-catch-all-error-p (vl-catch-all-apply '(lambda()
							   (vlax-put adob "Type" 1)
							   (vlax-invoke adob "Open")
							   (vlax-invoke-method adob "Write" tbl)
							   (vlax-invoke adob "SaveToFile" file 2)
							 )
				     )
	       )
	  )
	(setq ok T)
      )
    )
  )
  (princ "\nPlus de place sur le périphérique de destination.")
)
     )
     (princ (strcat "\nLe lien " url " n'est pas disponible."))
   )
 )
 (mapcar 'vlax-release-object (list http adob fso))
 (terpri)
 ok
)

 

Ou tu peux aussi essayer avec vla-getremotefile

 

@+

[l56]

Merci Patrick_35.

Comme d'habitude, ton aide est précieuse.

[capde06]

quand on voit ca, on comprend pourquoi il y a une zone securisée sur la 2014

en vlisp on a accès au shell a internet

je n'ose pas penser a ce qu il est possible de faire en .net

 

les hackers sur autocad , c'est pour bientôt

si ce n'est pas déjà fait

[Patrick_35]

Salut

 

Ce que tu vois n'est qu'une traduction en lisp de ce qui peut se faire dans d'autres langages.

Et ce n'est que la surface. C'est avec ce type liaisons que l'on trouve des failles de sécurité.

Il faut dire que protéger des données en entreprise (même chez les éditeurs de logiciels) n'est pas une priorité et c'est bien dommage.

Si quelqu'un se donne la peine de gratter un peu, il trouvera assez facilement.

 

@+

[capde06]

CA FAIT PEUR

PLU JAMAIS JE PRENDRAIS UN FICHIER COMPILé

DLL OU AUTRE

 

dans tous les cas, Patrick

bravo pour cette traduction

[Goldorak44]

CA FAIT PEUR

PLU JAMAIS JE PRENDRAIS UN FICHIER COMPILé

DLL OU AUTRE

 

:blink: Un peu de parano ? !!

[l56]

Bonjour,

 

La vérification du lien par

(vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list http 'send)))

provoque la création du fichier dans un dossier du type ...\Temporary Internet Files\Content.IE5\O2VBX9YT.

C'est un probleme car quand on redemande cette vérification et que le fichier n'est plus sur le FTP, il considere qu'il y est encore.

 

J'ai l'impression qu'il verifie d'abord dans les dossiers Windows et s'il le trouve, il ne verifie pas sur le FTP.

 

Il faudrai, avant de faire cette verification, trouver et supprimer le fichier du disque dur.

 

Comment peut-on faire ?