CADxp: Créer des champs rapidement - CADxp

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

Créer des champs rapidement LISP création de champ autocad

#1 L'utilisateur est hors-ligne   Alexandre113 

  • ceinture blanche
  • Groupe : Membres
  • Messages : 2
  • Inscrit(e) : 12-mars 18

Posté 13 mars 2018 - 11:21

Bonjour à tous,


Je suis entrain de créer des schémas qui sont amené a changer. J’utilise la fonction "Champ" d'autocad (Insertion/Champ) afin que mes numérotations suivent automatiquement.

Je me suis aperçu que le "dialogue" d'autocad était toujours le même.

Exemple ci-dessous: (J'utilise la fonction champ puis objet, je choisi l'objet et enfin sont index)

%<\AcObjProp Object(%<\_ObjId 8796086055536>%).TextString \f "%tc1">%
%<\AcObjProp Object(%<\_ObjId 8796086055664>%).TextString \f "%tc1">%
%<\AcObjProp Object(%<\_ObjId 8796085999168>%).TextString \f "%tc1">%


Serai t'il possible de créer une LISP qui permettrai de choisi en un clic le texte ou l'attribut et de le créer en champ ?


Merci
0

#2 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11045
  • Inscrit(e) : 02-septembre 05

Posté 13 mars 2018 - 12:54

Salut,

Quelque chose comme ça ?

(defun c:TXT2FIELD (/ doc txt pt)
  (vl-load-com)
  (setq doc (vla-get-Activedocument (vlax-get-acad-object)))
  (if
    (and
      (setq txt (car (nentsel "\nSéléctionnez un texte ou un attribut: ")))
      (member (vla-get-ObjectName (setq txt (vlax-ename->vla-object txt)))
	      '("AcDbAttribute" "AcDbMText" "AcDbText")
      )
    )
     (if (setq pt (getpoint "\nSpécifiez le point d'insertion : "))
       (vla-AddText
	 (vla-get-Block (vla-get-ActiveLayout doc))
	 (strcat
	   "%<\\AcObjProp Object(%<\\_ObjId "
	   (vla-GetObjectIdString (vla-get-Utility doc) txt :vlax-false)
	   ">%).TextString \\f \"%tc1\">%"
	 )
	 (vlax-3d-point (trans pt 1 0))
	 (getvar 'textsize)
       )
     )
    (prompt "\nSéléction no valide.")
  )
  (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#3 L'utilisateur est hors-ligne   Alexandre113 

  • ceinture blanche
  • Groupe : Membres
  • Messages : 2
  • Inscrit(e) : 12-mars 18

Posté 13 mars 2018 - 13:26

Merci gile pour ta rapidité et pour toute les lisp que tu as créé, cela m'aide beaucoup dans mon travail.
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)