Aller au contenu

Spline Méthode


Topheur

Messages recommandés

Bonjour,

 

J'utilise la commande EXTRIM d'autocad pour ajuster des splines qui parte du centre d'un cercle.

En clair, j'ai un cercle et je trace des splines depuis le centre du cercle vers des éléments en dehors du même cercle.

 

Lorsque j'utilise EXTRIM à l'intérieur du cercle, cela "nettoie" l'intérieur mais si je clique sur mes splines, les points de lissages ne corresponde plus à ajustement.

 

Pour palier à cela, je sélectionne toutes mes splines et je passe l'option Méthode (dans propriété) à Ajustement.

 

Je cherche la commande me permettant de le faire en ligne de commande sans succès.

J'ai essayé de sélectionner mes splines et de taper SPLMETHOD mais cela ne fonctionne pas.

 

Merci de votre aide.

Lien vers le commentaire
Partager sur d’autres sites

Coucou

 

Je viens de faire le test, effectivement les points d'ajustement et les points de lissage varient.

Est-ce important ? l'aspect visuel est identique et les splines (ni leurs points) ne se déplacent pas.

 

Si tu en as besoin de ce comportement il va falloir passer par un lisp qui va "couper" les splines à l'intersection avec le cercle, et dans ce cas tout est correct.

 

Amicalement

 

Lien vers le commentaire
Partager sur d’autres sites

Bonjour didier,

 

En terme de rendu cela n'est pas grave, mais je ne vous ai pas tous dit :P

 

En fait, je réutilise ces cercles et splines, sur différent plans, parfois je tombe bon, parfois il faut déplacer certains point des splines.

 

Pour le moment, je sélectionne toutes mes spline et dans propriété je change Méthode en Ajuster.

 

C'est pas très long mais quand on multiplie par le nombres de plans, c'est 3 secondes par plans de perdu et mis bout à bout, c'est des heures de travail perdu...

 

C'est pour cela que je cherche une commande (ou un lisp, je suis preneur) pour faire cela en une commande du genre SPAJUSTE ;)

 

Merci de ton aide

Lien vers le commentaire
Partager sur d’autres sites

Salut,

 

;; Met les splines sélectionnées en mode "sommets de contrôle"
(defun c:SPLCTRL (/ ss i elst flag)
 (if (setq ss (ssget '((0 . "SPLINE"))))
   (repeat (setq i (sslength ss))
     (setq elst (entget (ssname ss (setq i (1- i))))
           flag (assoc 70 elst)
     )
     (entmod (subst (cons 70 (logand (cdr flag) (~ 1024))) flag elst))
   )
 )
 (princ)
)

;; Met les splines sélectionnées en mode "ajustement"
(defun c:SPLFIT (/ ss i elst flag)
 (if (setq ss (ssget '((0 . "SPLINE"))))
   (repeat (setq i (sslength ss))
     (setq elst (entget (ssname ss (setq i (1- i))))
           flag (assoc 70 elst)
     )
     (entmod (subst (cons 70 (logior (cdr flag) 1024)) flag elst))
   )
 )
 (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
ADSK_Expert_Elite_Icon_S_Color_Blk_125.png

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité