commande "dissocier"

[La Lozère]

Bonjour,

La commande DISSOCIERGROUPE (ou via le menu contextuel), il est possible de dissocier UN groupe.

Mais peut-on faire la même manip sur plusieurs groupe simultanément? Sans le faire 1 par 1.

 

Je cherche, mais je n'ai rien trouvé et grpdegrp.vlx ne le permet pas non plus...

 

Une idée?

Merci.

[lili2006]

Bonsoir à toutes et tous,

PICKSTYLE : 1

Ou raccourcit clavier "control + H" ?

Là par contre tu associe/dissocie tous les groupes, ce n'est peut être pas ton souhait,..

 

[lecrabe]

Hello

 

Veux tu une routine LSP qui supprime TOUS les groupes ?

 

Bye, lecrabe (3000 routines en stock)

[La Lozère]

Hello,

 

Lili2006: PICKSTYLE ne dégroupe pas les groupes. La variable gère la sélectionnabilité ou non des groupes dans leur ensemble. Mais les groupes même avec pickstyle à 0 existent toujours.

 

lecrabe: Non, je ne veux pas supprimer tout les groupes, mais plusieurs par sélection. Sélection par fenêtre ou simple clic.

 

Merci.

 

PS lecrabe: Comment gères-tu 3000 routines? Tu as un fichier Excel pour suivre? Car il y a de quoi s'y perdre. ;)

[Fraid]

Bonjour,

 

Comme les groupes disparaissent quand on les envois dans un autre dessin, on peut faire un wbloc et réinsérer.

il faut créer le dossier c:\\Data ou remplacer le chemin par votre dossier préféré

(defun c:dgs (/ sel O< file)
   (vl-load-com)
(setq  file  "C:\\Data\\temporaire.dwg" sel (ssget))
(if (= (getvar "ctab") "Model")
	(progn
		(if (= (getvar "worlducs") 0)(progn (vl-cmdf "_.ucs" "")(setq O< 1)))
		(vla-wblock (vla-get-ActiveDocument (vlax-get-acad-object)) 
		   file (vla-get-activeselectionset (vla-get-ActiveDocument (vlax-get-acad-object)))
		)
		(vl-cmdf "_.delay" 1500)
		(vla-explode 
		  (vla-insertblock (vla-get-modelspace (vla-get-ActiveDocument (vlax-get-acad-object))) 
		  (vlax-3d-point '(0 0 0)) file 1 1 1 0)
		)
		(vl-cmdf "_erase" (ssget "_X" (list (cons 2 "temporaire"))) "")
		(vl-cmdf "_erase" sel "")
		(vl-cmdf "_.-purge" "b" "temporaire" "n")
		(vl-file-delete file)
		(if O< 
		  (progn 
		    (vl-cmdf "_ucs" "p")
			(vl-cmdf "repere" "")
			(vl-cmdf "_zoom" "_c" (trans (trans (getvar "viewctr") 1 0) 0 1) (getvar "viewsize"))
		   )
		)
	)
	(princ "\nCette commande s'execute dans l'espace Objet")
)
(princ)
)

 

c'est un peux tiré par les cheveux, mais cela fonctionne sur 2011.

[La Lozère]

Effectivement, ça peut le faire comme ça. Mais sur ma 2018, voici le retour que j'ai:

Sélectionner des objets: _.delay Entrez le temps de pause (en millisecondes): 1500

Commande: ; erreur: Erreur Automation Fichier introuvable

[Olivier Eckmann]

Bonjour,

 

en faisant précéder DISSOCIERGROUPE par la commande MULTIPLE pour la répéter

^C^CMULTIPLE DISSOCIERGROUPE

 

Sinon, si tu connais le nom du groupe, tu peux utiliser la commande

 

-GROUPE D XXXXX

 

Olivier

[Fraid]

désolé, j'ai oublier de tester l’existence du dossier C:\\Data, il faut le créer avant.

[bonuscad]

Ou encore voir PurgeAllGroups(ou d'autres) sur cette page

[La Lozère]

Alors,

Olivier, j'ai testé ta méthode. Disons que ça raccourcis la manip, mais on est encore obligé de sélectionner les groupes l'un après l'autre. Pas possible de faire de fenêtre.

Et merci, je ne connaissais pas la commande MULTIPLE ;)

 

Bonuscad, bizarre, je charge bien le lsp, mais la commande PurgeAllGroups me revoie commande inconnue :blink:

 

Fraid, ok merci, ça fonctionne

[bonuscad]

Bonuscad, bizarre, je charge bien le lsp, mais la commande PurgeAllGroups me revoie commande inconnue

Le concepteur n'a pas fais une commande, mais une fonction sans arguments.En ligne de commande il te faut l'invoquer avec des parenthèses

(PurgeAllGroups)

 

[rebcao]

Hello,

 

Ma réponse va pas te plaire ?!#!&@

 

Utilise une version LT et c'est bien une bizarrerie AUTODESKIENNE, merci les développeurs qui propose une SUPER barre d'outils où la sélection se fait très simplement !

 

rien à voir avec l'HORRIBLE fenêtre des groupes d'une version COMPLETE !!!

Franchement, ils ont encore du boulot chez AUTODESK, eh ben non, ils s'ennuies et redessinent les icônes !

 

Christian

 

 

[La Lozère]

Bonuscad, effectivement ça marche mieux comme ça. Mais du coup, cela détruit tous les groupes.... :(

 

Redcao, elle ressemble à quoi cette barre d'outils sur LT?

[rebcao]

Voici la fenêtre qui s'attache comme une barre d'outils et se gère comme les calques pour désactiver un groupe...

 

http://www.rebcao.fr/cadxp/images/fenetre_Gestionnaire_de_Groupes.png

 

Et bien sur les touches SHIFT + clic ou CONTROL + clic fonctionnent parfaitement...

 

Tu vois, LT c'est moins cher mais c'est mieux !!!!

 

Christian

[La Lozère]

:blink: :blink: :blink: Effectivement.... il y a du mieux.

[Fraid]

He coucou,

 

en faisant un petit effort, en utilisant le dictionnaire.

 

(defun c:sgs (/ sel listgroup listentgroupe listodestroy int)

(setq sel (ssget)
     listgroup (getallgroups)
  
)
(mapcar '(lambda (x)
           (setq listentgroupe (getgroupentities (car x)) int 0)
           (repeat (sslength sel)
		    (if (member (ssname sel int) listentgroupe) (setq listodestroy (cons (car x) listodestroy)))
			(setq int (1+ int))
		)
         )
 listgroup
)
(if listodestroy (PurgeGroups listodestroy))

(princ)

)

(defun getallgroups ( / dic item lst )
 (if (setq dic (reverse (dictsearch (namedobjdict) "ACAD_GROUP")))
   (while (setq item (assoc 3 dic))
     (setq lst (cons (cons (cdr item) (cdr (assoc 350 dic))) lst)
           dic (cdr (member item dic))
     )
   )
 )
 lst
)

(defun getgroupentities ( group / dic ent lst )
 (if
   (and
     (setq dic (dictsearch (namedobjdict) "ACAD_GROUP"))
     (setq dic (dictsearch (cdr (assoc -1 dic)) group))
   )
   (while (setq ent (assoc 340 dic))
     (setq lst (cons (cdr ent) lst)
           dic (cdr  (member ent dic))
     )
   )
 )
 lst
)
(defun PurgeGroups ( listg / grpList index grp)
 (setq grpList (dictsearch (namedobjdict) "ACAD_GROUP"))
 (setq index 1)
 (while (setq grp (nth index grplist))
   (if	(and (= (car grp) 3)(member (cdr grp) listg))
     (entdel (cdr (nth (+ index 1) grplist)))
   )
   (setq index (+ 1 index))
 )
 (princ)
)

inspiratition Lee Macienne

[rebcao]

Bonjour,

 

Franchement au prix qu'on paye les licences être encore obligé de développer des programmes c'est comme si j'achetais une voiture sur laquelle je devrais moi même installer des roues parce qu'ils ne les ont pas prévues !

 

Christian

[Aleck_Ultimate]

Salut.

 

Mais non, tu comprend rien ! C'est donner la possibilité au client de faire du tunigue ! Ca nous donne la possibilité de pimper notre logiciel pour qu'il soit parfaitement adapté à notre façon de travailler.

 

Parce que ta voiture, si tu a des pneus standards tu peut pas rouler correctement sur la glace ou les pistes caillouteuses des dessert ! Et puis comme ça c'est nickel, en plus c'est toi qui choisi les gentes qui te plaisent à toi ! Celle qui vont refléter ta personnalité !

 

Franchement, dans ce "nouveau monde" dans lequel nous somment de plus en plus infantilisés vous devriez être contant d'avoir enfin un éditeur de logiciel qui nous laisse la possibilité de personnaliser notre outils de travail, qui nous permet de créer par nous même ce dont nous avons besoin plutôt que de nous noyer sous les fonctionnalité toujours trop simples ou trop complexes dont on n'utilise qu'une infime fraction ! Regardez Revit, tout nouveau, et pourtant pas de LISP ! Même pas de barre de commande ! C'est une honte !

 

Autodesk, l'entreprise qui redonne le pouvoir à ses clients !

 

...

 

...

 

Non, j'ais pas (encore) pété un câble, mais j'imagine trop un jeun cadre dynamique BCBG qui ferait son spitch devant les actionnaires.

 

Cordialy.

[Fraid]

Bonjour,

 

Je suis d'accord avec vous deux, la programmation dans Autocad permet de personnaliser et gagner en productivité mais n'est pas la pour corriger les bugs.

 

Sinon, attention avec mon code, je n'ai pas testé en profondeur, et il doit planter avec les groupes anonymes.

Il y a donc des exceptions à gérer, je verrais cela dés que j'ai terminé mon taf.

[Aleck_Ultimate]

j'ais peut-être un peut trop bien réussit mon texte, c'était censé être du sarcasme. Même si quant j'ais testé Revit j'ais vraiment regretté l'absence de barre de commande.

[Fraid]

Bonjour,

 

Je n'ai pas trouvé de cas de plantage, même avec les groupes anonymes cela fonctionne (ils ne le sont pas vraiment).

Mais je n'ais pas essayer sur tes plans La Lozère, cela fonctionne t'il?