CADxp: cote d'angle supérieure à 180° - CADxp

Aller au contenu

  • 2 Pages +
  • 1
  • 2
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

cote d'angle supérieure à 180°

#1 L'utilisateur est hors-ligne   orionis 

  • ceinture bleue
  • Groupe : Membres
  • Messages : 104
  • Inscrit(e) : 16-avril 12
  • LocationDrôme

  Posté 28 mai 2014 - 08:50

Bonjour à tous,
je cherche à coter un angle supérieur à 180°, a priori ce n'est pas possible? Je me retrouve à chaque fois avec l'angle complémentaire.
Existe-t-il un moyen de contourner ce blocage?
0

#2 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 28 mai 2014 - 09:00

Salut,

À la première invite de la commande COTANG :
"Choix de l'arc, cercle, ligne ou <indiquez un sommet>: "
tu valides "indiquez un sommet" par Entrée, puis tu spécifies le sommet de l'angle, la première extrémité, la seconde et tu peux placer ta cote dans la zone de l'angle supérieure à 180°.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
1

#3 L'utilisateur est hors-ligne   Fundream 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 814
  • Inscrit(e) : 25-novembre 11

Posté 28 mai 2014 - 09:01

Il faut que tu selectionne les sommets de l'angle et non les lignes

EDIT : Grillé :angry:
Autocad 2015 - Lumion 3D - SCIA Engineer
I7 6700K 4 cores @4.0Ghz - 32Go DDR4 - GTX980ti 6Gb - SSD 512Go - Windows 7 64 bits.
0

#4 L'utilisateur est hors-ligne   rebcao 

  • ceinture rouge et blanche 8em dan
  • Groupe : Membres
  • Messages : 6951
  • Inscrit(e) : 25-août 04
  • LocationSELESTAT

  Posté 28 mai 2014 - 09:07

Bonjour,

Oui, il faut utiliser l'option <INDIQUER SOMMET> de la commande cote angulaire... tu fais simplement ENTREE.

Christian



Formateur, Consultant Expert AutoCAD, REVIT MEP, INVENTOR, télécharger des Supports de Cours AutoCAD, des Outils AutoCAD...
cad123 @ wanadoo.fr (enlever les espaces de part et d'autre de @)
1

#5 L'utilisateur est hors-ligne   orionis 

  • ceinture bleue
  • Groupe : Membres
  • Messages : 104
  • Inscrit(e) : 16-avril 12
  • LocationDrôme

Posté 28 mai 2014 - 09:08

Ah ben oui, ça marche!
Merci.
0

#6 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 14 février 2018 - 13:04

Bonjour à tous,
Est-il possible de faire apparaitre la cotation comme ceci ?
http://zupimages.net...=18/07/x7rw.jpg
Merci.
0

#7 L'utilisateur est hors-ligne   lili2006 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11858
  • Inscrit(e) : 21-décembre 05

Posté 14 février 2018 - 13:26

Bonjour à toutes et tous,

Oui ! Au lancement de la commande cotation angulaire, faire une entrée à vide pour pouvoir sélectionner le point, puis les branches,..

Commande: _dimangular
Choix de l'arc, cercle, ligne ou <indiquez un sommet>:
Indiquez le sommet de l'angle:
Indiquez la première extrémité de l'angle:
Indiquez la seconde extrémité de l'angle:
Indiquez la position de la dimension de l'arc de cote ou [textMult/TExte/Angle/Quadrant]:
Texte de cote = 180


Christian l'avais déjà écrit ici
AutoCAD MAP 3D 2019 - Covadis 17.0b
Forum : http://genie-civil.bbactif.com/
0

#8 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 20 février 2018 - 08:15

Bonjour à toutes et tous,
Merci Lili !
Quand on prend l'habitude d'utiliser une commande, on ne prend plus le temps de lire toutes les options proposées...
Une question cependant :
Serait il possible de coter les angles de la même façon, mais à la volée ?
- Cliquer sur l'axe 0°-180° (pour donner une base)
- Cliquer sur l'axe 22.5° [cela permet de trouver le sommet (axes concourants)]
- Déposer le texte manuellement en bout d'axe
- Cliquer sur l'axe suivant sans redonner la base 0°-180°, déposer le texte
- Cliquer sur l'axe suivant...
Faudrait il se tourner du côté LISP ?
Merci à vous.
0

#9 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 20 février 2018 - 08:30

Salut,

Je ne suis pas sûr de comprendre la demande.
Il me semble que s'il s'agit de reproduire l'image en lien, un bloc devrait faire l'affaire.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#10 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 20 février 2018 - 09:02

Bonjour,
En PJ un exemple de deux appareils complètement différents:
http://zupimages.net...=18/08/vewf.jpg
Sur le premier appareil, par exemple, il faut que je fasse 12x la même manipulation (cotation angulaire, indiquer un sommet, indiquer le sommet de l'angle, indiquer la 1iére extrémité de l'angle,...) pour arriver à coter tous les angles.
Les appareils sont toujours différents, mais la cotation suit toujours la même logique.
Merci pour votre aide.
0

#11 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 20 février 2018 - 09:51

OK, je te propose un petit LISP, il faut que dans le style de cote, la "Position du texte", case "Horizontal" soit sur : "Au dessus de la ligne d'attache 1".

(defun c:test (/ cen org pt)
  (if
    (and
      (setq cen (getpoint "\nSommet de l'angle: "))
      (setq org (getpoint cen "\nExtrémité de l'axe de base: "))
    )
     (progn
       (command "_.DIMANGULAR" "" "non" cen "non" org "non" org "non" org)
       (while (setq pt (getpoint cen "\nExtrémité de l'angle suivant: "))
         (command "_.DIMANGULAR" "" "non" cen  "non" pt "non" org "non" pt)
       )
     )
  )
  (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#12 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 20 février 2018 - 10:55

Merci Gile !
Quelques questions :
1- Sur mes plans, j'ai aussi de la cotation angulaire "traditionnelle", pour des détails de mécanique notamment (voir le lien), serait il possible de garder cette possibilité de cotation "traditionnelle" et aussi la cotation comme dans votre LISP ?
3- Serait il possible que la position des textes soit conforme au croquis "En final", c'est à dire centré et en bout de l'axe [sur le LISP, si j'essaie de le bouger par la suite, une fois la côte posée, le texte change d'angle (position)]?
2- Serait il possible d'avoir l'écriture des angles 0°-180° horizontale ?
http://zupimages.net...=18/08/jvlw.jpg
Merci encore pour votre aide.
0

#13 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 20 février 2018 - 12:53

1- Il suffit de définir deux styles de cotation.

2- 3- C'est plus compliqué en utilisant les cotations. Je te propose une solution avec juste des lignes et des textes.

(defun c:test (/ cen org dist ang0 ang pt)
  (if
    (and
      (setq cen (getpoint "\nCentre de la cotation: "))
      (setq org (getpoint cen "\nExtrémité de l'axe de base: "))
    )
     (progn
       (setq dist (distance cen org)
             ang0 (angle cen org))
       (command "_.line" "_non" cen "_non" org "")
       (command "_.text" "_justify" "_BC" "_non" org "" 0.0 "0°")
       
       (setq pt (polar cen (+ pi ang0) dist))
       (command "_.line" "_non" cen "_non" pt  "")
       (command "_.text" "_justify" "_TC" "_non" pt "" 0.0 "180°")
       
       (setq pt (polar cen (- ang0 (* 0.5 pi)) dist))
       (command "_.line" "_non" cen "_non" pt  "")
       (command "_.text" "_justify" "_ML" "_non" pt "" 0.0 "90°")
       
       (setq pt (polar cen (- ang0 (* 1.5 pi)) dist))
       (command "_.line" "_non" cen "_non" pt  "")
       (command "_.text" "_justify" "_MR" "_non" pt "" 0.0 "270°")
       
       (while (setq pt (getpoint cen "\nExtrémité de l'angle suivant: "))
         (setq ang (angle cen pt))
         (command "_.line" "_non" cen "_non" pt  "")
         (command "_.text"
                  "_justify"
                  "_ML"
                  "_non"
                  pt
                  ""
                  (angtos ang (getvar 'aunits) 16)
                  (strcat (angtos (- ang0 ang)) "°")
         )
       )
     )
  )
  (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#14 L'utilisateur est hors-ligne   DenisHen 

  • ceinture rouge et blanche 6em dan
  • Groupe : Membres
  • Messages : 3118
  • Inscrit(e) : 17-décembre 05
  • LocationSAINT FLORENTIN (Yonne)

Posté 20 février 2018 - 13:11

Salut à tous...

On n'est pas dans le forum AutoCAD LT 2013 ?
LinkedIn et mon site...
Windows 10 Pro 64bits / AutoCAD MAP 3D 2018.0.2
Covadis 16 / Microstation V8i

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres...
Davantage d'avantages, avantagent davantage. (Bobby Lapointe)
La connaissance s'accroît quand on la partage.(Socrate)
0

#15 L'utilisateur est en ligne   lecrabe 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8033
  • Inscrit(e) : 10-décembre 03
  • LocationLoire (42)

Posté 20 février 2018 - 13:23

Hello

YES Mr DenisHen !

Enfin un contributeur qui lit bien !

Néanmoins MERCI Gilles pour les Routines !!

Bye, lecrabe
Autodesk Expert Elite Team
0

#16 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 20 février 2018 - 13:30

C'est nicolas2 qui a déterré ce sujet et évoquer un LISP pour son problème.
Il aurait peut-être dû commencer un nouveau sujet, mais bon, c'est fait.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#17 L'utilisateur est hors-ligne   DenisHen 

  • ceinture rouge et blanche 6em dan
  • Groupe : Membres
  • Messages : 3118
  • Inscrit(e) : 17-décembre 05
  • LocationSAINT FLORENTIN (Yonne)

Posté 20 février 2018 - 13:47

Voir le messagelecrabe, le 20 février 2018 - 13:23 , dit :

YES Mr DenisHen !

Je disais ça car je ne comprenais pas ce que pouvait faire nicolas2 avec un LISP sous LT...

Voir le message(gile), le 20 février 2018 - 13:30 , dit :

C'est nicolas2 qui a déterré ce sujet et évoquer un LISP pour son problème.

Je ne t'incriminais nullement (gile)...

Ni nicolas2... errare humanum est, et je suis bien placé pour le savoir... ;)
LinkedIn et mon site...
Windows 10 Pro 64bits / AutoCAD MAP 3D 2018.0.2
Covadis 16 / Microstation V8i

Sur terre, il y a 10 types de personnes, celles qui comptent en binaire et les autres...
Davantage d'avantages, avantagent davantage. (Bobby Lapointe)
La connaissance s'accroît quand on la partage.(Socrate)
0

#18 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 20 février 2018 - 14:55

Je ne suis clairement pas dans le bon forum, milles excuses !
Merci Gile de prendre du temps pour mon problème.
http://zupimages.net...=18/08/jorb.jpg
- Serait il possible de modifier l'angle d'écriture au delà du 180° ?
- Serait il possible de ne pas écrire automatiquement 0°-90°-180°-270°, mais le gérer comme les autres écritures (à part le fait que l'écriture soit horizontale) ? En fait, si nous rajoutons un autre angle non prévu au départ (exemple 45°) et que nous relançons le LISP pour ce nouvel angle, le LISP va réécrire 0°-90°-180°-270° sur l'écriture déjà existante je crois (?)
Merci encore à vous.
0

#19 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11036
  • Inscrit(e) : 02-septembre 05

Posté 20 février 2018 - 17:02

Voilà une version plus aboutie.

(defun c:cotcirc (/ *error* space cen pt ang ht just rot text)
  (vl-load-com)
  (or *acdoc*
      (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
  )
  (defun *error* (msg)
    (and msg
         (/= msg "Fonction annulée")
         (prompt (strcat "\nErreur : " msg))
    )
    (vla-EndUndoMark *acdoc*)
    (princ)
  )
  (if (setq cen (getpoint "\nCentre de la cotation: "))
    (progn
      (vla-StartUndoMark *acdoc*)
      (setq space (vla-get-Block (vla-get-ActiveLayout *acdoc*)))
      (while (setq pt (getpoint cen "\nExtémité de l'angle: "))
        (setq pt (trans pt 1 0)
              cen (trans cen 1 0)
              ang (angle cen pt)
              ht (getvar 'textsize))
        (cond
          ((equal ang (* pi 0.5) 1e-9)
           (setq just acAlignmentBottomCenter
                 rot  0.0
           )
          )
          ((equal ang (* pi 1.5) 1e-9)
           (setq just acAlignmentTopCenter
                 rot  0.0
           )
          )
          ((< (* pi 0.5) ang (* pi 1.5))
           (setq just acAlignmentMiddleRight
                 rot  (+ pi ang)
           )
          )
          (T
           (setq just acAlignmentMiddleLeft
                 rot  ang
           )
          )
        )
        (vla-AddLine space (vlax-3d-point cen) (vlax-3d-point pt))
        (setq text (vla-AddText space (strcat (angtos (- (* 0.5 pi) ang)) "°") (vlax-3d-point pt) ht))
        (vla-put-Rotation text rot)
        (vla-put-Alignment text just)
        (vla-put-TextAlignmentPoint text (vlax-3d-point pt))
      )
    )
  )
  (*error* nil)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#20 L'utilisateur est hors-ligne   nicolas2 

  • ceinture marron
  • Groupe : Membres
  • Messages : 222
  • Inscrit(e) : 02-octobre 07
  • Locationchanas 38

Posté 20 février 2018 - 17:25

Merci Gile !
Une dernière petite demande si je peux me permettre :
Le même mais sans tracer les traits, uniquement l'écriture ?
0

Partager ce sujet :


  • 2 Pages +
  • 1
  • 2
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)