Aller au contenu

DEVERROUILLER / VERROUILLER FENETRE (FMULT)


PHILPHIL

Messages recommandés

bonjour

 

en general mes fenêtres sont toutes verrouillées dans l'espace PAPIER

 

dans un lisp comment déverrouiller la fenêtre dans laquelle on est entré apres un

 

 (command-s "espaceo")

 

faire la manip

 

puis la reverrouiller en sortant par un

 

command-s "espacep")

 

Merci, Phil

Autodesk Architecture 2023 sous windows 11 64

24 pouces vertical + 30 pouces horizontal + 27 pouces horizontal

Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Voir ci-dessous ...

 

LA SANTE, Joyeux Noel, Bonnes Fetes, Bye, lecrabe

 

PS: encore MERCI au Rennais Patrick_35 !!

 

 

;;;=================================================================
;;;
;;; UNVERR.LSP V1.00
;;;
;;; Déverrouiller toutes les fenêtres des présentations
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun c:unverr(/ fen n sel tot)
 (vl-load-com)
 (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))
 (if (setq sel (ssget "x" (list (cons 0 "VIEWPORT"))))
   (progn
     (setq n 0 tot 0)
     (while (ssname sel n)
       (setq fen (vlax-ename->vla-object (ssname sel n)))
       (if (eq (vlax-get-property fen "displaylocked") :vlax-true)
         (progn
           (vlax-put-property fen "displaylocked" :vlax-false)
           (setq tot (1+ tot))
         )
       )
       (setq n (1+ n))
     )
     (princ (strcat "\n"  (itoa tot) " fenêtre(s) de déverrouillée(s)"))
   )
   (princ "\nPas de fenêtres")
 )
 (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
 (princ)
)

(princ "\nUNVERR.LSP chargé. Tapez UNVERR pour l'exécuter")
(princ)



;;;=================================================================
;;;
;;; VERR.LSP V1.01
;;;
;;; Verrouiller toutes les fenêtres des présentations
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun c:verr(/ fen n sel tot)
 (vl-load-com)
 (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))
 (if (setq sel (ssget "x" (list (cons 0 "VIEWPORT"))))
   (progn
     (setq n 0 tot 0)
     (while (ssname sel n)
       (if (and (= (logand (cdr (assoc 90 (entget (ssname sel n)))) 16384) 0) (/= (cdr (assoc 69 (entget (ssname sel n)))) 1))
         (progn
           (setq fen (vlax-ename->vla-object (ssname sel n)))
           (vlax-put-property fen "displaylocked" :vlax-true)
           (setq tot (1+ tot))
         )
       )
       (setq n (1+ n))
     )
     (princ (strcat "\n"  (itoa tot) " fenêtre(s) de verrouillée(s)"))
   )
   (princ "\nPas de fenêtres")
 )
 (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
 (princ)
)

(princ "\nVERR.LSP chargé. Tapez VERR pour l'exécuter")
(princ)


Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité