Sans ouvrir le DWG

[l56]

Je me débrouille en LISP mais pas en VLISP et ce que je veux doit pouvoir peut-etre se faire en VLISP.

 

Comment faire pour récuperer la liste des blocs contenu dans chaques présentations d'un fichier sans l'ouvrir.

 

Merci à ceux qui savent ...

[(gile)]

Salut,

 

fais une recherche avec ObjectDBX

 

Un petit exemple vite fait :

 

;;; gc:GetAxDbDoc
;;; Accéder à un dessin fermé
;;;
;;; Retourne :
;;; un objet IAxDbDocument si le document est trouve
;;; nil si le document n'a pu être trouvé ou s'il est ouvert
;;;
;;; Argument :
;;; Le chemin complet du fichier
;;;
;;; Exemple d'utilisation :
;;; (if (setq doc (gc:GetAxDbDoc filename))
;;;   (progn
;;;     ...
;;;     (vla-SaveAs doc filename)
;;;     (vlax-release-object (car doc))
;;;   )
;;; )

(defun gc:GetAxDbDoc (filename / axdbdoc release)
 (setq axdbdoc
        (vlax-create-object
          (if (             "ObjectDBX.AxDbDocument"
            (strcat "ObjectDBX.AxDbDocument." (itoa release))
          )
        )
 )
 (if (vl-catch-all-apply
       'vla-open
       (list axdbdoc filename)
     )
   (not (vlax-release-object axdbdoc))
   axdbdoc
 )
)

;; Exemple d'utilisation

(defun test (/ filename doc lst sub)
 (if (and
(setq filename (getfiled "Fichier à traiter" "" "dwg" 0))
(setq doc (gc:GetAxDbDoc filename))
     )
   (progn
     (vlax-for	layout (vla-get-Layouts doc)
(if (/= (vla-get-Name layout) "Model")
  (progn
    (setq sub nil)
    (vlax-for obj (vla-get-Block layout)
      (if (= (vla-get-ObjectName obj) "AcDbBlockReference")
	(setq sub
	       (cons
		 (if
		   (vlax-property-available-p obj 'EffectiveName)
		    (vla-get-EffectiveName obj)
		    (vla-get-Name obj)
		 )
		 sub
	       )
	)
      )
    )
    (setq lst (cons (list (vla-get-Name layout) sub) lst))
  )
)
     )
     (vlax-release-object doc)
   )
 )
 lst
)

[l56]

Merci (gile) !

Non seulement tu me donnes la réponse sur un plateau mais en plus ton post est éducatif.

2 fois merci.

 

Combiné avec le post de Patrick_35, c'est le top.

http:// http://cadxp.cadmag.info/sujetXForum-13402.htm

 

A+

L56