Lisp dessin de talus

lutofo · le 7 juillet 2010

Bonjour,

J'ai trouvé ici : http://pagesperso-orange.fr/didier.duhem/routines.htm#Talus

un lisp pour créer des talus sous autocad. Le petit soucie est qu'à chaque ouverture d'un nouveau dessin une fenetre texte " tapez talus pour commencer "s'affiche.

Quelqu'un aurait il la solution pour ne plus avoir cette fenetre (mes connaissances en lisp se limite a l'utilisation).

merci.

Aviglémy · le 7 juillet 2010

Bonjour,

tu peu mettre un ";" avant la ligne : tmp (alert "Tapez TALUS pour commencer")

donc ca va donner :

;tmp (alert "Tapez TALUS pour commencer")

cette ligne est à la fin du fichier Talus.lsp

C'est vrai qu'il fonctionne bien ce petit lisp ! :)

Dinosor · le 7 juillet 2010

Hello,

Le téléchargement du lisp sur le site ne semble pas fonctionner, le fichier semble endommagé (d'après mon ordi), pouvez vous le coller à ce post SVP ? ;)

Merci

lutofo · le 7 juillet 2010

Voila le lisp:

;;------------------------------------------------------------------------------
;;Tracé d'un talus après saisie du type
;;Didier DUHEM 23/03/95  modifiée 21/11/98
;;E.Mail D.Duhem@wanadoo.fr
;; http://perso.wanadoo.fr/didier.duhem/outils.htm
;;-------------------------------------------------------------------------------


;;---Début---------------------------------------------------PutVar--------------
;; << change une variable système et mémorise l'ancienne valeur                >>
;; <<                                                                          >>
;;
;;  créée le :  mercredi 25 novembre 1998  à 23:52
;;
;; Admet : 
;; =======
;;   vari       : Chaine   = variable système
;;   valeur     : Entier   = valeur à placer
;;
;; Retourne : Entier = ancienne valeur
;; ==========
;-------------------------------------------------------------------------------
(Defun PutVar ( vari valeur / tmp)
  (setq tmp (getvar vari))
  (setvar vari valeur)
  tmp 
)
;;---fin-----------------------------------------------------PutVar--------------


;;---Début---------------------------------------------------tal_puis2-----------
;; <>
;; << (tal_puis2 48) donne 4 : 2*2*2*2*3                                        >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:41
;;
;; Admet : 
;; =======
;;   n          : Entier   = 
;;
;; Retourne : Entier = nombre de puissances de 2
;; ==========
;-------------------------------------------------------------------------------
(Defun tal_puis2 ( n / i)
 (setq i 0)
 (if (/= n 0)
   (while (zerop (rem n 2))
     (setq n (lsh n -1) i (1+ i))
   )
 ) 
 i 
)
;;---fin-----------------------------------------------------tal_puis2-----------



;;---Début---------------------------------------------------tal_serie-----------
;; << ;;calcul d'une série kn (1 + k + k² +.....+k (n-1))                      >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:43
;;
;; Admet : 
;; =======
;;   k          : Entier   = paramètre 
;;   n          : Entier   = puissance
;;
;; Retourne : Entier = 
;; ==========
;-------------------------------------------------------------------------------
(Defun tal_serie ( k n /  s i)
 (setq s 0 i 0)
 (if (/= n 0)
   (while (> n i)
     (setq s (+ s (expt k i))
           i (1+ i)
     )
   )
 )
 s
)
;;---fin-----------------------------------------------------tal_serie-----------



;;---Début---------------------------------------------------tal_affiche_image---
;; << ;;affiche le slide relatif à une image avec éventuellement un bord       >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:45
;;
;; Admet : 
;; =======
;;   num        : chaine   = "1" ou "2" ou "3" :numéro du slide
;;   bord       : Booléen  = T si slide à encadrer
;;
;; Retourne : Entier = 
;; ==========
;-------------------------------------------------------------------------------
(Defun tal_affiche_image ( num bord /  X Y imag nf)
  (setq nf (findfile (strcat "STTALUS" num ".sld")))
  (setq imag (strcat "ima"  num))
  (setq X (dimx_tile imag) Y (dimy_tile imag))
  (start_image imag)
  (if bord
    (progn
     (fill_image 0 0 X Y 1)
     (fill_image 3 3 (- X 6) (- Y 6) 0)
     (if nf (slide_image 3 3 (- X 6) (- Y 6) nf)) 
    )
    (progn
       (fill_image 0 0 X Y 0)
       (if nf (slide_image 3 3 (- X 6) (- Y 6) nf)) 
    )
  )
  (end_image)
)
;;---fin-----------------------------------------------------tal_affiche_image---



;;---Début---------------------------------------------------Tal_change_Image----
;; << modifie le contour de l'image sélectionnée                               >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:49
;;
;; Admet : 
;; =======
;;   cle        : Chaine   = chaine d'entrée
;;
;; Retourne : Entier = 
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_change_Image ( cle /  ncour)
    (setq ncour (substr cle 4))
    (Tal_Affiche_Image (itoa $typTal) nil)
    (Tal_Affiche_Image ncour T)
    (setq $TypTal (atoi ncour))
)
;;---fin-----------------------------------------------------Tal_change_Image----



;;---Début---------------------------------------------------Tal_Dial_Talus------
;; << Gestion de la case de dialogue                                           >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:55
;;
;; Admet : 
;; =======
;;
;; Retourne : Liste = (nb-d'esp  espacement  petit_trait grand-trait) ou 1
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_Dial_Talus ( / dclid linfo)
  (if (not (findfile $T_mess5))
    (alert $T_mess1)
  )  
  (setq dclid (load_dialog (findfile $T_mess5)))
  (if (new_dialog "dialtalus" dclid)
     (progn
       (foreach clef (list "ima1" "ima2" "ima3")
            (action_tile clef "(Tal_Change_Image $key)")
            (Tal_affiche_image (substr clef 4) (= (atoi (substr clef 4)) $typtal)) 
       )
       (mapcar '(lambda (clef valeur)
                    (set_tile clef (rtos valeur))  
                )  
                (list "pl" "gl" "esp")
                (list $pltal $gltal $esptal)
   
       )
       (mode_tile "effac" (if (= 0 $encourstal) 1 0))
        
       (set_tile "nb" (itoa $nesptal))	
       (action_tile "accept" "(setq linfo (Tal_lit_dial))(done_dialog)")
       (action_tile "effac" "(setq linfo 1)(done_dialog)")
       (start_dialog)
     )
  )
  (unload_dialog dclid)
  linfo
)
;;---fin-----------------------------------------------------Tal_Dial_Talus------



;;---Début---------------------------------------------------Tal_Lit_Dial--------
;; << lit la case de dialogue                                                  >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 16:59
;;
;; Admet : 
;; =======
;;
;; Retourne : Liste = (nb-d'esp  espacement  petit_trait grand-trait)
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_Lit_Dial ( / )
   (list (atoi (get_tile "nb")) 
         (atof (get_tile "esp")) 
         (atof (get_tile "pl")) 
         (atof (get_tile "gl"))
   ) 
)
;;---fin-----------------------------------------------------Tal_Lit_Dial--------



;;---Début---------------------------------------------------T_Ext---------------
;; << extrait une information DXF de l'entité                                  >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:00
;;
;; Admet : 
;; =======
;;   clef       : Entier   = clef DXF
;;   ent        : Liste ou nom d'entité   = liste obtenue par Entget 
;;
;; Retourne : varie = valeur associée à la clef DXF
;; ==========
;-------------------------------------------------------------------------------
(Defun T_Ext ( clef ent / )
  (if (not (listp ent)) (setq ent (entget ent)))
  (cdr (assoc clef ent))
)
;;---fin---------------------------------------------------T_Ext---------------



;;---Début---------------------------------------------------Tal_OK--------------
;; << définit les points de base des hachures et le coté  et lance le tracé    >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:03
;;
;; Admet : 
;; =======
;;
;; Retourne : Sans intérêt = 
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_OK ( / e selpt lpt ptor pttenp ang selpt pttemp2 d ptx ptx1)
   (setq e (car (entsel $T_mess2)))
   (if (and e (member (t_ext 0 e) (list "POLYLINE" "LINE" "ARC" "CIRCLE" "LWPOLYLINE" "SPLINE"))) 
     (progn 
       (command "_undo" "_g")
       (command "_measure" e $esptal)
       (setq selpt (ssget "_P") n 0)
       (repeat (if selpt (sslength selpt) 0)
           (setq lpt (cons (trans (t_ext 10 (ssname selpt n)) 0 1) lpt) 
                 n (1+ n)
           )
       )
       (command "_undo" "_e")(command "_undo" 1)
       (setq ptx (nth (/ (length lpt) 2) lpt)
             ptx1 (nth (1+ (/ (length lpt) 2)) lpt)
       )
       (initget 1)
       (setq ptor (getpoint ptx $T_mess3)
             ang (angle ptx ptx1) 
             pttemp (inters ptx ptx1 
                            ptor (polar ptor (+ ang (/ pi 2)) 100)
                            nil
                    )
             d (distance ptor pttemp)
             pttemp2 (polar pttemp (+ ang (/ pi 2)) d)
             ang (if (equal ptor pttemp2 0.001) (/ pi 2) (/ pi -2))
       )
       (Tal_trace_talus lpt ang)
     )
   )
   
)
;;---fin-----------------------------------------------------Tal_OK--------------


;;---Début---------------------------------------------------Tal_Trace_Talus-----
;; << sélectionne les pied de talus et lance la routine de tracé               >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:06
;;
;; Admet : 
;; =======
;;   lpt        : Liste    = de points
;;   ang        : Réel     = direction des poils de talus
;;
;; Retourne : Entier = le nombre de talus tracé : 1 ou 0
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_Trace_Talus ( lpt ang /  selpied x)
  (prompt (strcat $T_mess4 (if (= 1 $typtal) $T_mess6 " ")))
  (setq selpied (ssget))
  (cond
    ((= 1 $typtal) (talus1 lpt ang selpied))
    ((and selpied (= 2 $typtal)) (talus2 lpt ang selpied))
    ((and selpied (= 3 $typtal)) (talus3 lpt ang selpied))
    ((not selpied) (no_talus))
  ) 
)
;;---fin-----------------------------------------------------Tal_Trace_Talus-----



;;---Début---------------------------------------------------Talus1--------------
;; << calcul et lancement du tracé d'un talus de type 1                        >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:09
;;
;; Admet : 
;; =======
;;   lpt        : Liste    = de points
;;   ang        : Réel     = direction
;;   selpied    :          = jeu de sélection pied de talus
;;
;; Retourne : Entier = nombre de talus tracé : 1
;; ==========
;-------------------------------------------------------------------------------
(Defun Talus1 ( lpt ang selpied /  n  pt pt1 pt2 ang1 long snap)
  (command "_undo" "_g")
  (setq n 0 sel nil snap (PutVar "osmode" 0)) 
  (repeat (- (length lpt) 1)
    (setq pt (nth n lpt) pt1 (nth (1+ n) lpt) ang1 (+ ang (angle pt pt1)))
    (setq long (if (zerop (rem n $nesptal)) $gltal $pltal))
    (command "_line" pt (setq pt2 (polar pt ang1 long)) "")
    (setq sel (cons (list (entlast) pt2) sel))
    (setq n (1+ n))

  )
  (setq long (if (zerop (rem n $nesptal)) $gltal $pltal))
  (command "_line" (last lpt) (setq pt2 (polar (last lpt) ang1 long)) "")
  (setq sel (cons (list (entlast) pt2) sel))
  (if selpied 
   (progn
    (command "_trim" selpied "")
    (foreach info sel (command info))
    (command "")
   )
  )
  (PutVar "osmode" snap) 
   (command "_undo" "_e")
 1
)
;;---fin-----------------------------------------------------Talus1--------------



;;---Début---------------------------------------------------Talus2--------------
;; << calcul et lancement du tracé d'un talus de type 2                        >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:09
;;
;; Admet : 
;; =======
;;   lpt        : Liste    = de points
;;   ang        : Réel     = direction
;;   selpied    :          = jeu de sélection pied de talus
;;
;; Retourne : Entier = nombre de talus tracé : 1
;; ==========
;-------------------------------------------------------------------------------
(Defun Talus2 ( lpt ang selpied / n sel sel1 pt pt1 pt2 ang snap)
  (command "_undo" "_g")
  (setq n 0 sel nil sel1 nil snap (putvar "osmode" 0))
  (repeat (- (length lpt) 1)
    (setq pt (nth n lpt) pt1 (nth (1+ n) lpt) ang1 (+ ang (angle pt pt1)))
    (command "_line" pt (setq pt2 (polar pt ang1 $pltal)) "")
    (setq sel (cons (list (entlast) pt2) sel))
    (if (zerop (rem n $nesptal)) (setq sel1 (cons (car sel) sel1)))
    (setq n (1+ n))

  )
  (command "_line" (last lpt) (setq pt2 (polar (last lpt) ang1 $pltal)) "")
  (setq sel (cons (list (entlast) pt2) sel)) 
  (command "_extend" selpied "")
  (foreach info sel1 (command info))
  (command "")

  (command "_trim" selpied "")
  (foreach info sel (command info))
  (command "")
  (putvar "osmode" snap)

  (command "_undo" "_e")
  1
)
;;---fin-----------------------------------------------------Talus2--------------



;;---Début---------------------------------------------------Talus3--------------
;; << calcul et lancement du tracé d'un talus de type 3                        >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:09
;;
;; Admet : 
;; =======
;;   lpt        : Liste    = de points
;;   ang        : Réel     = direction
;;   selpied    :          = jeu de sélection pied de talus
;;
;; Retourne : Entier = nombre de talus tracé : 1
;; ==========
;-------------------------------------------------------------------------------
(Defun Talus3 ( lpt ang selpied / n sel sel1 pt pt1 pt2 ang snap)
  (command "_undo" "_g")
  (setq n 0 sel nil sel1 nil snap (putvar "osmode" 0))
  (repeat (- (length lpt) 1)
    (setq pt (nth n lpt) pt1 (nth (1+ n) lpt) ang1 (+ ang (angle pt pt1)))
    (if (zerop (rem n 2))
     (progn 
      (command "_line" pt (setq pt2 (polar pt ang1 0.001)) "")
      (setq sel (cons (list (entlast) pt2 n) sel))
     )
     (progn 
      (command "_line" pt (setq pt2 (polar pt ang1 $pltal)) "")
      (setq sel1 (cons (list (entlast) pt2) sel1))
     )
    ) 
    (setq n (1+ n))

  )
    (if (zerop (rem n 2))
     (progn 
      (command "_line" (last lpt) (setq pt2 (polar (last lpt) ang1 0.001)) "")
      (setq sel (cons (list (entlast) pt2 n) sel))
     )
     (progn 
      (command "_line" (last lpt) (setq pt2 (polar (last lpt) ang1 $pltal)) "")
      (setq sel1 (cons (list (entlast) pt2) sel1))
     )
    ) 
  (command "_trim" selpied "")
  (foreach info sel1 (command info))
  (command "")
  (Tal_exectalus3 sel selpied)
  (putvar "osmode" snap)
  (command "_undo" "_e")
  1
)
;;---fin-----------------------------------------------------Talus3--------------



;;---Début---------------------------------------------------Tal_exectalus3------
;; << trace les traits étendus des talus de type 3                             >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:14
;;
;; Admet : 
;; =======
;;   sel        : Jeu de sélection = traits à prolonger éventuellement
;;   selpied    : Jeu de sélection = pieds de talus
;;
;; Retourne : Sans intérêt = 
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_exectalus3 ( sel selpied / ent d1 d2 long ang p1 p2)
  (command "_extend" selpied "")
  (foreach info sel (command (list (car info) (cadr info))))
  (command "")
  (setq coef (/ $gltal $pltal)) 
  (foreach info sel
     (setq ent (entget (car info))
           puiss (tal_puis2 (caddr info))
           d1 (+ $pltal (* $gltal (tal_serie coef (- puiss 1))))
           d2 (+ $pltal (* $gltal (tal_serie coef puiss)))
           long (distance (t_ext 10 ent) (t_ext 11 ent))
           ang (angle (t_ext 10 ent) (t_ext 11 ent))
     )
     (if (> d1 long)
         (entdel (car info))
         (progn  
           (setq p1 (polar (t_ext 10 ent) ang d1))
           (if (> d2 long)
               (setq  p2 (t_ext 11 ent))
               (setq p2 (polar (t_ext 10 ent) ang d2))
           )
           (setq ent (subst (cons 10 p1) (assoc 10 ent) ent)
                 ent (subst (cons 11 p2) (assoc 11 ent) ent)  
           )
           (entmod ent)
         )
     ) 
  )
)
;;---fin-----------------------------------------------------Tal_exectalus3------




;;---Début---------------------------------------------------tal_no_talus--------
;; << message si pas de talus à tracer                                         >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:16
;;
;; Admet : 
;; =======
;;
;; Retourne : Entier = nombre de talus tracé donc 0
;; ==========
;-------------------------------------------------------------------------------
(Defun tal_no_talus ( / )
  (alert "pour ce type de talus, vous devez désigner \nau moins un pied de talus")
  0 
)
;;---fin-----------------------------------------------------tal_no_talus--------





;;---Début---------------------------------------------------chg_var-------------
;; << modifie une variable système et récupère sa valeur initiale              >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:18
;;
;; Admet : 
;; =======
;;   nom        : Chaine   = de la variable
;;   valeur     :          = à attacher à la variable
;;
;; Retourne : Entier = ancienne valeur
;; ==========
;-------------------------------------------------------------------------------
(Defun chg_var ( nom valeur /  xx)
  (setq xx (getvar nom))
  (setvar nom valeur)
  xx
)
;;---fin-----------------------------------------------------chg_var-------------


;;---Début---------------------------------------------------Tal_Cree_DCL--------
;; << écrit le DCL                                                             >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:20
;;
;; Admet : 
;; =======
;;   option     : Booléen  = T : écrit NIL met à 0
;;
;; Retourne : Sans intérêt = 
;; ==========
;-------------------------------------------------------------------------------
(Defun Tal_Cree_DCL ( option / fich)
 (setq fich (open "imtal.dcl" "w"))
 (if option
  (progn
   (write-line (strcat "imagetal:image_button {width = 20" (chr 59) 
                       "fixed_width = true"(chr 59) "aspect_ratio = 1"(chr 59) "}"
               ) fich
   )
   (write-line "lesimagestalus : column {" fich)
   (write-line (strcat "  : text {value = " (chr 34) "Offert par Didier-AD" (chr 34)(chr 59)"}") fich)
   (write-line "  :row {" fich)
   (write-line (strcat "    : imagetal {key=" (chr 34) "ima1" (chr 34) (chr 59) "}") fich) 
   (write-line (strcat "    : imagetal {key=" (chr 34) "ima2" (chr 34) (chr 59) "}") fich) 
   (write-line (strcat "    : imagetal {key=" (chr 34) "ima3" (chr 34) (chr 59) "}") fich) 
   (write-line "  }" fich)
   (write-line "}" fich)
  )
 )
 (setq fich (close fich))
)    
;;---fin-----------------------------------------------------Tal_Cree_DCL--------


;;---Début---------------------------------------------------Talerreur-----------
;; << gestion d'erreur                                                         >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:22
;;
;; Admet : 
;; =======
;;   ch         : Chaine   = message d'erreur
;;
;; Retourne : Sans intérêt = 
;; ==========
;-------------------------------------------------------------------------------
(Defun Talerreur ( ch / )
 (Tal_cree_dcl nil)
 (setq *error* $olderr)
)
;;---fin-----------------------------------------------------Talerreur-----------


;;---Début---------------------------------------------------C:TALUS-------------
;; << commande principale                                                      >>
;; <<                                                                          >>
;;
;;  créée le :  samedi 21 novembre 1998  à 17:23
;;
;; Admet : 
;; =======
;;
;; Retourne : Sans intérêt = 
;; ==========
;-------------------------------------------------------------------------------
(Defun tal_TALUS ( /  blp cmd linfo )
    (setq $encourstal 0)
    (setq $olderr *error* *error* talerreur)
    (setq cmd (chg_var "cmdecho" 0))
    (setq blp (chg_var "blipmode" 0))
    (setq linfo t)
    (while linfo
      (if (not $typtal) (setq $typtal 1))
      (if (not $esptal) (setq $esptal 2.0))
      (if (not $pltal) (setq $pltal 8.0))
      (if (not $gltal) (setq $gltal 15.0))
      (if (not $nesptal) (setq $nesptal 4))
      (setq oldtyp $typtal)
;       (Tal_cree_dcl T)
      (setq linfo (tal_dial_talus))
;      (tal_cree_dcl nil)
      (if (and linfo (listp linfo))
        (progn
          (setq  $nesptal (car linfo)
                $esptal (cadr linfo)
                $pltal (caddr linfo)
                $gltal (cadddr linfo) 
          )          
          (setq $encourstal (+ (tal_OK) $encourstal))
        )
        (setq $typtal oldtyp)
      )
      (if (= 1 linfo) 
       (progn 
         (command "_undo" 1)
         (setq $encourstal (- $encourstal 1))
       )
      )
  )  
  (setq *error* $olderr $olderr nil)
  (setvar "cmdecho" cmd)
  (setvar "blipmode" blp)
)
;;---fin-----------------------------------------------------C:TALUS-------------


;;---Début---------------------------------------------------initialisation------
(if (wcmatch (strcase (getvar "LOCALE")) "FR*")
   (progn
     (defun c:talus () (tal_talus))
     (setq $T_mess1 "FDTALUS.DCL non trouvé"
    $T_mess2 "\nPointez la crête du talus "
    $T_mess3 "\nCoté des hachures "
    $T_mess4 "\nSélectionnez le ou les pied(s) de talus "
    $T_mess5  "FDTALUS.DCL"
    $T_mess6  " (facultatif) "
    tmp (alert "Tapez TALUS pour commencer")
     )
   )
   (progn
     (defun c:bank () (tal_talus))

     (setq $T_mess1 "EDTALUS.DCL not found"
    $T_mess2 "\nPick the top of the bank "
    $T_mess3 "\nSide for the hatch"
    $T_mess4 "\nSelect the bottom of the bank "
    $T_mess5 "EDTALUS.DCL"
    $T_mess6 " (optional) "
    c:bank c:talus
    tmp (alert "Type BANK to begin")
     )
   )  
)
;;---Début---------------------------------------------------initialisation------

J'ai essayer de rajouter le";" comme tu me la dis et c'est nickel.Merci beaucoup[Edité le 7/7/2010 par lutofo]

Greg27 · le 29 juin 2022

Bonjour à tous,

Je viens d'essayer le lisp cité si dessus, même avec la modification ;tmp (alert "Tapez TALUS pour commencer") j'ai un message d'erreur : FDTALUSDCL non trouvé.

pouvez-vous me dire comment faire fonctionne le lisp, S'il vous plait.

Cordialement

Luna · le 29 juin 2022

Coucou,

Si je comprend à peu près le code, je dirais que tu as besoin d'un fichier DCL (il n'est pas créé par le programme LISP). Donc quand tu dis

il y a 30 minutes, Greg27 a dit :

Je viens d'essayer le lisp cité si dessus

que veux-tu dire par là ? As-tu fais un copié/collé du code du post précédent ou bien as-tu cliqué sur le lien du premier post pour télécharger le ZIP présent sur le site ?
Car si c'est la première option, je te suggère de télécharger le ZIP qui doit très certainement contenir le fichier LISP ainsi que les fichiers DCL nécessaires au bon fonctionnement du programme !

Bisous,
Luna

Greg27 · le 29 juin 2022

Salut Luna,

j'ai trouver le problème il fallait aussi inscrire le chemin d'accès du fichier dans : "option" onglet Fichiers puis "chemin de recherche de fichiers de support de travail" faire ajouter (le chemin de mon fichier) puis le monter en 1er ligne, afin que la lisp sois bien reconnu.

Merci de ta réponse.

Greg27

PS, aurais-tu une liste de lisp pour Autocad , afin de pouvoir améliorer l'améliorer.

Luna · le 29 juin 2022

Regarde déjà les LISPs de Patrick_35 ainsi que les LISPs de (gile). Tu devrais déjà en avoir plus qu'il n'en faut !
Sinon tu peux essayer de regarder sur le site de LeeMac (en anglais !) si tu n'en as pas suffisamment..

Bisous,
Luna

Greg27 · le 29 juin 2022

merci beaucoup luna pour ton aide,

Sais-tu comment je peux récupéré un model de lisp de Gile car quand je clic dessus il y a une page internet qui s'ouvre avec le contenu mais je ne peux pas avec le fichier lisp.

Greg27

didier · le 29 juin 2022

Bonjour @Greg27

C'est quoi un "modèle de lisp" ? Et ça : "mais je ne peux pas avec le fichier lisp" c'est encore plus obscur.

Je pense que tu es en apprentissage de ce langage, non ? Tu peux lire les programmes des autres, mais c'est comme une langue étrangère et sans base de vocabulaire ou de syntaxe, voire de grammaire, tu ne sauras pas faire les tiens rien qu'en lisant les autres.

J'ai réalisé un site pour l'apprentissage, je me permets de t'y convier (voir ma signature)

À ta disposition pour répondre aux questions qui ne devraient pas tarder.

Amicalement

Connexion

Lisp dessin de talus

Messages recommandés

lutofo

Lien vers le commentaire

Partager sur d’autres sites

Aviglémy

Lien vers le commentaire

Partager sur d’autres sites

Dinosor

Lien vers le commentaire

Partager sur d’autres sites

lutofo

Lien vers le commentaire

Partager sur d’autres sites

Greg27

Lien vers le commentaire

Partager sur d’autres sites

Luna

Lien vers le commentaire

Partager sur d’autres sites

Greg27

Lien vers le commentaire

Partager sur d’autres sites

Luna

Lien vers le commentaire

Partager sur d’autres sites

Greg27

Lien vers le commentaire

Partager sur d’autres sites

didier

Lien vers le commentaire

Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante