Aller au contenu

TAR.BZ2 to DWG en masse


Fraid

Messages recommandés

Bonjour,

 

Les questions sur les fichiers de données communales sont de plus en plus présente.

et on tombe souvent sur des .tar.bz2

 

format prévu pour les système linux.

 

le but est de les décompresser et ne garder que les dwg.

 

il y a quelque prérequis.

DOSLIB (suis accro)

7z (pas réussi avec Izarcc)

un dossier c:/Data

un dossier avec des dossiers nommé avec les N° INSEE des communes

 

(defun c:EXTRACT_CADA (/ LIST_COM
		)
(vl-load-com)
(if (= required nil) ;si les prérequis sont là
	(progn
	(setq LIST_COM  (cdr (dos_dirtree (dos_getdir "Chercher un Dossier..." "G:/MAP/Cadastre" "Sélectionne un dossier" t))));Editer "G:/MAP/Cadastre" pour ouvrir l'explorateur a cet endroit
	(mapcar '(lambda (oOo) (extract oOo)) LIST_COM);extract est appliqué à chaque élément de la liste des dossiers
	(princ "\nExtraction des DWG réussi !!")
	)
	(cond 	((= retour 1) (princ "\nVeuillez installer la version du DOSLIB adaptée à votre poste : http://wiki.mcneel.com/doslib/home"))
		((= retour 2) (princ "\nVeuillez installer 7z sur votre poste : http://7zip.fr/"))
		((= retour 3) (princ "\nVeuillez installer la version du DOSLIB adaptée à votre poste : http://wiki.mcneel.com/doslib/home" 
					"\net installer 7z : http://7zip.fr/"))
	)
)
);Fin

(defun extract ( com / TEXT WT DES
			)
(setq 	TEXT "C:\\Data\\Z.bat"
	WT (open  TEXT "w");Création du .bat
)
(write-line "@echo off" WT)
(write-line (strcat "\"C:\\Program Files\\7-Zip\\7z.exe\" e " com "*.tar.bz2 -o" com " -r -y") WT)
(write-line (strcat "\"C:\\Program Files\\7-Zip\\7z.exe\" e " com "*.tar -o" com " -r -y") WT)
(close WT)
(command 	"_.shell" TEXT) ;lancement du .bat 
(command	"_.delay" 1000)
(setq DES (dos_find (strcat com "*.DXF")));Liste des dxf
(if (/= DES nil) ;si la décompression à réussie
	(progn
		(mapcar '(lambda (OoO) (dos_delete OoO)) (list (strcat com "*.bz2") (strcat com "*.tar") TEXT));Suppression des archives
		(mapcar '(lambda (OoO) (dxf2dwg OoO "O")) DES);Conversion des DXF en DWG, Remplacer "O" par "N" pour ne pas effacer les dxf
		
	)
	(dos_delete TEXT)
);Fin du if
);Fin extract
(defun dxf2dwg ( dxf sup / DWG OP)
(setq 	DWG (strcat (substr dxf 1 (- (strlen dxf) 3)) "dwg")
	OP 	(vla-open (vla-get-documents (vlax-get-acad-object)) dxf)
)
(command "_.delay" 1000)
(vla-saveas OP DWG)
(command "_.delay" 1000)
(vla-close OP)
(command "_.delay" 500)
(if (= sup "O") (dos_delete dxf))
(command "_.delay" 500)
);Fin dxf2dwg
(defun required nil
(setq retour nil)
(CreatFolder "C:\\Data");le dossier est créer si il n'existe pas	
(if (not (TEST_DOSLIB)) (setq retour 1))			
(if (not (findfile "C:\\Program Files\\7-Zip\\7z.exe")) (setq retour (+ 2 retour)))			
retour			
);Fin required
(defun CreatFolder (PathFolder)
 (if (not (vl-file-directory-p PathFolder))
   (vl-mkdir PathFolder)
 )
)
(defun TEST_DOSLIB (/ LIST_DOSLIB flag
				)

(setq LIST_DOSLIB (list   ;liste des versions du DOSLIB
	"DOSLib17.arx"
	"DOSLib17x64.arx"
	"DOSLib18.arx"
	"DOSLib18x64.arx"
	"DOSLib19.arx"
	"DOSLib19x64.arx"
	"DOSLib20.arx"
	"DOSLib20x64.arx"
	"DOSLib21.arx"
	"DOSLib21x64.arx"
	"DOSLib22.arx"
	"DOSLib22x64.arx")
)

(mapcar '(lambda (IOI) ((if (member IOI (arx))(setq flag 1))) LIST_DOSLIB)) ;vérifie si un des membre de la liste est présent dans la liste des arx chargés.

flag
)

 

si ça peut rendre service

Modifié par Fraid
Lien vers le commentaire
Partager sur d’autres sites

Salut Fraid.

 

Personnellement, j'ai téléchargé le Cadastre de la France entière, et dès que j'ai besoin d'une commune, je me suis fais un petit Lisp, voici ma méthodologie :

 


  1.  
  2. Décompression de toutes les planches dans le répertoire de la commune, en fait, dans chacun des .tar.bz2 il y a un et un seul DXF, qui correspond à une feuille cadastrale,
  3. Sauvegarde d'un DWG vièrge dans ce même répertoire portant le nom de la commune,
  4. Lancement de on Lisp.
  5. Et voilà...
     

Si tu veux mon petit bout de code, je te le posterais volontiers... Mais je ne fais que du "ponctuel", je ne traite qu'une seule commune à la fois... Ce qui correspond à mes besoins...

 

Et ne travaille pas trop... On est dimanche que diable... ;)

 

Vas faire un tour dans ta magnifique ville, j'ai adoré Saint Malo...

 

Denis...

Windows 11 / AutoCAD 2024

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres (developpez.net).
Davantage d'avantages, avantagent davantage (Bobby Lapointe).
La connaissance s'accroît quand on la partage (Socrate).
Tant va la cruche à l'eau que l'habit n'amasse pas mousse avant de l'avoir tué. (Moi)

Lien vers le commentaire
Partager sur d’autres sites

yop

 

tu vois on fait tous les même prog chacun de notre coté

 

curieux de voir ton code.

 

c'est surtout l'utilisation de 7z en ligne de commande qui m'a intéressé le plus...

j'ai toujours aimé les chauve-souris

 

sinon je travail surtout sur les département (35, 22, 37, 72, 49, 44, 53)

donc pour gagner du temps je me suis dit, vais me les décompresser...

 

mais susceptible de travailler sur des chantiers partout en france

j'en ai un en sortie de gare Montparnasse...

suis sous traitant de bureaux d'ingénierie. (dans le domaine de la fibre optique)

Lien vers le commentaire
Partager sur d’autres sites

Voici mon petit code, comme tu pourras le constater, il y a une petite mise en forme, histoire d'avoir que du cadastre et pas toutes les données parasites qui n'intéressent que les Experts Géomètres... :

;;; Insert les feuilles du Cadastre en DXF
(defun c:InsCadDXF (/ Select ent n a b RepDXF ListFich )
 (princ "\nDéveloppé par Denis H.")
 (command "-unites" "2" "2" "3" "2" "0,0" "@0,1" "O" "pdmode" "32" "pdsize" ".1" "PLINEGEN" "1" "-couleur" "ducalque") ;_ Fin de command
 (command "filedia" "1" "insunits" "6" "attdia" "1" "-typeligne" "a" "ducalque" "" "ecrangra" "_ucs" "_w" "imageframe" "2" "psltscale" "0") ;_ Fin de command
 (ade_projsetwscode "Lambert93");
 (c:DebutChrono)
 (setq RepDXF (getvar "dwgprefix"))
 (setq ListFich (vl-directory-files RepDXF "*.dxf"))
 (setq a 0)
 (while (/= (nth a ListFich) nil) (setq a (+ a 1)))
 (setq b 0)
 (while (/= (nth b ListFich) nil)
   (princ (strcat "\nProgression : " (rtos (+ b 1) 2 0) "/" (rtos a 2 0) "\n"))
   (command "_insert" (strcat RepDXF (nth b ListFich)) '(0 0 0) 1 1 0)
   (command "_explode" "_last")
   (command "-purger" "bl" (substr (nth b ListFich) 1 (- (strlen (nth b ListFich)) 4)) "n")
   (command "zoom" "et")
   (setq b (+ b 1))
 ) ;_ Fin de while
 (c:ConfCadastre);;; Attention, appel d'une autre routine ! ! ! ! ! ! ! ! ! !
 (command "-calque" "e" "CAD_BATI_DUR_HACH" "")
 (setq n 0)
 (if (setq Select (ssget "_X"
                         (list (cons 0 "LWPOLYLINE") (cons 8 "CAD_BATI_DUR") (cons -4 "&") (cons 70 1)) ;_ Fin de list
                  ) ;_ Fin de ssget
     ) ;_ Fin de setq
   (while (setq ent (ssname Select n))
     (command "_hatch" "solid" ent "")
     (setq n (1+ n))
   ) ;_ Fin de while
 )
 (command "_qsave")
 (command "-calque" "e" "CAD_BATI_LEG_HACH" "")
 (setq n 0)
 (if (setq Select (ssget "_X"
                         (list (cons 0 "LWPOLYLINE") (cons 8 "CAD_BATI_LEG") (cons -4 "&") (cons 70 1)) ;_ Fin de list
                  ) ;_ Fin de ssget
     ) ;_ Fin de setq
   (while (setq ent (ssname Select n))
     (command "_hatch" "solid" ent "")
     (setq n (1+ n))
   ) ;_ Fin de while
 )
 (command "_qsave")
 (c:FinChrono)
 (command "_qsave")
 (princ)
) ;_ Fin de defun

Et tu auras aussi besoin de ça :

(defun c:ConfCadastre (/)
 (princ "\nDéveloppé par Denis H.") ;Renomme les calques issu d'un levé de Christophe vers la Charte Graphique
 (setq old_cmdecho (getvar "cmdecho"))
 (setvar "cmdecho" 0)
 (princ "\nInitialisation du dessin...'")
 (command "-unites" "2" "2" "3" "2" "0,0" "@0,1" "O" "pdmode" "32" "pdsize" ".1" "PLINEGEN" "1" "-couleur" "ducalque" "filedia" "1" "attdia" "1" "-typeligne" "a" "ducalque" "" "ecrangra" "_ucs" "_w") ;_ Fin de command
 (princ "\nTous les objets seront 'DuCalque'")
 (command "chprop" "tout" "" "co" "ducalque" "t" "ducalque" "ep" "ducalque" "")
 (princ "\nCalque courant '0'...")
 (command "-calque" "e" "0" "")
 (setq Select nil)
 (setq LstCalq '(("1COMM" . "CAD_LIM_COMMUN") ; Amorces des limites communales
                 ("1DEPART" . "CAD_LIM_DEPART") ; Amorces des limites départementales
                 ("1ETAT" . "CAD_LIM_ETAT") ; Amorces des limites étatiques
                 ("1LIEUDIT" . "CAD_LIM_LIEUDIT") ; Périmètre du lieut-dit
                 ("1PARCELLE" . "CAD_LIM_PARC") ; Périmètre de la parcelle figurée au plan
                 ("1PARCELLENFP" . "CAD_LIM_PARC") ; Périmètre de parcelle non figurée au plan
                 ("1PYLONE" . "CAD_DIVERS") ; Pylône
                 ("1STATION" . "CAD_DIVERS") ; Station de gare
                 ("1SECTION" . "CAD_LIM_SEC") ; Périmètre de la section
                 ("1TRONFLUV" . "CAD_DIVERS") ; Périmètre du tronçon de cours d'eau
                 ("1TRONROU" . "CAD_DIVERS") ; Périmètre de la voie privée
                 ("3AQUEDUC" . "CAD_DIVERS") ; Ligne de l'aqueduc
                 ("3AQUEDUCTEX" . "CAD_DIVERS_TEXT") ; Texte associé à l'aqueduc
                 ("3BATIDUR" . "CAD_BATI_DUR") ; Périmètre du bâtiment dur
                 ("3BATILEGER" . "CAD_BATI_LEG") ; Périmètre du bâtiment léger
                 ("3BATITEX" . "CAD_BATI_TEXT") ; Texte associé au bâtiment
                 ("3CALVAIRE" . "CAD_DIVERS") ; Croix de calvaire
                 ("3CALVAIRETEX" . "CAD_DIVERS_TEXT") ; Indication sur l'occurence "Calvaire", "Puits"...
                 ("3CHEMIN" . "CAD_DIVERS") ; Limite du chemin
                 ("3CHEMINTEX" . "CAD_DIVERS_TEXT") ; Nom du chemin
                 ("3CIME" . "CAD_DIVERS") ; Périmètre du cimetière
                 ("3CIMM" . "CAD_DIVERS") ; Périmètre du cimetière musulman
                 ("3CIMS" . "CAD_DIVERS") ; Périmètre du cimetière israélite
                 ("3CIMETEX" . "CAD_DIVERS_TEXT") ; Libellé associé au cimetière
                 ("3CIMMTEX" . "CAD_DIVERS_TEXT") ; Libellé associé au cimetière
                 ("3CIMSTEX" . "CAD_DIVERS_TEXT") ; Libellé associé au cimetière
                 ("3DPTEX" . "CAD_LIM_PARC_TEXT") ; Numéro parcellaire du DP
                 ("3EAU" . "CAD_DIVERS") ; Périmètre de la surface en eau, lacs, étangs...
                 ("3EAUTEX" . "CAD_DIVERS_TEXT") ; Nom de l'étang, lac
                 ("3EDF" . "CAD_DIVERS") ; Ligne de transport de force
                 ("3EDFTEX" . "CAD_DIVERS_TEXT") ; Nom de la ligne de transport de force
                 ("3EGLISE" . "CAD_DIVERS_TEXT") ; Représentation du sympole d'église
                 ("3EGLISETEX" . "CAD_DIVERS_TEXT") ; Nom de l'église
                 ("3ENSIMMO" . "CAD_DIVERS_TEXT") ; Nom de l'ensemble immobilier
                 ("3FLECHEPAR" . "CAD_LIM_PARC_TEXT") ; Flèche de rattachement de n° parcelle
                 ("3GAZODUC" . "CAD_DIVERS") ; Ligne du gazoduc
                 ("3GAZODUCTEX" . "CAD_DIVERS_TEXT") ; Texte associé au gazoduc
                 ("3LIEUDITTEX" . "CAD_LIM_LIEUDIT_TEXT") ; Nom du lieut-dit
                 ("3LINEDIVERS" . "CAD_DIVERS") ; Détail topographique linéaire divers
                 ("3LINEDIVERSTEX" . "CAD_DIVERS_TEXT") ; Texte associé au détail topographique linéaire divers
                 ("3MOSQUEE" . "CAD_DIVERS") ; Représentation du symbole de mosquée
                 ("3MOSQUEETEX" . "CAD_DIVERS_TEXT") ; Nom de la mosquée
                 ("3NUMVOIE" . "CAD_DIVERS_TEXT") ; Numéro de voirie
                 ("3PARCELLETEX" . "CAD_LIM_PARC_TEXT") ; Numéro de parcelle
                 ("3PARCELLETEX2" . "CAD_LIM_PARC_TEXT") ; Numéro de parcelle 2 ? ?
                 ("3PARCNFPTEX" . "CAD_LIM_PARC_TEXT") ; Numéro de parcelle NFP
                 ("3PONCTDIVERS" . "CAD_DIVERS") ; Détail topographique ponctuel divers
                 ("3PONCTDIVERSTEX" . "CAD_DIVERS_TEXT") ; Texte associé au détail topographique ponctuel divers
                 ("3PONT" . "CAD_DIVERS") ; Périmètre du pont
                 ("3PONTTEX" . "CAD_DIVERS_TEXT") ; Nom du pont
                 ("3SECTIONTEX" . "CAD_LIM_SEC_TEXT") ; Libellé de la section
                 ("3SENTIER" . "CAD_DIVERS") ; Linéaire des sentiers, trottoirs
                 ("3SENTIERTEX" . "CAD_DIVERS_TEXT") ; Nom du sentier
                 ("3SNCF" . "CAD_DIVERS") ; Rail de chemin de fer
                 ("3SNCFTEX" . "CAD_DIVERS_TEXT") ; Nom de la voie de chemin de fer
                 ("3SYNAGO" . "CAD_DIVERS") ; Représentation du symbole religieux
                 ("3SYNAGOTEX" . "CAD_DIVERS_TEXT") ; Nom de la synagogue
                 ("3TELEFERI" . "CAD_DIVERS") ; Ligne du téléphérique
                 ("3TELEFERITEX" . "CAD_DIVERS_TEXT") ; Nom du téléphérique
                 ("3TOPOLINE" . "CAD_DIVERS") ; Terrains de sport, petit ruisseaux et fossés
                 ("3TOPOLINETEX" . "CAD_DIVERS_TEXT") ; Texte associé aux topolines
                 ("3FISCLINE" . "CAD_DIVERS") ; Parkings, terrasses et surplombs
                 ("3FISCLINETEX" . "CAD_DIVERS_TEXT") ; Textes associés aux fisclines
                 ("3PUIT" . "CAD_DIVERS") ; Représentation du puits
                 ("3PUITTEX" . "CAD_DIVERS_TEXT") ; Texte associé au puits
                 ("3PISCINE" . "CAD_DIVERS") ; Périmètre de la piscine
                 ("3PISCINETEX" . "CAD_DIVERS_TEXT") ; Texte associé à la piscine
                 ("3TRONFLUVTEX" . "CAD_DIVERS_TEXT") ; Nom du cours d'eau
                 ("3TRONROUTEX" . "CAD_DIVERS_TEXT") ; Nom de la voie privée
                 ("3TROUBATI" . "CAD_BATI_DUR") ; Contour du trou à l'intérieur des bâtis légers et durs
                 ("3TUNNEL" . "CAD_DIVERS") ; Périmètre du tunnel
                 ("3TUNNELTEX" . "CAD_DIVERS_TEXT") ; Nom du tunnel
                 ("3ZONCOMMTEX" . "CAD_DIVERS_TEXT") ;Nom de la voie du DP routier
                )
 ) ;_ Fin de setq
 (princ "\nRemplacement / fusion des calques...")
 (foreach PosLst LstCalq
   (if (tblsearch "layer" (car PosLst))
     (progn (if (not (tblsearch "layer" (cdr (assoc (car PosLst) LstCalq))))
              (command "-calque" "n" (cdr (assoc (car PosLst) LstCalq)) "")
            ) ;_ Fin de if
            (command "fuscalques" "n" (car PosLst) "" "n" (cdr (assoc (car PosLst) LstCalq)) "o") ;_ Fin de command
     ) ;_ Fin de progn
   ) ;_ Fin de if
 ) ;_ Fin de foreach
 ;;
 (setq LstCalqSup
        '("1ARRET" ;Arret de gare
          "1CHARGE" ;périmètre de la charge
          "1FLECHEFL" ; Flèche rivière
          "1HALTE" ; Halte de gare
          "1SUBDFISC" ; Périmètre de subdivision fiscale
          "1SUBDSECT" ; Périmètre de subdivision de section
          "1TROUCHARGE" ; Contour des trous à l'intérieur des charges
          "1TROUPARCELLE" ; Contour des trous à l'intérieur des parcelles (et NFP)
          "1TROUSECTION" ; Contour des trous à l'intérieur de la section
          "1TROUSUBDFISC" ; Contour des trous à l'intérieur d'une division fiscale
          "1TROUSUBDSECT" ; Contour des trous à l'intérieur des subdivision de section
          "1ZONCOMM" ; Axes de la voie du domaine public routier, chemin rural
          "3BORNE" ; Borne limite de propriété
          "3BOULON" ; Boulon scellé
          "3CADB" ; Point cadastre borné
          "3CADNB" ; Point cadastre non borné
          "3CHARGETEX" ; Lettre indicative de la charge
          "3CLOTMI" ; Cloture mitoyenne
          "3CLOTNONMI" ; Cloture non mitoyenne
          "3CROIX" ; Crois gravée
          "3DIVERS" ; Bornes communales et/ou RNGF
          "3FOSSEMI" ; Fossé mitoyen
          "3FOSSENONMI" ; Fossé non mitoyen
          "3HAIEMI" ; Haie mitoyenne
          "3HAIENONMI" ; Haie non mitoyenne
          "3IGNB" ; Point géodésique borné
          "3IGNNB" ; Point géodésique non borné
          "3LIMNONPARC" ; Ruines et limites surfaciques ne formant pas parcelle
          "3LIMNONPARCTEX" ; Texte associé aux limites surfaciques ne formant pas parcelle
          "3MURMI" ; Mur mitoyen
          "3MURNONMI" ; Mur non mitoyen
          "3SUBDFISCTEX" ; Lettre de subdivision fiscale
         )
 ) ;_ Fin de setq
 (princ "\nSuppression des autres calques...")
 (foreach calque LstCalqSup
   (if (tblsearch "layer" calque)
     (command-s "_-laydel" "_name" calque "" "_yes")
     (princ (strcat "\nCalque " calque " introuvable"))
   ) ;_ Fin de if
 ) ;_ Fin de foreach
 (setvar "cmdecho" old_cmdecho)
 (princ)
) ;_ Fin de defun

 

Bon, c'est pas l'apéro, là, hein ? ;)

Windows 11 / AutoCAD 2024

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres (developpez.net).
Davantage d'avantages, avantagent davantage (Bobby Lapointe).
La connaissance s'accroît quand on la partage (Socrate).
Tant va la cruche à l'eau que l'habit n'amasse pas mousse avant de l'avoir tué. (Moi)

Lien vers le commentaire
Partager sur d’autres sites

commence vers 18h00 l'apéro chez nous :D

 

dès que l'on travail avec la topo, on fait des lisp de transfert de calques par entreprise transmetteuse

y en a c'est facile d'autre moins

des fois il faut penser au différente variations possibles

exemple le calque *VEGETATION*

on trouve, Végétation, gazon, herbe, pelouse, terrain, j'en oublie des cocasses...

et ceux dessiner à l'appareil

ça peut être terrible en traitement de polyligne et bloc si la personne qui fait le levé n'a jamais dessiné autrement.

c'est un métier de levé, c'en ai un autre de les recevoir.

sur le forum c'est plein d'exemples de lisp de traitements de levé

Lien vers le commentaire
Partager sur d’autres sites

Et encore, perso, je reçois des levés topo fait avec GéoVisual (couche de MicroStation), en type V3 (levés spécifique à ENEDIS, trs loin d'être des plans topo) pour faire justement des plans topographiques de qualité sous AutoCAD ! ! !

 

J'ai pourtant forcé la direction à acheter Land2Map et j'ai fais tous les thèmes pour les plans topo...

 

Mais que veux-tu, quand le pouvoir de décision est aux ignorants dans le domaine, on est dans la m****... ;)

Windows 11 / AutoCAD 2024

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres (developpez.net).
Davantage d'avantages, avantagent davantage (Bobby Lapointe).
La connaissance s'accroît quand on la partage (Socrate).
Tant va la cruche à l'eau que l'habit n'amasse pas mousse avant de l'avoir tué. (Moi)

Lien vers le commentaire
Partager sur d’autres sites

  • 4 ans après...

Bonjour Fraid, 

Je suis tombé sur votre post et j'ai essayé la routine lisp que vous proposez mais rien ne se passe quand je la lance. Je ne comprends pas ce que je fais mal, j'ai pourtant respecté les prérequis.

(Je suis sur Autocad 2023)

Lien vers le commentaire
Partager sur d’autres sites

  • 1 mois après...

Bonjour à la communauté.
Personnellement, j'ai un truc rapide mais pas très joli : 
Dans l'explorateur, Ctrl+A > 7zip > "Extraire ici", puis je recommence la même manipulation en remplaçant tous les fichiers.
Ensuite, j'efface les fichiers créés dans la première étape.
Mais c'est vrai que compresser des fichiers (.tar) dans des fichiers compressés (.bz2), ce n'est pas très facile à gérer.

Windows 11 / AutoCAD 2024

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres (developpez.net).
Davantage d'avantages, avantagent davantage (Bobby Lapointe).
La connaissance s'accroît quand on la partage (Socrate).
Tant va la cruche à l'eau que l'habit n'amasse pas mousse avant de l'avoir tué. (Moi)

Lien vers le commentaire
Partager sur d’autres sites

Je n'y avais pas pensé, mais ça fait des années que je n'ai pas utilisé WinRar ou WinZip...

Windows 11 / AutoCAD 2024

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres (developpez.net).
Davantage d'avantages, avantagent davantage (Bobby Lapointe).
La connaissance s'accroît quand on la partage (Socrate).
Tant va la cruche à l'eau que l'habit n'amasse pas mousse avant de l'avoir tué. (Moi)

Lien vers le commentaire
Partager sur d’autres sites

Hello

J ai encore decompresser au moins une dizaine de communes EDIGEO en Lambert CCxx avec Winrar ces 3 dernieres semaines ...

Puis EDIGEOIMPORTREP pour traiter tous les THF en un seul traitement et obtenir un magnifique DWG (avec des MPOLYGONs de MAP quand c necessaire + Object Data) de la commune ... MERCI Covadis !

De plus nous avons le cadastre 04/2023 depuis peu de temps !

Bye, lecrabe

 

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité