Copier une sélection dans un autre calque

[DenisHen]

Bonjour à tous.

 

Voilà, je cherche à copier une sélection dans un autre calque.

 

J'ai écris ceci, mais rien ne se copie :

;;; ******************************************
;;; Copie une polyligne dans un autre calque  
;;; ******************************************
(defun c:CopieCalq (Calq / i etx ss)
 (if (not (tblsearch "layer" Calq))
   (command "-calque" "e" Calq "")
 ) ;_ Fin de if
 (setq ss (ssget))
 (command "_copyclip" ss "")
 (command "_pasteorig")
 (if ss
   (progn (setq i 0)
          (while (< i (sslength ss))
            (setq etx (entget (ssname ss i)))
            (setq etx (subst (cons 8 Calq) (assoc 8 etx) etx))
            (entmod etx)
            (setq i (+ i 1))
          ) ;_ Fin:while
   ) ;_ Fin:progn
 ) ;_ Fin:if
) ;_ Fin de defun

Que j'appelle comme ceci :

^C^C(c:CopieCalq "_Construction HT");

Si quelqu'un a une astuce, un conseil... je suis preneur...

[DenisHen]

Je viens de découvrir un problème.

 

Lorsque je fais un "copier", puis un "coller vers coordonnées d'origine" "à la main", rien ne se copie... :blink: nul part... :blink:

[Patrick_35]

Salut

 

Utilises la commande copier (_.copy), puis la commande chprop pour changer de calque.

Si tu restes en Autolisp, que tu veux que ce soit les objets copiés (et non la sélection) qui changent de calque, il faut pointer avant la commande copier le dernier objet (entlast), faire la copie. Tu retrouveras les objets copiés avec (entnext (entlast)), puis (entnext (entnext (entlast))), etc...

 

ps : tes objets copiés doivent être superposés à la sélection.

 

@+

[Patrick_35]

Comme j'avais 5 mn ;)

 

(defun c:CopieCalq (Calq / cmd der ss)
 (setq cmd (getvar "cmdecho"))
 (setvar "cmdecho" 0)
 (or (tblsearch "layer" Calq)
   (vl-cmdf "_.layer" "_make" Calq "")
 )
 (and (setq ss (ssget))
   (progn
     (setq der (entlast))
     (vl-cmdf "_.copy" ss "" "0,0,0" "0,0,0")
     (while (setq der (entnext der))
(vl-cmdf "_.chprop" der "" "_layer" Calq "")
     )
     (princ (strcat "\n" (itoa (sslength ss)) " objet(s) copié(s) sur le calque : " Calq))
   )
 )
 (setvar "cmdecho" cmd)
 (princ)
)

 

@+

[DenisHen]

Salut patrick_35.

 

Mille mercis ! ! ! Ça fonctionne à merveille ! ! ! ;)

[Patrick_35]

Juste en jouant avec les codes dxf

 

(defun c:CopieCalq (Calq / n ent ss)
 (setq n 0)
 (and (setq ss (ssget))
   (while (setq ent (ssname ss n))
     (setq ent (vl-remove-if '(lambda(x)(vl-position (car x) '(-1 5))) (entget ent)))
     (entmake (subst (cons 8 Calq) (assoc 8 ent) ent))
     (setq n (1+ n))
   )
 )
 (princ (strcat "\n" (itoa n) " objet(s) copié(s) sur le calque : " Calq))
 (princ)
)

 

@+

[rebcao]

Bonjour,

 

Si c'est pour l'exercice OK, mais pourquoi ne pas utiliser la commande toute prête : _-COPYTOLAYER

 

 

Christian

[DenisHen]

Salut Christian.

 

Tout simplement parce que je ne connaissais pas cette commande... :huh:

[Patrick_35]

Salut

 

+1 avec Denis

 

@+