Transformer une Définition d'Attribut en texte

[barbichette]

Bonjour,

 

J'ai dans le dessin que j'ai récupéré, des définitions d'attribut.

J'aimerai bien transformer ces définitions en Texte simple (le texte prenant la valeur de l'étiquette)

 

J'ai testé les différentes option du menu Express Tools en rapport avec le texte, mais aucune ne semble fonctionner..

en ce sens que la définition d'attribut reste une définition d'attribut

 

Merci pour votre aide.

[x_all]

il me semble que c'est une commende des Xpress... burst

[barbichette]

j'ai utilisé la commande Burst

mais à la sélection des définitions d'attibut, il me note 0 objets sélectionnés.

[DenisHen]

Quels noms ont tes blocs ?

 

Je pense à des blocs "anonymes" ou sans nom, style "$AC28...".

[barbichette]

Mais justement, ce ne sont pas des blocs, ce sont des définitions d'attribut directes...

[lecrabe]

Hello

 

OUI je suis deja TOMBE (de haut) sur des DWGs ou les gens avaient utilise des ATTDEFs

pour ecrire des textes simples !! ... Si si ca existe !!

 

Donc il te faut un Lisp pour transformer un ATTDEF en Texte simple

sous entendu , l'etiquette du ATTDEF = le futur texte simple !

 

Je farfouille car je crois avoir ce qu'il faut !?

 

Bye, lecrabe

[lecrabe]

Hello

 

SVP tu testes cette routine :

http://cadtips.cadalyst.com/attributed-blocks/convert-attdef-entities-text

 

Bye, lecrabe

[VDH-Bruno]

Bonjour,

 

Un lisp écrit à la volé à tester (juste pour me prouver si je pouvais l'écrire plus vite que le temps de recherche de lecrabe ;) )

 

(defun c:barbichette (/ ss i e )
 (if (setq ss (ssget "_X" '((0 . "ATTDEF"))))
   (repeat (setq i (sslength ss))
     (setq e (entget (ssname ss (setq i (1- i)))))
     (entmake (list '(0 . "TEXT")
                    '(100 . "AcDbEntity")
                    (assoc 67 e)
                    (assoc 410 e)
                    (assoc 8 e)
                    '(100 . "AcDbText")
                    (assoc 10 e)
                    (assoc 40 e)
                    (cons 1 (cdr (assoc 2 e)))
                    (assoc 50 e)
                    (assoc 41 e)
                    (assoc 51 e)
                    (assoc 7 e)
                    (assoc 71 e)
                    (assoc 72 e)
                    (assoc 11 e)
                    (assoc 210 e)
                    '(100 . "AcDbText")
                    (assoc 73 e)
              )
     )
     (entdel (cdr (assoc -1 e)))
   )
 )
 (princ)
)

 

Edit: !!!!!!!!!!!!!!!!!! Perdu !!!!!!!!!!!!!!!!!!!! :angry: :angry: :angry: (à 2 mn près grrr..)

 

A+

Modifié le 16 septembre 2015 par VDH-Bruno

[(gile)]

Salut,

 

Essaye en collant ça en ligne de commande :

 

((lambda (/ ss i e l)
  (if (setq ss (ssget "_X" '((0 . "ATTDEF"))))
    (repeat (setq i (sslength ss))
      (setq e (ssname ss (setq i (1- i)))
     l (entget e)
      )
      (entmake
 (cons
   '(0 . "TEXT")
   (cons
     (cons 1 (cdr (assoc 2 l)))
     (vl-remove-if-not
       '(lambda	(p)
	  (member (car p) '(67 41 8 10 40 50 41 51 7 71 72 11 210))
	)
       l
     )
   )
 )
      )
      (entdel e)
    )
  )
  (princ)
)
)

[lecrabe]

Hello

 

Vous plaisantez les Pros (Bruno + Gilles) !

 

Vous avez developpe A LA VOLEE et moi j'ai simplement farfouille dans mes 2000 routines ou mes Sites favoris ...

 

Bye, lecrabe

[barbichette]

Merci à vous tous...

 

Je testerai tout ça histoire de voir ce qui marche le mieux...

 

Bye

[DenisHen]

Bonsoir à tous...

 

Petite demande au Décapode... Quels sont tes fameux sites préférés ?

 

Qu'on en profite un peu...

 

Denis...