Aller au contenu

Nettoyer - wipeout


dfbiagio

Messages recommandés

Hello

 

Je n ai pas vu tes fichiers !

 

Néanmoins il faut savoir que il y a un bug aléatoire dans AutoCAD avec les Wipeout (Commande: nettoyer) lors du Trace : Polygone Noir et Non pas Blanc !

 

Donc il faut faire manuellement un polygone de "protection" dans la couleur RGB 254,254,254 !!

Et surtout pas 255, 255, 255

 

Bye, lecrabe "triste"

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Bonjour, si le problème concerne uniquement le bloc CHASSIS-COULISSANT il ne faut pas que le wipeout soit dans le calque DEFPOINT. C'est un calque non imprimable.

Cordialement.

 

 

Ah bien mince alors, je ne comprends pas comment c'est arrivé!! Effectivement, c'est bien ça.

Je n'utilise plus ce layer depuis qu'il on introduit les layers non-imprimable.

 

Merci encore.

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Je n ai pas vu tes fichiers !

 

Néanmoins il faut savoir que il y a un bug aléatoire dans AutoCAD avec les Wipeout (Commande: nettoyer) lors du Trace : Polygone Noir et Non pas Blanc !

 

Donc il faut faire manuellement un polygone de "protection" dans la couleur RGB 254,254,254 !!

Et surtout pas 255, 255, 255

 

Bye, lecrabe "triste"

 

J'aime pas trop cette solution, on obtient des tâches blanches partout ;)

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

ATTENTION : parfois les Polygones Wipeout (en theorie BLANC) sortent en NOIR sur le Papier ou en PDF !?

 

Bye, lecrabe "triste"

 

C'est quand même navrant qu'en 2019, on rencontre encore des problèmes basiques qui existaient déjà il y a au moins 15 ans angry.gif

  • Upvote 1
Lien vers le commentaire
Partager sur d’autres sites

Hello

 

C pourquoi le REGRETTE Patrick_35 m'avait developpe une superbe Routine RWH_254 !

 

Bye, lecrabe "triste"

 

 

;; 
;; http://cadxp.com/topic/38953-wipeout/page__p__230975
;; 
;; Routine: RWH_254  (Ex RWH)  par P35 pour Patrice
;; 
;; Remplacer un wipeout par une hachure "SOLID" de couleur 254,254,254
;; 
;; Modifier avec 254,254,254 a cause d un BUG Aleatoire avec les PDFs !!
;;

(vl-load-com) 

(defun c:RWH_254 (/ blo col dat dic doc ent hac ele lst obj pol rgb)
 (setq doc (vla-get-activedocument(vlax-get-acad-object))
col (vlax-create-object (strcat "AutoCAD.AcCmColor." (substr (getvar "acadver") 1 2)))
 )
 (vla-startundomark doc) 

; (vla-setrgb col 255 255 255) 
 (vla-setrgb col 254 254 254) 

 (vlax-for blo (vla-get-blocks doc)
   (or (wcmatch (vla-get-name blo) "*|*")
(eq (vla-get-isxref blo) :vlax-true)
     (progn
(vlax-for ent blo
  (and (eq (vla-get-objectname ent) "AcDbWipeout")
    (progn
      (setq hac (vla-addhatch blo acHatchPatternTypePredefined "SOLID" :vlax-true)
	    lst (gc:RasterVertices (vlax-vla-object->ename ent))
	    pol (vla-addlightweightpolyline blo
					    (vlax-safearray-fill
					      (vlax-make-safearray vlax-vbdouble (cons 0 (1- (* (length lst) 2))))
					      (apply 'append (mapcar '(lambda (x) (list (car x) (cadr x))) lst))
					    )
		)
      )
      (vlax-put pol 'closed :vlax-true)
      (vlax-invoke hac 'appendouterloop (list pol))
      (vla-evaluate hac)
      (foreach ele (list hac pol)
	(mapcar '(lambda(x) (vlax-put ele x (vlax-get ent x))) (list 'layer 'linetype 'linetypescale))
	(vlax-put ele 'truecolor col)
      )
      (setq dat (cons hac (cons pol dat)))
      (vla-delete ent)
    )
  )
)
(and dat
  (progn
    (and (vl-catch-all-error-p (setq dic (vl-catch-all-apply 'vla-item (list (vla-getextensiondictionary blo) "ACAD_SORTENTS"))))
      (setq dic (vla-addobject (vla-getextensiondictionary blo) "ACAD_SORTENTS" "AcDbSortentsTable"))
    )
    (vlax-invoke dic 'movetobottom dat)
    (setq dat nil)
  )
)
     )
   )
 )
 (vlax-release-object col)
 (vla-regen doc acallviewports)
 (vla-endundomark doc)
 (princ)
)


;; Différentes routines de GC trouves sur theswamp.org
;; http://www.theswamp.org/index.php?topic=36270.msg418035#msg418035
;; Convertion des pixels d'une image en coordonnées Autocad
;; gc:RasterVertices
;; Returns the image raster (or wipeout) boundary vertices list (WCS) 

(defun gc:RasterVertices (img / elst ins u v size norm mat disp pts)
 (setq	elst (entget img)
ins  (cdr (assoc 10 elst))
u    (cdr (assoc 11 elst))
v    (cdr (assoc 12 elst))
size (cdr (assoc 13 elst))
norm (gc:CrossProduct u v)
u    (trans u 0 norm)
v    (trans v 0 norm)
mat  (trp (list u (mapcar '- v) '(0. 0. 1.)))
disp (mapcar '+
	     (trans ins 0 norm)
	     (gc:ScaleVector v (cadr size))
	     (gc:ScaleVector u 0.5)
	     (gc:ScaleVector v -0.5)
     )
pts  (if (= 1 (logand 1 (cdr (assoc 71 elst))))
       ((lambda	(l)
	  (list	(car l)
		(list (caadr l) (cadar l) (caddar l))
		(cadr l)
		(list (caar l) (cadadr l) (caddar l))
	  )
	)
	 (gc:massoc 14 elst)
       )
       (cdr (gc:massoc 14 elst))
     )
 )
 (mapcar
   '(lambda (p)
      (trans (mapcar '+ (mxv mat p) disp) norm 0)
    )
   pts
 )
)


;; gc:ScaleVector
;; Multiply a vector by a scalar 

(defun gc:ScaleVector (v s) (mapcar (function (lambda (x) (* x s))) v))

;; gc:CrossProduct
;; Returns the cross product of two vectors
(defun gc:CrossProduct (v1 v2)
 (list	(- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
(- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
(- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
 )
)


;; MXV
;; Apply a transformation matrix to a vector -Vladimir Nesterovsky- 

(defun mxv (m v)
 (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) m)
)


;; TRP
;; Transpose a matrix -Doug Wilson- 

(defun trp (m) (apply 'mapcar (cons 'list m)))

;; gc:massoc
;; Returns the list of all values for the code in an association list
(defun gc:massoc (code alst)
 (if (setq alst (member (assoc code alst) alst))
   (cons (cdar alst) (gc:massoc code (cdr alst)))
 )
) 

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Invité
Répondre à ce sujet…

×   Collé en tant que texte enrichi.   Coller en tant que texte brut à la place

  Seulement 75 émoticônes maximum sont autorisées.

×   Votre lien a été automatiquement intégré.   Afficher plutôt comme un lien

×   Votre contenu précédent a été rétabli.   Vider l’éditeur

×   Vous ne pouvez pas directement coller des images. Envoyez-les depuis votre ordinateur ou insérez-les depuis une URL.

×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité