CADxp: Cacher les calques des XREF - CADxp

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

Cacher les calques des XREF

#1 L'utilisateur est hors-ligne   sechanbask 

  • ceinture noire 2em dan
  • Groupe : Membres
  • Messages : 1012
  • Inscrit(e) : 06-octobre 06
  • LocationPoitiers

Posté 07 juillet 2014 - 12:24

Bonjour,

Est-ce qu'il existe une variable pour que les calques des XREF n'apparaissent plus dans "Tous" de la fenêtre "gestionnaire des propriété des calques" y'a pas un "Tous sauf Xref" ?
ATEN - Bureau d'Études Fluides
Image IPB
Exécution, Synthèse, Conception, Maîtrise d'Oeuvre, Audit, Chiffrage
www.atenbet.fr
0

#2 L'utilisateur est hors-ligne   fauxsuisse 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 927
  • Inscrit(e) : 01-septembre 04
  • LocationSuisse - Châtel St. Denis

Posté 07 juillet 2014 - 12:37

Oui tu peux.
Tu sélectionne dans les filtres le groupe Xref puis enbas à gauche tu coche Inverser le filtre.
0

#3 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 10743
  • Inscrit(e) : 02-septembre 05

Posté 07 juillet 2014 - 12:39

Salut,

À ma connaissance, ça n'existe pas.
Mais tu peux choisir le filtre "Xref" et cocher "Inverser le filtre".
Sinon, il est facile de créer un filtre de propriétés "Sauf xref" avec une propriété "Nom" = "~*|*".
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#4 L'utilisateur est hors-ligne   sechanbask 

  • ceinture noire 2em dan
  • Groupe : Membres
  • Messages : 1012
  • Inscrit(e) : 06-octobre 06
  • LocationPoitiers

Posté 07 juillet 2014 - 13:22

merci (gile), je viens de reprendre mes gabarits pour utiliser ce filtre.
Je comprends pas pourquoi j'ai pas demandé avant, j'en avais tellement besoin !!
ATEN - Bureau d'Études Fluides
Image IPB
Exécution, Synthèse, Conception, Maîtrise d'Oeuvre, Audit, Chiffrage
www.atenbet.fr
0

#5 L'utilisateur est hors-ligne   nosset 

  • ceinture noire
  • Groupe : Membres
  • Messages : 475
  • Inscrit(e) : 06-septembre 12

Posté 07 juillet 2014 - 16:09

Par contre, Honte à Autodesk de ne pas ajouter une case à cocher ou autre pour retenir ce choix ou enregistrer une préférence quelconque car la première chose que l'on fait quand on ouvre un fichier, c'est; "ouverture des calques" "filtres xref" et "inverser le filtre" "OK".

Et ca gonfle !!!
0

#6 L'utilisateur est hors-ligne   La Lozère 

  • ceinture noire 4em dan
  • Groupe : Membres
  • Messages : 2285
  • Inscrit(e) : 28-juin 06
  • LocationVienne (38) - Etude APA - A480

Posté 07 juillet 2014 - 17:10

Salut,
En complément. Comme tu l'as remarqué, l'inversion de filtre n'est pas repris à l'ouverture du fichier. Ce qui est baloure.... Mais le filtre oui.

Du coup, la solution de (Gile) reste la meilleur solution.

A plus.
www.cad-is.fr
Autocad Map 2016/2018 - Covadis/Autopiste V16.0c - Mensura Genius V8
Nous n’héritons pas de la Terre de nos ancêtres, nous l’empruntons à nos enfants
0

#7 L'utilisateur est hors-ligne   x_all 

  • ceinture rouge et blanche 6em dan
  • Groupe : Membres
  • Messages : 3067
  • Inscrit(e) : 27-juin 06
  • Location04190

Posté 08 juillet 2014 - 06:24

c'est vrai que c'est grave lourd...
du coup, y aurait il un moyen d'automatiser la création de ce filtre. Du genre avoir un alias ou un bouton pour créer le filtre tout en masquant la visibilité des Xref..

Mais je voie pas trop comment, les option dans " -calque" ne donnent pas accès aux filtres
"La possibilité d'expliquer m'a toujours paru comme la seule excuse à l’existence de la parole"
JL Godard

quelques trucs sur autocad
0

#8 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 10743
  • Inscrit(e) : 02-septembre 05

Posté 08 juillet 2014 - 08:13

Salut,

Je crains que ça ne soit pas possible en macro mais les spécialistes (rebcao, si tu passes par là) me contrediront peut-être.

Les filtres de calques sont stockés dans des Xrecords (enrgistrements) dans le dictionnaire "ACAD_LAYERFILTERS", lui même stocké dans le dictionnaire d'extension de la table des calques.

Il est tout à fait possible de créer ce filtre en LISP.
Voici un exemple en pur AutoLISP (qui devrait donc aussi fonctionner sur AutoCAD MAC).

;; gc:GetOrCreateExtDict (gile)
;; Retourne le dictionnaire d'extension de l'entité
;; Le dictionnaire est créé s'il n'existe pas
;;
;; Argument : ent (ENAME)

(defun gc:GetOrCreateExtDict (ent / dict)
  (cond
    ((cdadr (member '(102 . "{ACAD_XDICTIONARY") (entget ent))))
    ((setq dict	(entmakex
		  '((0 . "DICTIONARY") (100 . "AcDbDictionary"))
		)
     )
     (entmod (append (entget ent)
		     (list '(102 . "{ACAD_XDICTIONARY")
			   (cons 360 dict)
			   '(102 . "}")
		     )
	     )
     )
     dict
    )
  )
)

;; gc:GetOrCreateDict
;; Retourne le ENAME du dictionnaire trouvé ou créé s'il n'exstait pas
;;
;; Arguments
;; dict : ENAME du dictionnaire parent
;; name : nom du dictionnaire à chercher ou créer

(defun gc:GetOrCreateDict (dict name)
  (if (snvalid name)
    (cond
      ((cdr (assoc -1 (dictsearch dict name))))
      ((dictadd	dict
		name
		(entmakex '((0 . "DICTIONARY") (100 . "AcDbDictionary")))
       )
      )
    )
  )
)

;; Commande : NoXrefFilter
;; Crée le filtre de calque "Sauf xref" s'il n'existe pas déjà

(defun c:NoXrefFilter (/ layerTable layerFilters)
  (setq	layerTable   (cdr (assoc 330 (entget (tblobjname "LAYER" "0"))))
	layerFilters (gc:GetOrCreateDict (gc:GetOrCreateExtDict layerTable) "ACAD_LAYERFILTERS")
  )
  (if (not (dictsearch layerFilters "Sauf xref"))
    (dictadd layerFilters
	     "Sauf xref"
	     (entmakex
	       '((0 . "XRECORD")
		 (100 . "AcDbXrecord")
		 (280 . 1)
		 (1 . "Sauf xref")
		 (1 . "~*|*")
		 (1 . "*")
		 (1 . "*")
		 (70 . 0)
		 (1 . "*")
		 (1 . "*")
		 (-3 ("ACAD" (1000 . "(NAME==\"~*|*\")")))
		)
	     )
    )
  )
  (princ)
)
(princ "\nEntrez : NOXREFFILTER pour lancer la commande")
(princ)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#9 L'utilisateur est hors-ligne   x_all 

  • ceinture rouge et blanche 6em dan
  • Groupe : Membres
  • Messages : 3067
  • Inscrit(e) : 27-juin 06
  • Location04190

Posté 08 juillet 2014 - 08:27

ENORME !!!

merci beaucoup
je le met dans ma valise de démarage auto :)
"La possibilité d'expliquer m'a toujours paru comme la seule excuse à l’existence de la parole"
JL Godard

quelques trucs sur autocad
0

#10 L'utilisateur est hors-ligne   nosset 

  • ceinture noire
  • Groupe : Membres
  • Messages : 475
  • Inscrit(e) : 06-septembre 12

Posté 08 juillet 2014 - 08:38

Pourquoi créer ce filtre alors qu'il existe. La seule différence est que celui qui existe les affiche, donc il faut l'inverser, alors que celui créé les masque.

Dans tout les cas à l'ouverture aucun des deux ne sera actif !
0

#11 L'utilisateur est hors-ligne   AnglesDroits 

  • ceinture verte
  • Groupe : Membres
  • Messages : 50
  • Inscrit(e) : 03-juin 14
  • LocationLyon

Posté 29 novembre 2017 - 14:07

Un p'tit mix entre les deux et surtout parce que je n'ai pas compris quoi faire avec "~*|*" Gile... On met le texte du nom de calque à la place de ~ ?

Je créé un filtre de groupe "Sans XRef" que je laisse vide.
Je fais un filtre des propriété avec inverser.
Je mets les calques du filtre des propriété dans le filtre de groupe.

Evidement, les mise à jour ne sont pas automatique donc c'est moyen. Ca passe sur un fichier avec peu d'évolution.
Mais c'est simple à retenir comme bidouille.
Dessin, Synthèse, Conseil, en Etude et Exécution.
0

#12 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 10743
  • Inscrit(e) : 02-septembre 05

Posté 29 novembre 2017 - 14:35

Voir le messageAnglesDroits, le 29 novembre 2017 - 14:07 , dit :

Un p'tit mix entre les deux et surtout parce que je n'ai pas compris quoi faire avec "~*|*" Gile... On met le texte du nom de calque à la place de ~ ?


"~*|*" est un modèle utilisant les caractères génériques qui signifie : toutes les chaînes qui ne contiennent pas de barre verticale (|).
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)