Aller au contenu

COUDE AVEC ATTRIBUT LISP


philou62640

Messages recommandés

  • 3 semaines après...

Bonjour

Je n'en sais rien , comment comptes-tu l' employer pour la mise en place des coudes, car il faut pouvoir maitriser les orientations 3D sinon ça fera un bloc différent pour chaque coude !

Et est-ce que tu as pu télécharger profil.lsp car je viens de voir ton message, en ce moment je ne suis pas souvent sur Cadxp.

Lien vers le commentaire
Partager sur d’autres sites

bonjour Usegomme

partir comme l'extrais de ton lisp suivant"

 

 

(defun c:cdt (/ lo ) ;; pour raccorder 2 axes et tracer un coude de tuy.

(diam-t3d)

(if (> epcalo 0)(creercalquecalo))

(setq mtrim (getvar "trimmode"))

(setvar "FILLETRAD" rayo) (setvar "trimmode" 1)

(setq lo (entlast))

(command "_fillet")

(while (not (zerop (getvar "cmdactive")))(command pause))

(cond

((not (equal lo (setq coude (entlast))))

(setq pt (trans (cdr (assoc 10 (entget coude))) 0 1))

(generetube coude pt 1)

)

)

(while (not (equal coude (setq lo (entlast))))

(command "_fillet")

(while (not (zerop (getvar "cmdactive")))(command pause))

(cond ((not (equal lo (setq coude (entlast))))

(setq pt (trans (cdr (assoc 10 (entget coude))) 0 1))

(generetube coude pt 1)

)

)

)

(setvar "trimmode" mtrim)

(princ)

)

le transformer en bloc avec attributs

 

 

Lien vers le commentaire
Partager sur d’autres sites

Salut

 

Voilà un premier jus pour les coudes en bloc, ça semble pas trop mal, il faut continuer à tester.

 

La commande "CDB" (CouDe Bloc) et le code sont intégrés à tuy.lsp

 

Le calo est toujours fonctionnel pour les coudes mais reste en solide 3d.

 

 

Edit : version 6.1

 


;; Tuyau 3d pour autocad à partir de la version 2007

;; et avec ou sans calorifuge

;; Usegomme   5-2-2007

;; commandes: TUY tuyau 3D, TSA tuyau sans axe, TU tube depuis axe, CDT coude seul et CD axe coude, CALOS seul depuis axe ou 2 points.

;; version 4  le 12-6-2011 ajout commande CDB  pour relier 2 lignes par un coude en bloc avec attributs (pas de coude emboité)

;; version 5  le 01-7-2011 ajout commande TUB  pour génèrer le tube en bloc avec attributs à partir de la ligne sélectionné

;; version 6  le 28-8-2011 ajout commande TUYCB et TSACB  = TUY ou TSA avec coudes en bloc et attributs

;; version 6.1 correction bug sur division par 45

;;; génère le tube en bloc à partir de l'axe sélectionné

(defun c:TUB (/ sel typent ent ent1 pt eptub lga px p1 atdia epc tub1 

        af ht it tsize aat1 att2 att3 att4 att5 att6 att7 att8 nle lda)

 (diam-t3d)

 (if (> epcalo 0)(creercalquecalo))

 (if (not tuy:ep) (setq tuy:ep 0))

 (initget "Epaisseur Matiere") 

 (while

   (setq sel (entsel (strcat "\nSélectionner l'AXE du TUBE ou [Epaisseur/Matiere] = "(rtos tuy:ep 2 4)" :"))) 

   (cond 

     ((= sel "Epaisseur")

       (setq eptub (getdist (strcat "\nEpaisseur tube ou 2 pts <" (rtos tuy:ep 2 4) ">: ")))

       (if eptub (if (< (abs eptub) ddia)(setq tuy:ep eptub)))

     )

     ((= sel "Matiere")(setq tuy:mat (getstring T "\n  Matière ?: ")))

     

     (t

       (setq typent (cdr (assoc 0 (entget (setq ent (car sel))))))

       (cond

         ((= typent "LINE")

          (setq lga (distance (cdr (assoc 10 (entget ent)))(cdr (assoc 11 (entget ent))))) ; longueur axe

   (setq pt (trans (cdr (assoc 10 (entget ent))) 0 1))	  

   (command "_ucs" "_non" pt "") (setq pt '(0. 0. 0.))

   (setq px (trans (cdr (assoc 11 (entget ent))) 0 1))

          (command "_ucs" "_non" pt "_non" px "") (setq p1 '(1. 0. 0.))


   ;; ajout calorifuge si présent

   (if (> epcalo 0) (progn (generetube ent pt nil)(entdel tub3d)))

          ;; suppression de l'axe si:

   (if (and (= 2 (getvar "DELOBJ"))(= 0 epcalo)) (entdel ent))


       ;;; nom du bloc

   (if (or (= tuy:ep nil) (<= tuy:ep 0.0))

           (setq nomb (strcat "TUBE" "_""DN" (rtos dn 2 0)   "_" norme ))

  

           (setq nomb (strcat "TUBE" "_""DN" (rtos dn 2 0)   "_" norme "_Ep_" 

           (rtos (fix tuy:ep) 2 0) (if (> tuy:ep (fix tuy:ep)) (strcat "_" (rtos (* 10 (- tuy:ep (fix tuy:ep))) 2 0)) "_0" ))   

           )

          )

       ;;; recherche bloc dans dessin

   (if (tblsearch "block"  nomb) 

           (progn

             ;;;; insertion bloc

             (setq atdia (getvar "attdia"))

             (setvar "attdia" 1)

             (command "._-insert" nomb "X" lga "Y" 1 "Z" 1 "_non" '(0. 0. 0.) "0" )

             (setvar "attdia" atdia)   

           )

           (progn

      ;;; création du solide

            (command "_line" "_non" pt "_non" p1 "")(setq ent1 (entlast))

            (if (> epcalo 0) (setq epc epcalo epcalo 0) (setq epc 0))

     (generetube ent1 pt nil) (setq tub1 (entlast))

     (if (> 2 (getvar "DELOBJ")) (entdel ent1))

     (if (> epc 0) (setq epcalo epc epc 0))


       ;; création attributs


            (setq st (getvar "textstyle"))

            (setvar "textstyle" "standard")

            (setq tsize (getvar "textsize"))   

            (setq af (getvar "aflags"))           

            (setq ht (* 0.07 ddia )) ; hauteur texte

            (setq it (* 1.3 ht))          ; intervale ligne texte

           

            (setvar "aflags" 9)  ;;; prédéfini et invisible

     

            (command "._-attdef" "" "POUCE" "POUCE" (if pouce pouce "")  "_non" '(0. 0. 0.)  ht "0")

            (setq att1 (entlast))

    

            (command "._-attdef" "" "DN" "DN" (rtos dn 2 0)  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(+ it ht))  ht "0")

            (setq att2 (entlast))

     

            (command "._-attdef" "" "NORME" "NORME" norme  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 2 (+ it ht)))  ht "0")

            (setq att3 (entlast))

     

            (command "._-attdef" "" "MATIERE" "MATIERE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 3 (+ it ht)))  ht "0")

            (setq att4 (entlast))

     

            (command "._-attdef" "" "EP" "EP" (if (or (= tuy:ep nil) (<= tuy:ep 0.0)) "" (rtos (abs tuy:ep) 2 1))

                                             "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 4 (+ it ht)))  ht "0")

            (setq att5 (entlast))

     

            (command "._-attdef" "" "LONG" "LONG" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 5 (+ it ht)))  ht "0")

            (setq att6 (entlast))

     

            (command "._-attdef" "" "FLUIDE" "FLUIDE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 6 (+ it ht)))  ht "0")

            (setq att7 (entlast))


     (command "._-attdef" "" "REPERE" "REPERE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 7 (+ it ht)))  ht "0")

            (setq att8 (entlast)) 


            ;;;; création bloc

            (command "._-block" nomb "_non" '(0. 0. 0.) att1 att2 att3 att4 att5 att6 att7 att8 tub3d "")

   

            ;;;; insertion bloc

            (setq atdia (getvar "attdia"))

            (setvar "attdia" 1)

     (command "._-insert" nomb "X" lga "Y" 1 "Z" 1 "_non" '(0. 0. 0.) "0" )

            (setvar "attdia" atdia)

    )

          )  ;;; (if (tblsearch "block"


          ;;; mise à jour attributs variables

     ;;;;;;;; matière ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     

     (cond  (tuy:mat

       (setq nle (entlast))  ; nom logique entité

       (while

    (and

            (/= (cdr (assoc 2 (setq lda (entget (setq nle (entnext nle)))))) "MATIERE")

     (/= "SEQEND" (cdr (assoc 0 lda)))

    )

       )

       (setq lda (subst (cons 1 tuy:mat) (assoc 1 lda) lda))  ;liste données attribut

       (entmod lda)

       (entupd nle)           ;attribut matiere mise à jour

 

     ))

     

      ;;;;;;; si épaisseur négative  , lorsqu' on ne veut pas qu'elle soit représentée.

     

     (cond  ((and tuy:ep (< tuy:ep 0))

       (setq nle (entlast))  ; nom logique entité

       (while

    (and

            (/= (cdr (assoc 2 (setq lda (entget (setq nle (entnext nle)))))) "EP")

     (/= "SEQEND" (cdr (assoc 0 lda)))

    )

       )

       (setq lda (subst (cons 1 (rtos (abs tuy:ep)2 1)) (assoc 1 lda) lda))  ;liste données attribut

       (entmod lda)

       (entupd nle)           ;attribut épaisseur mise à jour

 

     ))

     ;;;;;;;; longueur du tube ;;;;;;;;;;;; 

     (cond  (lga

       (setq nle (entlast))  ; nom logique entité

       (while

    (and

            (/= (cdr (assoc 2 (setq lda (entget (setq nle (entnext nle)))))) "LONG")

     (/= "SEQEND" (cdr (assoc 0 lda)))

    )

       )

       (setq lda (subst (cons 1 (rtos lga 2 2)) (assoc 1 lda) lda))  ;liste données attribut

       (entmod lda)

       (entupd nle)           ;attribut LONG mise à jour

 

     ))

     ;;;;;;;;;;;;;;;;;;;;;;;;;;;;

   


    (repeat 2 (command "_ucs" "_p")) 

   

         );;; = typent "LINE"

       ) ;; cond 

     )

  

   )  ;; cond

 ) ; w

 (gc)

 (princ)

)



;;  pour raccorder 2 axes et tracer un coude de tuy sauf emboitements, en bloc avec attributs 

(defun c:cdb (/ lo coude mtrim nomb sel s ok erreurcdb)

 

 (defun erreurcdb (msg)

  (if (not (zerop (getvar "cmdactive")))(command))

  (setq *error* er:cdb er:cdb nil)

  (princ)

 )

 (setq er:cdb *error* *error* erreurcdb)

 (diam-t3d)

 (if (> epcalo 0)(creercalquecalo))

 (setq mtrim (getvar "trimmode"))

 (setvar "FILLETRAD" rayo) (setvar "trimmode" 1)

 (setq coude T ok 0)    

 (while (and (= ok 0)(not (equal coude (setq lo (entlast)))))

   (command "_fillet")

   (while (< ok 2)                                                                        

    (setq s 0) (initget "Epaisseur Matiere")                                              

    (while (and (not (setq sel (entsel "\nSélectionnez l'Axe du tube  ou [Epaisseur/Matiere] :")))

	 (< s 0  ; <---- nombre de sélection manquée autorisée de 0 à n             ****************

                )) (setq s (1+ s))

    )

     (if sel

      (cond

 ((= sel "Epaisseur")

  (setq s 0) (if (not tuy:ep) (setq tuy:ep 0))

  (setq eptub (getdist (strcat "\nEpaisseur tube ou 2 pts <" (rtos tuy:ep 2 4) ">: ")))

  (if eptub (setq tuy:ep eptub))

  (while (>= (abs tuy:ep) ddia)

          (initget 1)

          (setq tuy:ep (getdist (strcat "\n*** Epaisseur "(rtos tuy:ep 2 4)" INCORRECTE *** Nouvelle Epaisseur : ")))

         )

 )

        ((= sel "Matiere")(setq s 0)(setq tuy:mat (getstring T "\n  Matière ?: "))) 

 ((or (= (cdr (assoc 0 (entget (car sel)))) "LINE")

      (= (cdr (assoc 0 (entget (car sel)))) "XLINE")

      (= (cdr (assoc 0 (entget (car sel)))) "RAY")

   )

   (setq ok (1+ ok))(command  sel)

 )

 (t (setq s 0)(prompt " LIGNE UNIQUEMENT")) 

      )

      (setq ok 3)

     )	

   ); w 2

   (cond

     ((and (< ok 3)(not (equal lo (setq coude (entlast))))) (setq ok 0) (coudbloc coude))

     (t (command))

   )

  ) ; w 1

 

 (setvar "trimmode" mtrim)

 (setq *error* er:cdb er:cdb nil)

 (princ)

 (princ nomb)

 (prin1)

)


(defun coudbloc (coude / pt acd atdia ht it tsize af st att1 att2 att3 att4 att5 att6 epc a50 a51 pt1scg pt2scg pt3scg ) 

 

 ;;pt1 pt2 pt3 avec tuycb , tsacb

 (cond

  ((and epemboit pt1 pt2 pt3) (setq pt1scg (trans pt1 1 0) pt2scg (trans pt2 1 0) pt3scg (trans pt3 1 0) acd (- 180 at))) 

  ((and pt1 pt2 pt3) (setq  acd (- 180 at)))

  


  (t  ;; pour cdb

    (if

      (> (setq a51 (* (cdr (assoc 51 (entget coude))) (/ 180 pi))) (setq a50 (* (cdr (assoc 50 (entget coude))) (/ 180 pi))))

       (setq acd (- a51 a50))

       (setq acd (+ (- 360 a50) a51))

    )

  )

 )

 

 (command "_ucs" "_E" coude)

 (setq pt (trans (cdr (assoc 10 (entget coude))) 0 1))

 (if (and epemboit pt1 pt2 pt3) (setq pt1 (trans pt1scg 0 1) pt2 (trans pt2scg 0 1) pt3 (trans pt3scg 0 1)))

     

 (if (or (= tuy:ep nil) (<= tuy:ep 0.0))

   (setq nomb (strcat "COUDE" "_" (rtos acd 2 2) "°"  "_""DN" (rtos dn 2 0)   "_" norme ))

  

   (setq nomb (strcat "COUDE" "_" (rtos acd 2 2) "°"  "_""DN" (rtos dn 2 0)   "_" norme "_Ep_" 

     (rtos (fix tuy:ep) 2 0) (if (> tuy:ep (fix tuy:ep)) (strcat "_" (rtos (* 10 (- tuy:ep (fix tuy:ep))) 2 0)) "_0" ))   

   )

  )


 ;; ajout calorifuge si présent

 (if (> epcalo 0) (progn (generetube coude pt 1) (entdel cd3d)))

  

 (if (tblsearch "block"  nomb) ;; recherche bloc dans dessin

    (progn

      ;;;; insertion bloc

      (setq atdia (getvar "attdia"))

      (setvar "attdia" 1)

      (command "._-insert" nomb "_non" '(0. 0. 0.) "" "" "0" )

      (setvar "attdia" atdia)

      

    )

    (progn

     (if (> epcalo 0) (setq epc epcalo epcalo 0) (setq epc 0))

     (generetube coude pt 1)

     (if (> epc 0) (setq epcalo epc epc 0))


     ;; création attributs


    (setq st (getvar "textstyle"))

    (setvar "textstyle" "standard")

    (setq tsize (getvar "textsize"))   

    (setq af (getvar "aflags"))           

    (setq ht (* 0.07 ddia )) ; hauteur texte

    (setq it (* 1.3 ht))          ; intervale ligne texte    tuy:ep


    (setvar "aflags" 9)  ;;; prédéfini et invisible

    (command "._-attdef" "" "TYPE" "TYPE" (strcat "COUDE" " " (rtos acd 2 2) "°")  "_non" '(0. 0. 0.)  ht "0")

    (setq att1 (entlast))

    (command "._-attdef" "" "DN" "DN" (rtos dn 2 0)  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(+ it ht))  ht "0")

    (setq att2 (entlast))

    (command "._-attdef" "" "NORME" "NORME" norme  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 2 (+ it ht)))  ht "0")

    (setq att3 (entlast))

    (command "._-attdef" "" "MATIERE" "MATIERE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 3 (+ it ht)))  ht "0")

    (setq att4 (entlast))

    (command "._-attdef" "" "EP" "EP" (if (or (= tuy:ep nil) (<= tuy:ep 0.0)) "" (rtos (abs tuy:ep) 2 1))

                                             "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 4 (+ it ht)))  ht "0")

    (setq att5 (entlast)) 

    (command "._-attdef" "" "FLUIDE" "FLUIDE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 5 (+ it ht)))  ht "0")

    (setq att6 (entlast))

    (command "._-attdef" "" "REPERE" "REPERE" ""  "_non" (polar '(0. 0. 0.)(* 1.5 pi)(* 6 (+ it ht)))  ht "0")

    (setq att7 (entlast))


     ;;;; creation bloc

    (command "._-block" nomb "_non" '(0. 0. 0.) att1 att2 att3 att4 att5 att6 att7 cd3d "")

     

    ;;;; insertion bloc

     (setq atdia (getvar "attdia"))

     (setvar "attdia" 1)

     (command "._-insert" nomb "_non" '(0. 0. 0.) "" "" "0" )

     (setvar "attdia" atdia)


     (setvar "aflags" af)

     (setvar "textsize" tsize )  

     (setvar "textstyle" st)


    )  ;;; progn

  )  ;;if

     

     ;;;;;;;; matière ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

     

     (cond  (tuy:mat

       (setq nle (entlast))  ; nom logique entité

       (while

    (and

            (/= (cdr (assoc 2 (setq lda (entget (setq nle (entnext nle)))))) "MATIERE")

     (/= "SEQEND" (cdr (assoc 0 lda)))

    )

       )

       (setq lda (subst (cons 1 tuy:mat) (assoc 1 lda) lda))  ;liste données attribut

       (entmod lda)

       (entupd nle)           ;attribut matiere mise à jour

 

     ))

     

 

      ;;;;;;; si épaisseur négative  , lorsqu' on ne veut pas qu'elle soit représentée.

     

     (cond  ((and tuy:ep (< tuy:ep 0))

       (setq nle (entlast))  ; nom logique entité

       (while

    (and

            (/= (cdr (assoc 2 (setq lda (entget (setq nle (entnext nle)))))) "EP")

     (/= "SEQEND" (cdr (assoc 0 lda)))

    )

       )

       (setq lda (subst (cons 1 (rtos (abs tuy:ep)2 1)) (assoc 1 lda) lda))  ;liste données attribut

       (entmod lda)

       (entupd nle)           ;attribut épaisseur mise à jour

 

     ))

     

(command "_ucs" "_p")

)



(defun choixnorme (/ sv_dm dm )

 (setq sv_dm (getvar "DYNMODE"))

 (cond ((< sv_dm 0) (setq dm (* sv_dm -1)) (setvar "DYNMODE" dm))

   (t (setq sv_dm nil dm nil))

 )

  (initget 1 "ISO3D ISO5D INOX-VIS 3000Lbs-VIS PE-PP-EMB PVC-PRESSION PVC-ECOUL CINTRE-SGN")   ;;;;   bit refus reponse nulle

   (setq norme (getkword "\nChoisir une Norme [iSO3D/ISO5D/INOX-VIS/3000Lbs-VIS/PE-PP-EMB/PVC-PRESSION/PVC-ECOUL/CINTRE-SGN] : "))

   

 (if sv_dm (setvar "DYNMODE" sv_dm))                                      

)


(Defun getDNtuy( a b d e f g / c) 

 ;(setq c (strcat  a d g "<" b ">" e f " "))

 ; (setq c (strcat  a d g "<" b ">" " "))

 (setq c (strcat  a g "<" b ">" " "))

 (setq c (getreal  c))

)


(defun diam-t3d (/ diam d B)  ;; dn  

 (setq dn "Norme" epcd 0 emboit 0 EPemboit nil L90 nil L45 nil L30 nil L20 nil ecart 0)

 (if (not norme) (setq norme "ISO3D"))  ;; par defaut

 (if (not epcalo)(setq epcalo 0))       ;; par defaut    

 (while (or(= dn "Norme")(= dn "Calo"))

   (if (> epcalo 0) (setq msgcalo " CALO ep" msgecalo (rtos epcalo 2 0))

     (setq msgcalo " Sans" msgecalo " calo")

   )

   (cond 

     ((= norme "ISO3D") (setq msgdn " DN:")

       (if

         (and (/= iso3d:dn "Autre")(/= iso3d:dn nil))

         (setq dn (rtos iso3d:dn 2 0)) (setq dn "Autre")                   

       ) 

       (setq choixdn

         (strcat "\n " norme msgcalo msgecalo msgdn "[Norme/Calo/8/10/15/21/20/25/32/40/50/65/80/100/125/150/200/250/300/350/400/450/500/600/Autre]")

       )                          

     )


     ((= norme "CINTRE-SGN") (setq msgdn " DN:")  

       (if

         (and (/= CINTRE-SGN:dn "Autre")(/= CINTRE-SGN:dn nil))

         (setq dn (rtos CINTRE-SGN:dn 2 0)) (setq dn "Autre")                   

       ) 

       (setq choixdn

         (strcat "\n " norme msgcalo msgecalo msgdn "[Norme/Calo/8/10/15/20/25/32/40/Autre]")

       )                          

     )

     

     ((= norme "ISO5D") (setq msgdn " DN:")

       (if

         (and (/= iso5d:dn "Autre")(/= iso5d:dn nil))

         (setq dn (rtos iso5d:dn 2 0))(setq dn "Autre")                   

       )  

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/20/25/32/40/50/65/80/100/125/150/200/250/300/350/Autre]")

       )                                       

     ) 

     

     ((= norme "INOX-VIS") (setq msgdn " DN:")

       (if

         (and (/= inox-vis:dn "Autre")(/= inox-vis:dn nil))

         (setq dn (rtos inox-vis:dn 2 0)) (setq dn (rtos 25 2 0) inox-vis:dn 25)                  

       ) 

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/6/8/10/15/20/25/32/40/50/65/80]")

       )                          

     )

     

     ((= norme "3000Lbs-VIS") (setq msgdn " DN:")

       (if

         (and (/= 3000Lbs-VIS:dn "Autre")(/= 3000Lbs-VIS:dn nil))

         (setq dn (rtos 3000Lbs-VIS:dn 2 0)) (setq dn (rtos 50 2 0) 3000Lbs-VIS:dn 50)                  

       ) 

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/6/8/10/15/20/25/32/40/50/65/80]")

       )                          

     )

     

     ((= norme "PE-PP-EMB") (setq msgdn " DN:")

       (if

         (and (/= PE-PP-EMB:dn "Autre")(/= PE-PP-EMB:dn nil))

         (setq dn (rtos PE-PP-EMB:dn 2 0)) (setq dn (rtos 50 2 0) PE-PP-EMB:dn 50)                  

       ) 

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/10/15/20/25/32/40/50/65/80/100]")

       )                          

     )

     

     ((= norme "PVC-PRESSION") (setq msgdn " Diam:")

       (if

         (and (/= PVC-P:dn "Autre")(/= PVC-P:dn nil))

         (setq dn (rtos PVC-P:dn 2 0)) (setq dn (rtos 50 2 0) PVC-P:dn 50)                   

       ) 

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/6/8/10/12/16/20/25/32/40/50/63/75/90/110/125/140/160/200/225/250]")

       )                          

     )

     

     ((= norme "PVC-ECOUL") (setq msgdn " Diam:")

       (if

         (and (/= PVC-ECOUL:dn "Autre")(/= PVC-ECOUL:dn nil))

         (setq dn (rtos PVC-ECOUL:dn 2 0)) (setq dn (rtos 40 2 0) PVC-ECOUL:dn 40)                   

       ) 

       (setq choixdn

         (strcat "\n " norme  msgcalo msgecalo msgdn "[Norme/Calo/32/40/50/63/75/80/90/100/110/125/140/160/200/250/315]")

       )                          

     )

   ) ;; fin cond

   

   (initget "Autre Norme Calo")

   (setq dn (getDNtuy choixdn dn norme  msgcalo msgecalo msgdn ))

   (if (= dn "Norme") (choixnorme))

   (if (= dn "Calo") 

     (if (setq epc (getdist (strcat "\nEpaisseur calo ou 2 pts <" (rtos epcalo 2 0) ">: ")))

       (setq epcalo epc epc nil)

     )

   )     

 ) ;; while dn= norme

 

 (cond

   ((= norme "ISO3D")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq iso3d:dn dn))

       ((= dn nil) (if iso3d:dn (setq dn iso3d:dn)))       

     )      

     (cond

       ((= dn 8) (setq diam 13.5  rayo 20 pouce "1/8"))

       ((= dn 10) (setq diam 17.2  rayo 25 pouce "1/4" ))

       ((= dn 15) (setq diam 21.3  rayo 28 pouce "1/2" )) ;27

       ((= dn 21) (setq diam 21.3  rayo 38 pouce "1/2" )) ; dn15 inox

       ((= dn 20) (setq diam 26.9  rayo 28.5 pouce "3/4")) 

       ((= dn 25) (setq diam 33.7 rayo 38 pouce "1")) 

       ((= dn 32) (setq diam 42.4  rayo 47.5 pouce "1 1/4")) 

       ((= dn 40) (setq diam 48.3 rayo 57 pouce "1 1/2"))

       ((= dn 50) (setq diam 60.3 rayo 76 pouce "2"))   

       ((= dn 65) (setq diam 76.1 rayo 95 pouce "2 1/2"))

       ((= dn 80) (setq diam 88.9 rayo 114.5 pouce "3"))

       ((= dn 100)(setq diam 114.3 rayo 152.5 pouce "4")) 

       ((= dn 125) (setq diam 139.7 rayo 190.5 pouce "5"))  

       ((= dn 150) (setq diam 168.3 rayo 228.5 pouce "6")) 

       ((= dn 200) (setq diam 219.1 rayo 305 pouce "8"))  

       ((= dn 250) (setq diam 273 rayo 381 pouce "10"))  

       ((= dn 300) (setq diam 323.9 rayo 457 pouce "12"))  

       ((= dn 350) (setq diam 355.6 rayo 533.5 pouce "14")) 

       ((= dn 400) (setq diam 406.4 rayo 609.5 pouce "16"))

       ((= dn 450) (setq diam 458 rayo 686 pouce "18"))

       ((= dn 500) (setq diam 508 rayo 762 pouce "20"))

       ((= dn 600) (setq diam 610 rayo 914 pouce "24")) 

       (t  (autrediametre) )

     )     

   )


((= norme "CINTRE-SGN")  ;;;; cintrage tube d'après un document SGN

     (cond

       ((and (/= dn "A") (/= dn nil))(setq CINTRE-SGN:dn dn))

       ((= dn nil) (if CINTRE-SGN:dn (setq dn CINTRE-SGN:dn)))       

     )      

     (cond

       ((= dn 8) (setq diam 13.5  rayo 70 ))

       ((= dn 10) (setq diam 17.2  rayo 90 ))

       ((= dn 15) (setq diam 21.3  rayo 110 )) 

       ((= dn 20) (setq diam 26.9  rayo 135)) 

       ((= dn 25) (setq diam 33.7 rayo 170)) 

       ((= dn 32) (setq diam 42.4  rayo 215)) 

       ((= dn 40) (setq diam 48.3 rayo 245))

        

       (t  (autrediametre) )

     )

     (setq ecart 110) ;;; longueur droite entre 2 courbes

   )

   

   ((= norme "ISO5D")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq iso5d:dn dn))

       ((= dn nil) (if iso5d:dn (setq dn iso5d:dn)))     

     )

     (cond

       ((= dn 20) (setq diam 26.9  rayo 57.5 pouce "3/4")) 

       ((= dn 25) (setq diam 33.7 rayo 72.5 pouce "1")) 

       ((= dn 32) (setq diam 42.4  rayo 92.5 pouce "1 1/4")) 

       ((= dn 40) (setq diam 48.3 rayo 109.5 pouce "1 1/2")) 

       ((= dn 50) (setq diam 60.3 rayo 137.5 pouce "2"))   

       ((= dn 65) (setq diam 76.1 rayo 175 pouce "2 1/2")) 

       ((= dn 80) (setq diam 88.9 rayo 207.5 pouce "3")) 

       ((= dn 100) (setq diam 114.3 rayo 270 pouce "4")) 

       ((= dn 125) (setq diam 139.7 rayo 330 pouce "5"))  

       ((= dn 150) (setq diam 168.3 rayo 390 pouce "6")) 

       ((= dn 200) (setq diam 219.1 rayo 515 pouce "8"))  

       ((= dn 250) (setq diam 273 rayo 650 pouce "10"))  

       ((= dn 300) (setq diam 323.9 rayo 770 pouce "12"))  

       ((= dn 350) (setq diam 355.6 rayo 850 pouce "14")) 

       (t  (autrediametre) )

     )   

   )

   

   ((= norme "INOX-VIS")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq inox-vis:dn dn))

       ((= dn nil) (if inox-vis:dn (setq dn inox-vis:dn)))       

     )      

     (cond  ;; d diametre ext coude

       ((= dn 6) (setq diam 10.2  L90 19 d 14.5))

       ((= dn 8) (setq diam 13.5  L90 21 d 17.5))

       ((= dn 10) (setq diam 17.2  L90 25 d 21.5))

       ((= dn 15) (setq diam 21.3  L90 28 d 27))

       ((= dn 20) (setq diam 26.9  L90 33 d 33.5)) 

       ((= dn 25) (setq diam 33.7 L90 38 d 40.5)) 

       ((= dn 32) (setq diam 42.4  L90 45 d 50)) 

       ((= dn 40) (setq diam 48.3 L90 50 d 57))

       ((= dn 50) (setq diam 60.3 L90 58 d 70))   

       ((= dn 65) (setq diam 76.1 L90 75 d 86))

       ((= dn 80) (setq diam 88.9 L90 85 d 100))   

       (t  (autrediametre) )

     )  

     (setq epcd (* (- d diam) 0.5))  ; epaisseur coude

     (setq rayo (+ (* diam 0.5) epcd 1) emboit (- l90 rayo) epemboit epcd)   

   )  

   

   ((= norme "3000Lbs-VIS")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq 3000Lbs-VIS:dn dn))

       ((= dn nil) (if 3000Lbs-VIS:dn (setq dn 3000Lbs-VIS:dn)))       

     )      

     (cond  ;;;; b = diametre "manchon"

       ((= dn 8) (setq diam 13.5  L90 24.5 l45 22 b 26.5))

       ((= dn 10) (setq diam 17.2  L90 28.5 l45 22 b 34))

       ((= dn 15) (setq diam 21.3  L90 33.5 l45 25 b 38.5))

       ((= dn 20) (setq diam 26.9  L90 38 l45 28.5 b 46.5)) 

       ((= dn 25) (setq diam 33.7 L90 44.5 l45 33.5 b 56.5)) 

       ((= dn 32) (setq diam 42.4  L90 51 l45 38 b 62.5)) 

       ((= dn 40) (setq diam 48.3 L90 60.5 l45 41.5 b 76))

       ((= dn 50) (setq diam 60.3 L90 63.5 l45 50.5 b 92))   

       ((= dn 65) (setq diam 76.1 L90 82.5 l45 63.5 b 110))

       ((= dn 80) (setq diam 88.9 L90 95.5 l45 63.5 b 122)) 

       ((= dn 100)(setq diam 114.3 L90 114.5 l45 80 b 152))  

       (t  (autrediametre) )

     ) 

     

     (setq epcd (* (- b diam) 0.25)) ;; ep coude = moitie epaisseur manchon ?..

     (setq rayo (+ (* diam 0.5) epcd 1) emboit (- l90 rayo) epemboit (* 2 epcd))     

   )    

   

   ((= norme "PE-PP-EMB") 

     (cond

       ((and (/= dn "A") (/= dn nil))(setq PE-PP-EMB:dn dn))

       ((= dn nil) (if PE-PP-EMB:dn (setq dn PE-PP-EMB:dn)))       

     )      

     (cond  ;;;; d= diametre ext coudes

       ((= dn 10) (setq diam 16 L90 25 L45 20 d 26))

       ((= dn 15) (setq diam 20 L90 28 L45 21 d 30.5))

       ((= dn 20) (setq diam 25 L90 32 L45 24 d 36))

       ((= dn 25) (setq diam 32 L90 38 L45 28 d 43.5))

       ((= dn 32) (setq diam 40 L90 44 L45 33 d 53.5)) 

       ((= dn 40) (setq diam 50 L90 51 L45 36 d 66)) 

       ((= dn 50) (setq diam 63 L90 62 L45 43 d 82)) 

       ((= dn 65) (setq diam 75 L90 75.5 L45 51 d 92.5))

       ((= dn 80) (setq diam 90 L90 88 L45 58 d 110))   

       ((= dn 100) (setq diam 110 L90 106 L45 68 d 134))          

       (t  (autrediametre) )

     ) 

     (setq epcd (* (- d diam) 0.5))  ; ep coude

     (setq rayo (+ (* diam 0.5) epcd 1) emboit (- l90 rayo) epemboit epcd ecart 5)    

   )

   

   ((= norme "PVC-PRESSION")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq PVC-P:dn dn))

       ((= dn nil) (if PVC-P:dn (setq dn PVC-P:dn)))       

     )      

     (cond  ;;;; D diam ext coude

       ((= dn 6) (setq diam dn L90 16 D 11))

       ((= dn 8) (setq diam dn L90 17 D 13))

       ((= dn 10) (setq diam dn L90 18 D 14))

       ((= dn 12) (setq diam dn L90 19 D 17)) 

       ((= dn 16) (setq diam dn L90 23 L45 18.5 D 21))

       ((= dn 20) (setq diam dn L90 27 L45 21 D 25))

       ((= dn 25) (setq diam dn L90 33 L45 25 D 30.5))

       ((= dn 32) (setq diam dn L90 39 L45 30 D 38.2))

       ((= dn 40) (setq diam dn L90 49 L45 36 D 47.2)) 

       ((= dn 50) (setq diam dn L90 57 L45 42.5 D 58.5)) 

       ((= dn 63) (setq diam dn L90 71 L45 52 D 73.4)) 

       ((= dn 75) (setq diam dn L90 83 L45 60.5 D 87.2))

       ((= dn 90) (setq diam dn L90 97 L45 70.5 D 105))   

       ((= dn 110) (setq diam dn L90 116 L45 86 D 127)) 

       ((= dn 125) (setq diam dn L90 172 L45 97 D 146.2))

       ((= dn 140) (setq diam dn L90 146 L45 108 D 162))

       ((= dn 160) (setq diam dn L90 166 L45 122 D 185))         

       ((= dn 200) (setq diam dn L90 207 L45 149 D 225.2))                 

       ((= dn 225) (setq diam dn L90 233 L45 168 D 250))                          

       ((= dn 250) (setq diam dn L90 263 L45 191.5 D 282))                                   

       (t  (autrediametre) )

     )  

     (setq epcd (* (- d diam) 0.5)) ;; ep coude

     (setq rayo (+ (* diam 0.5) epcd 1) emboit (- L90 rayo) epemboit epcd ecart 5)     

   ) 

   

  ((= norme "PVC-ECOUL")

     (cond

       ((and (/= dn "A") (/= dn nil))(setq PVC-ECOUL:dn dn))

       ((= dn nil) (if PVC-ECOUL:dn (setq dn PVC-ECOUL:dn)))       

     )      

     (cond  ;;;; L87 longueur pour coude 87.5°

       ((= dn 32) (setq diam dn L87 48 L45 34 emboit 23))  ;; +3

       ((= dn 40) (setq diam dn L87 58 L45 40 L30 38 L20 33.5 emboit 27)) 

       ((= dn 50) (setq diam dn L87 71 L45 49 emboit 32))

       ((= dn 63) (setq diam dn L87 86.5 L45 59.5 emboit 38.5))

       ((= dn 75) (setq diam dn L87 101.5 L45 69.5 emboit 44.5))

((= dn 80) (setq diam dn L87 108 L45 73.5 emboit 47))

       ((= dn 90) (setq diam dn L87 121 L45 82 emboit 52))

       ((= dn 100) (setq diam dn L87 134 L45 90 emboit 61))

       ((= dn 110) (setq diam dn L87 145 L45 97 emboit 61))

       ((= dn 125) (setq diam dn L87 157 L45 102 emboit 61))

((= dn 140) (setq diam dn L87 168 L45 107 emboit 61))

((= dn 160) (setq diam dn L87 183 L45 114 emboit 61))

((= dn 200) (setq diam dn L87 214 L45 127 emboit 61))

((= dn 250) (setq diam dn L87 225 L45 145 emboit 61))

((= dn 315) (setq diam dn L87 309 L45 210 emboit 124))

       (t  (autrediametre) )

     )  

     (setq L90 (/ (- (* L87 45)(* L45 2.5)) 42.5)) ;; 90-87.5=2.5 et 45-2.5=42.5

     (setq rayo (- L90 emboit) epemboit 2 epcd 0 ecart 5)

     ;;; ecart = ecartement mini entre 2 embouts de coude

   )       

   

 ) ; fin cond dn suivant norme

 (setq ddia (/ diam 2))

 (if (not (> rayo (+ ddia epcd))) (setq rayo (* (+ ddia epcd) 1.01)))

 (if tuy:ep

  (while (>= (abs tuy:ep) ddia)

   (initget 1)

   (setq tuy:ep (getdist (strcat "\n*** Epaisseur "(rtos tuy:ep 2 4)" INCORRECTE *** Nouvelle Epaisseur : ")))

  )

 )  

)


(defun autrediametre ()

 (setq epcd 0)

 (if (not tuy:dia)(if ddia (setq tuy:dia (* ddia 2))(setq tuy:dia 8)))   

 (setq diam (getdist (strcat "\nDiametre Exterieur Tuyauterie ou 2 pts <" (rtos tuy:dia 2 4) ">: ")))

 (if diam (setq tuy:dia diam) (setq diam tuy:dia))

 (if (not tuy:ray)(setq tuy:ray diam))

 (setq rayo (getdist (strcat "\nRayon coude ou 2 pts <" (rtos tuy:ray 2 4) ">: ")))

 (if rayo (setq tuy:ray rayo) (setq rayo tuy:ray))

) 


(defun tubage (ent typ / lent)   

 ;change proprietes de l'axe

 (setq lent (entget ent))

 ;; si le code 62 pour la couleur est présent ...

 (if (assoc 62 lent)

   ;; ... le remplacer par un nouveau

   (setq lent (subst (cons 62 6)  ;;Nouvelle couleur  magenta

     (assoc 62 lent) lent)    

   )

   ;; sinon, en ajouter un

   (setq lent (append lent (list (cons 62 6))))  ;; magenta

 ) 

 ;; idem pour type de ligne

 (if (assoc 6 lent)

   (setq lent (subst (cons 6 "AXES2")  

     (assoc 62 lent) lent)    

   )

   (setq lent (append lent (list (cons 6 "AXES2"))))  

 ) 

 

 (entmod lent)

 (setq pt (trans (cdr (assoc 10 (entget ent))) 0 1))

 

 ;; modification pour tuyb

 (cond

   ((and (= cdblc 1) (= typ 1)) (coudbloc ent))  

   (t (generetube ent pt typ))

 )

)


(defun tubage1 (ent typ / lent) ;;; N'EST PAS UTILISE

 ;change le calque de l'axe

 ; (setq calqax (strcat (getvar "clayer") "-AXE")) ; defini dans c:tuy

 (setq lent (entget ent))

 ; change le calque

 (setq lent (subst (cons 8 calqax)  

   (assoc 8 lent) lent)    

 )

 (entmod lent)  

 (setq pt (trans (cdr (assoc 10 (entget ent))) 0 1))

 (generetube ent pt typ)

)


(defun generetube (ent pt typ / circonftuy)  

 (if (or (= tuy:ep nil) (<= tuy:ep 0.0))

   (progn

     (command "_circle" "_none" pt)

     (if (= typ 1) (command (+ ddia epcd)) (command ddia))

     (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

     (command "_sweep" "_L" "" ent)  ;; balayage

     (if (= typ 1) (setq cd3d (entlast) tub3d nil)(setq cd3d nil tub3d (entlast)))

     (if circonftuy (entdel circonftuy))

     (if (> epcalo 0) (progn (if (= 2 (getvar "delobj"))(entdel ent))

         (if (= (cdr (assoc 0 (setq lent (entget ent)))) "ARC")

           (if (> (cdr (assoc 40 lent)) (+ ddia epcalo))

             (if (< tuy:ep 0.0)(calocreux ent pt)(caloplein ent pt))

           )

           (if (< tuy:ep 0.0)(calocreux ent pt)(caloplein ent pt))

         )        

       )

     ) 

   ) 

   (progn

     (command "_circle" "_none" pt)

     (if (= typ 1) (command (+ ddia epcd)) (command ddia))     

     (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

     (command "_sweep" "_L" "" ent)

     (if (= 2 (getvar "delobj"))(entdel ent))

     (if circonftuy (entdel circonftuy))

     (setq tubext (entlast))

     (command "_circle" "_none" pt (- ddia tuy:ep))

     (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

     (command "_sweep" "_L" "" ent)

     (if circonftuy (entdel circonftuy))

     (command "_subtract" tubext "" "_L" "")

     (if (= typ 1) (setq cd3d (entlast) tub3d nil)(setq cd3d nil tub3d (entlast)))

     (if (> epcalo 0) (progn (if (= 2 (getvar "delobj"))(entdel ent))

         (if (= (cdr (assoc 0 (setq lent (entget ent)))) "ARC")

           (if (> (cdr (assoc 40 lent)) (+ ddia epcalo))(calocreux ent pt))

           (calocreux ent pt)

         )        

       )

     )           

   )

 )

 

 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; embcdf ; embout coude femelle

 (if (and cd3d epemboit pt1 pt2 pt3) (embcdf))

)


(defun embcdf (/ lgt ptn ent circonftuy tubext cd3)                 

 (setq lgt (+ dmin emboit))

 (redefsommet pt2 pt1 lgt)

 (setq ptn sbn)

 (redefsommet ptn pt2 emboit)

 (command "_line" "_none" ptn "_none" sbn "")

 (setq ent (entlast))

 (command "_circle" "_none" sbn)

 (command (+ ddia epemboit))    

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent)  

 (if (= 2 (getvar "delobj"))(entdel ent))  

 (if circonftuy (entdel circonftuy))

 (setq tubext (entlast))

 (command "_circle" "_none" sbn ddia)

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent) 

 (if (/= 2 (getvar "delobj"))(entdel ent))

 (if circonftuy (entdel circonftuy))

 (command "_subtract" tubext "" "_L" "")

 (command "_.union" cd3d (entlast) "")

 (setq cd3 (entlast))

 (redefsommet pt2 pt3 lgt)

 (setq ptn sbn)

 (redefsommet ptn pt2 emboit)

 (command "_line" "_none" ptn "_none" sbn "")

 (setq ent (entlast))

 (command "_circle" "_none" sbn)

 (command (+ ddia epemboit))    

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent)  

 (if (= 2 (getvar "delobj"))(entdel ent))  

 (if circonftuy (entdel circonftuy))

 (setq tubext (entlast))

 (command "_circle" "_none" sbn ddia)

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent) 

 (if (/= 2 (getvar "delobj"))(entdel ent))

 (if circonftuy (entdel circonftuy))

 (command "_subtract" tubext "" "_L" "")

 (command "_.union" cd3 (entlast) "")

)



(defun caloplein (ent pt / circonftuy lent)

 (command "_circle" "_none" pt(+ ddia epcalo))

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent)  ;; balayage

 (if circonftuy (entdel circonftuy))

 (setq lent (entget (entlast)))  ; calo

 (setq lent (subst (cons 8 calqcalo)   

     (assoc 8 lent) lent)    

   )

 (entmod lent)

)


(defun calocreux (ent pt / circonftuy lent)

 (command "_circle" "_none" pt(+ ddia epcalo))

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent)  ;; balayage 

 (if (= 2 (getvar "delobj"))(entdel ent))

 (if circonftuy (entdel circonftuy))

 (setq tubext (entlast))

 (command "_circle" "_none" pt ddia) 

 (if (= 0 (getvar "delobj"))(setq circonftuy (entlast))(setq circonftuy nil))

 (command "_sweep" "_L" "" ent)

 (if circonftuy (entdel circonftuy))

 (command "_subtract" tubext "" "_L" "")

 (setq lent (entget (entlast)))   ; calo

 (setq lent (subst (cons 8 calqcalo)   

     (assoc 8 lent) lent)    

   )

 (entmod lent)

)



(defun descoude ( L1 L2 pt long)

 (command "_fillet" L1 L2)

 (setq coude (entlast))

 (if (or del1 (if dminp (= (- long dminp) dmin) (= long dmin)))

   (entdel L1) (tubage L1 lg)

 )

 (setq del1 nil)

 (tubage coude cd)

)


(defun deterdmin ( / a a90 p)        ;; determine la distance mini pour placer un coude

 (cond  ;; restauration rayon original

   ((and l90 l45 epemboit) (setq rayo (- l90 emboit)) (setvar "FILLETRAD" rayo))

 )  

 

 (if dmin (setq dminp dmin))                              ;;; dminp = dmin du coude precedent

 (if (= b (+ d01 d10)) (setq a180 t) (setq a180 nil))      ;; si angle 180 pas de coude mais prolongement

 (if (or (= d01 (+ b d10)) (= d10 (+ b d01)))

   (setq a0 t) (setq a0 nil)                               ;; si angle 0   pas possible  alors arret

 )

 (if (= (* b B) (+ (* d01 d01) (* d10 d10)))                ;; si angle 90  dmin = rayon

   (setq a90 t dmin rayo) (setq a90 nil)

 )

 (if (and (not a0) (not a90)(not a180))                       ;;; si autre alors calcul

   (progn 

     (setq p (/ (+ d01 d10 B) 2))   ;;; p=1/2 perimetre du triangle

     (setq a (abs (atan (sqrt (/ (* (- p d01)(- p d10)) (* p (- p B)))))))  ;; 1/2 angle

     (setq at (* 2 (* a (/ 180 pi))))   ;; angle tuyauterie

     (cond

((and l45 l20 epemboit (> at 150)) 

         (setq dmin (- (- l45 emboit)  (* (/ (- (- l45 emboit)(- l20 emboit)) 25)(- at 135))))

         (setq rayo (/ (* (sin a) dmin) (cos a))) 

  (if (not (> rayo (+ ddia epemboit)))

    (setq rayo (* (+ ddia epemboit) 1.01)

                 dmin (* (cos a) (/ rayo (sin a)))	  

           )

  )

 (setvar "FILLETRAD" rayo)

       )

((and l45 l30 epemboit (> at 136))

         (setq dmin (- (- l45 emboit)  (* (/ (- (- l45 emboit)(- l30 emboit)) 15)(- at 135))))

         (setq rayo (/ (* (sin a) dmin) (cos a))) 

  (if (not (> rayo (+ ddia epemboit)))

    (setq rayo (* (+ ddia epemboit) 1.01)

                 dmin (* (cos a) (/ rayo (sin a)))	  

           )

  )

 (setvar "FILLETRAD" rayo)

       )

       ((and l90 l45 epemboit (> at 90))

         (setq dmin (- (- l90 emboit)  (* (* (- (- l90 emboit)(- l45 emboit)) 0.022222)(- at 90))))

         (setq rayo (/ (* (sin a) dmin) (cos a))) 

  (if (not (> rayo (+ ddia epemboit)))

    (setq rayo (* (+ ddia epemboit) 1.01)

                 dmin (* (cos a) (/ rayo (sin a)))	  

           )

  )

 (setvar "FILLETRAD" rayo)

       )

       (t (setq dmin (* (cos a) (/ rayo (sin a))))) 

     )

   )

 )

 (if a90 (setq at 90.0)) 

 (if a180 (setq at 180.0))                                        

)


(defun onfekoi (L1 L2 pt1 pt2 pt3 d1 d2)

 (cond

   (a180 (tubage L1 lg))

   (a0 (tubage L1 lg) (entdel L2) (setq p0 nil p1 nil))

   ((and (not a0) (not a180))

     (if (> rayo 0)

       (cond

         ((and (if dminp (>= (- d1 dminp) (+ dmin (* 2 emboit) ecart)) (>= d1 dmin)) (>= d2 dmin) )

           (descoude L1 L2 pt2 d1)            

         )

         ((or (if dminp (< (- d1 dminp) (+ dmin (* 2 emboit) ecart)) (< d1 dmin))

             (< d2 dmin)

           )

           (correction L1 L2 pt1 pt2 pt3 d1 d2)  

         )

       )        

       (tubage L1 lg)  ;;;  si rayon 0    pas de raccordement

     )

   )

 )

)


(defun correction (L1 L2 pt1 pt2 pt3 d1 d2)  

 (setq lg (if dminp (+ dmin dminp (* 2 emboit) ecart) dmin))

 (if (< d1 lg)

   (progn          

     (setq pt1 (trans (cdr (assoc 10 (entget L1))) 0 1))

     (if dminp (setq lgmin (+ dmin (* 2 emboit) ecart))(setq lgmin dmin))

     (redefsommet pt1 pt2 lgmin)   

     (entdel L1)

     (command "_line" "_non" pt1 "_non" sbn "")

     (setq L1 (entlast))

     (command "_move" L2 "" "_non" pt2 "_non" sbn)

     (setq pt2 sbn)

     (if (and (= emboit 0)(= ecart 0))(setq del1 t))

   )    ;;; progn

 )  ;;; if

 (cond

   ((> d2 dmin)        

     (setq pt3 (trans (cdr (assoc 11 (entget L2))) 0 1))

     (if (= dp t) (setq p1 pt3 p0 pt2) (setq p0 pt3 p1 pt2) )

     (descoude L1 L2 pt2 lg)  ;; pas modif ok

   )

   ((= d2 dmin)

     (descoude L1 L2 pt2 lg)  

     (entdel L2)

     (setq p0 nil p1 nil)     ;;; arret sur coude 

   )

   ((< d2 dmin)           ;; modification L2 

     (if (< d1 lg)

       (progn

         (setq pt2 sbn)

         (setq pt3 (trans (cdr (assoc 11 (entget L2))) 0 1))

         (setq d1 lg)

       )

     )

     (redefsommet pt2 pt3 dmin)        

     (command "_move" L2 "" "_non" pt3 "_non" sbn)

     (descoude L1 L2 pt2 d1)    

     (entdel L2)

     (setq p0 nil p1 nil)     ;;; arret sur coude      

   )

 )

)


(defun redefsommet (sa sb dist / h a ab za zb z y x b bn hn ap psbn)

 (setq h (- (caddr sb)(caddr sa)))         ;;; hauteur triangle

 (if (= h 0.0)   ;; si parallele plan xy

   (progn

     (setq a (angle sa sb))

     (setq sbn (polar sa a dist))

   )

   ;; si vertical suivant axe Z

   (if (and (= (rtos (car sa) 2 1) (rtos (car sb) 2 1)) ;; probleme de precision avec deplacement ligne

       (= (rtos (cadr sa) 2 1) (rtos (cadr sb) 2 1))

     )

     (progn

       (setq za (caddr sa) zb (caddr sb))

       (if (> za zb)

         (setq z (- za dist))

         (setq z (+ za dist))

       )

       (setq x (car sa) y (cadr sa))

       (setq sbn (list x y z))                      ;;; nouv sommet b

     )

     ;; orientation quelconque

     (progn

       (setq ab (distance sa sb))    

       (setq b (sqrt (- (* ab ab) (* h h))))    ;;; base triangle

       (setq hn (/ (* h dist) ab))                  ;;; nouvelle hauteur

       (setq bn (/ (* b dist) ab))                  ;;; nouvelle base

       (setq ap (angle sa sb))                  ;;; angle projeté de ab

       (setq psbn (polar sa ap bn))          ;;; projection nouv sommet b

       (setq z (+ (caddr sa) hn))               ;;; z nouv pb

       (setq x (car psbn))

       (setq y (cadr psbn))

       (setq sbn (list x y z))                      ;;; nouv sommet b

     )      

   ) 

 )

)



(defun creercalqueAXE (/ calqax)   ;;; pas utilisé

 ;creer calque de l'axe

 (setq calqax (strcat (getvar "clayer") "-AXE"))

 (if (not (tblsearch "layer" calqax))

   ; (command "_-layer" "_n" calqax "" "" )

   (command "_-layer" "_n" calqax "_co" "6" calqax "_lt" "axes2" calqax "")

 )

)

(defun creercalqueCALO ();creer calque pour calorifuge

 (setq calqcalo (strcat (getvar "clayer") "-CALO"))

 (if (not (tblsearch "layer" calqcalo))

   ; s'il n'existe pas le calque est créé avec la couleur 9

   (command "_-layer" "_n" calqcalo "_co" "9" calqcalo "")

 )

)


(defun TUY (/ p0 p1 L01 L10 coude mtrim ent eptub at) 

 (setvar "cmdecho" 0)     

  (diam-t3d)

 (setq p1 nil dmin nil dminp nil L10 nil del1 nil cd 1 lg 0)

 ;(creercalqueaxe ) pas utilisé

 (if (not (tblsearch "ltype" "axes2")) (command "_-linetype" "_l" "AXES2" "" ""))

 (if (> epcalo 0)(creercalquecalo))

 

 (setvar "FILLETRAD" rayo) (setq mtrim (getvar "trimmode"))(setvar "trimmode" 1)                       

 (if (not tuy:ep) (setq tuy:ep 0))

 (setq p0 "Epaisseur")

 (while (= p0 "Epaisseur")

   (initget "Epaisseur")

   (setq p0 (getpoint (strcat "\nPOINT DE DEPART ou <Epaisseur> = "(rtos tuy:ep 2 4)"  :")))

   (if (not p0) (setq p0 "Epaisseur"))

   (if (= p0 "Epaisseur")

     (progn

       (setq eptub (getdist (strcat "\nEpaisseur tube ou 2 pts <" (rtos tuy:ep 2 4) ">: ")))

       (if eptub (if (< (abs eptub) ddia)(setq tuy:ep eptub)))

     ) 

   )

 )

 

 (while p0  

   (if p1  (setq pd p1))                                     ;;; pd  point de depart

   (cond (at (princ "Angle tuyauterie ")(princ at)(princ "°")

          (princ " et Coude ")(princ (- 180 at))(princ "°")

         )    

   )

   (princ " Rayon ")(princ rayo)

   (setq p1 (getpoint p0 "\nPoint suivant <Arret> : ")) 

   (if p1

     (progn

       (command "_line" "_non" p0 "_non" p1 "")

       (setq L01 (entlast) d01 (distance p0 p1) dp t)       ;;;  dp = dernier point p1

       

       (if l10      ;;; si plusieurs boucles ;;;;;;;

         (progn

           (setq b (distance p1 pd))                         ;;; b  base triangle

           (deterdmin) 

           (onfekoi L10 L01 pd p0 p1 d10 d01)           

         )

       ) 

       (if p0 (setq pd p0))

       (cond (at (princ "Angle tuyauterie ")(princ at)(princ "°")

           (princ " et Coude ")(princ (- 180 at))(princ "°")

       ))

(princ " Rayon ")(princ rayo)



       (if p1  (setq p0 (getpoint p1 "\nPoint suivant <Arret> : ")))

       (if p0

         (progn 

           (command "_line" "_non" p1 "_non" p0 "")

           (setq l10 (entlast) d10 (distance p1 p0) dp nil)

           (setq b (distance p0 pd))

           (deterdmin) 

           (onfekoi L01 L10 pd p1 p0 d01 d10) 

         ) 

       )

     )

     ;;; si p1 nil

     (progn

       (if (and l10 p0 ) (tubage l10 lg))   ;; si plusieurs boucles ;;;;;;; 

       (setq p0 nil )  

     )

   )   ;;;; fin if p1   

 )   ;;; fin while

 

 (cond ((and l01 p1)(tubage l01 lg)))     ;;;; termine dernier tronçon  

 (setvar "trimmode" mtrim)(setvar "cmdecho" 1)

 (cond (at (princ "\nAngle tuyauterie ")(princ at)(princ "°")

     (princ " et Coude ")(princ (- 180 at))(princ "°")

 ))

 (cond (rayo (princ " Rayon ")(princ rayo)))

 (gc)

 (prin1)

)



;;   pour raccorder 2 axes et tracer seulement l'axe du coude de tuy

(defun c:cd (/ lo lo2)   

  (diam-t3d)

 (setq mtrim (getvar "trimmode"))

 (setvar "FILLETRAD" rayo) (setvar "trimmode" 1)

 (setq lo (entlast))

 (command "_fillet")

 (while (not (zerop (getvar "cmdactive")))(command pause))

 (while (not (equal lo (setq lo2 (entlast))))

   (command "_fillet")

   (while (not (zerop (getvar "cmdactive")))(command pause)) 

   (setq lo lo2)

 )

 

 (setvar "trimmode" mtrim)

 (princ)

)


;;  pour raccorder 2 axes et tracer un coude de tuy sauf emboitements.

(defun c:cdt (/ lo )  

  (diam-t3d)

 (if (> epcalo 0)(creercalquecalo))

 (setq mtrim (getvar "trimmode"))

 (setvar "FILLETRAD" rayo) (setvar "trimmode" 1)

 (setq lo (entlast))

 (command "_fillet")

 (while (not (zerop (getvar "cmdactive")))(command pause))

 (cond 

   ((not (equal lo (setq coude (entlast))))

     (setq pt (trans (cdr (assoc 10 (entget coude))) 0 1))

     (generetube coude pt 1)

   )

 )

 (while (not (equal coude (setq lo (entlast))))

   (command "_fillet")

   (while (not (zerop (getvar "cmdactive")))(command pause))

   (cond ((not (equal lo (setq coude (entlast))))

       (setq pt (trans (cdr (assoc 10 (entget coude))) 0 1))

       (generetube coude pt 1)

     )

   )

 )

 (setvar "trimmode" mtrim)

 (princ)

)


;; Pour ne tracer que le calorige par sélection de l'axe ou par deux points

(defun c:calos (/ sel typent ent pt p1 p2 eptub axetemp rep)

  (diam-t3d)

 (while (or (>= 0 epcalo)(not epcalo))

   (setq epcalo (getdist "\nEpaisseur calorifuge ou 2 pts : "))

 )

 (creercalquecalo)

 (if(= tuy:ep nil) ; si utilisation avant  tuy

   (progn (initget "Creux Plein")

     (setq rep (getstring "\n Calo dessiné [<Plein>/Creux]:"))

     (if (or (= rep "")(= rep "Plein")) (setq tuy:ep 0.0) (setq tuy:ep -1))

   )

 )

 (setq sel t)

 (while sel

   (setq sel (entsel "\nSélectionner l'AXE du TUBE ou par < 2 Points> :"))

   (if  (not sel) 

     (progn (setq sel t)

       (setq p1 (getpoint  "\nPoint de départ <Arret> : "))

       (if p1 (setq p2 (getpoint p1 "\nPoint final <Arret> : ")))

       (if (and p1 p2)

         (progn

           (command "_line" "_non" p1 "_non" p2 "")

           (setq axetemp (entlast))(setq pt (trans (cdr (assoc 10 (entget axetemp))) 0 1))

           (if (or (= tuy:ep nil) (= tuy:ep 0.0))

             (caloplein axetemp pt )

             (calocreux axetemp pt )

           )

           (if (/= 2 (getvar "delobj"))(entdel axetemp))

         )

         (setq sel nil)

       ) 

     )

     

     (progn

       (setq typent (cdr (assoc 0 (entget (setq ent(car sel))))))

       (cond

         ((or (= typent "LINE")(= typent "ARC")(= typent "POLYLINE")(= typent "LWPOLYLINE") 

             (= typent "ELLIPSE")(= typent "CIRCLE")(= typent "SPLINE")(= typent "HELIX")

           )

           (setq pt (cadr sel))

           (if (or (= tuy:ep nil) (= tuy:ep 0.0))

             (progn 

               (if (> epcalo 0) (progn 

                   (if (= (cdr (assoc 0 (setq lent (entget ent)))) "ARC")

                     (if (> (cdr (assoc 40 lent)) (+ ddia epcalo))(caloplein ent pt))

                     (caloplein ent pt)

                   )        

                 )

               )     

             )

             (progn 

               (if (> epcalo 0) (progn 

                   (if (= (cdr (assoc 0 (setq lent (entget ent)))) "ARC")

                     (if (> (cdr (assoc 40 lent)) (+ ddia epcalo))(calocreux ent pt))

                     (calocreux ent pt)

                   )        

                 )

               )

             )      

           )             

         )

       )

     )

   )  ;; if

 )

 (gc)

 (princ)

)



;;; génère le tube à partir de l'axe sélectionné

(defun c:TU (/ sel typent ent pt eptub )

  (diam-t3d)

 (if (> epcalo 0)(creercalquecalo))

 (if (not tuy:ep) (setq tuy:ep 0))

 (initget "Epaisseur") 

 (while

   (setq sel (entsel (strcat "\nSélectionner l'AXE du TUBE ou Epaisseur,[Epaisseur] = "(rtos tuy:ep 2 4)" :"))) 

   (if (= sel "Epaisseur")

     (progn

       (setq eptub (getdist (strcat "\nEpaisseur tube ou 2 pts <" (rtos tuy:ep 2 4) ">: ")))

       (if eptub (if (< (abs eptub) ddia)(setq tuy:ep eptub)))

     ) 

     (progn

       (setq typent (cdr (assoc 0 (entget (setq ent(car sel))))))

       (cond

         ((or (= typent "LINE")(= typent "ARC")(= typent "POLYLINE")(= typent "LWPOLYLINE") 

             (= typent "ELLIPSE")(= typent "CIRCLE")(= typent "SPLINE")(= typent "HELIX")

           )

           (setq pt (cadr sel))

           (generetube ent pt nil)

         )

       )

     )

   )  ;; if

 ) (gc)

 (princ)

)


;;;;;;;;;;;;;;;;;;;;;;;

(defun erreurtuy (msg)

 (setvar "delobj" delobjet)

 (if (not (zerop (getvar "cmdactive")))(command))

 (setq *error* m:err m:err nil)

 (princ)

)


(defun c:tsa ()  ;; tuyau sans axe

 (setq m:err *error* *error* erreurtuy)

 (setq delobjet (getvar "delobj"))

 (setvar "delobj" 2)

 (tuy)

 (setvar "delobj" delobjet)

 (setq *error* m:err m:err nil)

 (princ)

)


(defun c:tuy ()

 (setq m:err *error* *error* erreurtuy)

 (setq delobjet (getvar "delobj"))

 (setvar "delobj" 1)

 (tuy)

 (setvar "delobj" delobjet)

 (setq *error* m:err m:err nil)

 (princ)

)


(defun c:tuycb (/ cdblc)

 (setq m:err *error* *error* erreurtuy)

 (setq delobjet (getvar "delobj"))

 (setvar "delobj" 1)

 (setq cdblc 1)

 (tuy)

 (setvar "delobj" delobjet)

 (setq *error* m:err m:err nil)

 (princ)

)


(defun c:tsacb (/ cdblc)

 (setq m:err *error* *error* erreurtuy)

 (setq delobjet (getvar "delobj"))

 (setvar "delobj" 2)

 (setq cdblc 1)

 (tuy)

 (setvar "delobj" delobjet)

 (setq *error* m:err m:err nil)

 (princ)

)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


(prompt "\nCMD dispo: TUY ,TSA ,TU ,CD, CDT, CALOS ou avec bloc TUYCB, TSACB, TUB, CDB")

(princ)


<font class=edite>[Edité le 12/6/2011 par usegomme]</font><font class=edite>[Edité le 26/6/2011 par usegomme]</font><font class=edite>[Edité le 1/7/2011 par usegomme]</font><font class=edite>[Edité le 2/7/2011 par usegomme]</font><font class=edite>[Edité le 6/7/2011 par usegomme]</font>

 

<font class=edite>[Edité le 29/8/2011 par usegomme]</font>

Lien vers le commentaire
Partager sur d’autres sites

  • 2 semaines après...

Salut , j'ai remplacé le code au-dessus par la version 4.1 qui prend en compte dans les attributs des coudes en blocs, l' épaisseur et la matière si elles sont renseignées

Si on ne veut l'épaisseur que dans les attributs et pas dans le dessin, il faut la renseigner avec le signe "-" devant.

Les options sont accessibles au moment de la sélection des axes.

Lien vers le commentaire
Partager sur d’autres sites

Bonjour usegomme

 

Peux tu definir la longueur des manchettes un peu comme avec patrick et son lisp ins3d?

definir en fonction du DN la correspondance en pouce et l'integrer dans les attributs !

ceci pourrait etre super pour etablir un chiffrage.

derriere tout ca le but final serait de pouvoir extraire les attributs dans une nomenclature pour d'une part les matieres et de l'autre le nombre total de pouce multiplier par un coef de difficultées permettrait d'avoir la main d'oeuvre la je pense que tu aurais un outil tres interessant.

A ton lisp j'ai associer des boutons,pour le tube le coude la reduction les brides,ainsi que ma bibliotheque 3D vannes pompes ect.........

pour la creation de nomenclature je maitrise!

mais je suis malheureusement zeros en lisp

alors ton aide et comme d'hab la bien venu

 

 

Diamétre Pouce

Ø 13 1/8

Ø 17,1 1/4

Ø 21,3 1/2

Ø 26,9 3/4

Ø 33,7 1

Ø 42,4 1 1/4

Ø 48,3 1 1/2

Ø 60,3 2

Ø 76,1 2 1/2

Ø 88,9 3

Ø 114,3 4

Ø 139,7 5

Ø 168,3 6

Ø 219,1 8

Ø 273 10

Ø 323,9 12

Ø 355,6 14

Ø 406,4 16

Ø 457,2 18

Ø 508 20

Ø 608 24

Ø 708 28

Ø 808 32

Ø 914,4 36

Ø 1016 40

 

chaque soudure correspond a un nombre de pouce en fonction du diametre.

 

 

 

 

Lien vers le commentaire
Partager sur d’autres sites

Salut Philou

Oui , je pense à faire aussi les tubes en blocs , dans quelques temps ça devrait sortir, mais bon pas d'impatience , je n'ai pas trop le temps de lisper et je ne suis loin d'être un as ce qui ne m'arrange pas.

Ceci mis à part les pouces que tu indiques sont ceux des diamètres et pas ceux des longueurs de soudure correspondante . Est-ce bien ce que tu veux ?

Lien vers le commentaire
Partager sur d’autres sites

Bonsoir usegomme

 

Pour le chiffrage on calcul le nombre de soudure par tube!

 

exemple

 

un tube en dn25 avec 4 soudures

 

4 x 1" =4" X par un coef (0,7 à 1,3 ) donne un temps prenons le cas simple 0,7

4 X 0.7= 2.8h est le temps de réalisation et pose de cette tuyauterie

multiplié par le tarif horaire te donne un prix main d'oeuvre!!

 

Lien vers le commentaire
Partager sur d’autres sites

Salut Philou et les autres amateurs de tuyaux

j'ai remplacé le code au dessus par la version 5 qui peut faire aussi les tubes droits en bloc.

Avec ces blocs "tube" on peut utiliser les lisp de (gile) stretchins et editlen puisque leur longueur = echelle axe X du bloc.

Je n'ai pas pu mettre tous les diamètres de tube que tu m'as indiqué car il me manque certains rayon de coude.

Bien que j 'y ai passé un temps certain , il y a des choses à améliorer et probablement des bugs à corriger.

Je te ( vous) laisse continuer les tests et faire les commentaires, pour l'instant j'ai ma dose, mais je suis content d'être arrivé à quelques choses de pas trop mal.

A+

Lien vers le commentaire
Partager sur d’autres sites

Salut , pour l'instant je n'arrive pas à reproduire le bug avec autocad 2008.

J'ai trouvé cette erreur :

(defun c:TUB (/ sel typent ent ent1 pt eptub pouce lga px p1 atdia epc tub1

Supprime pouce dans la ligne ci-dessus.

Aprés avoir fait fonctionner le lisp, tape sur la ligne de commande !pouce

La valeur de la variable doit s'afficher et ne pas être nil.

Si cela persiste donne moi le plus de détails possible.

Il arrive que les lisp foire lorsque la mémoire qui leur est aloué est pleine aprés de nombreux tests par exemple.

Lien vers le commentaire
Partager sur d’autres sites

  • 2 mois après...

Un seul détail me "gêne" : je n'ai pas trouvé comment modifier les axes des tuyaux.

Il faut apprendre à lire ... le lisp.

 

Dans

(defun TUY

tu trouveras

;(creercalqueaxe ) pas utilisé

qu'il faut remplacer par:

(creercalqueaxe )

 

dans

(defun creercalqueAXE

tu trouveras

(command "_-layer" "_n" calqax "_co" "6" calqax "_lt" "axes2" calqax "")

remplace le 6 par un 7 pour la couleur blanche

 

ensuite il faut renommer la fonction

(defun tubage

en

(defun tubage-old 

par exemple

et la fonction

(defun tubage1

en

(defun tubage

pour la rendre active

 

si tu tiens à n'avoir qu' un seul calque AXES

dans

(defun creercalqueAXE

il faut remplacer

(setq calqax (strcat (getvar "clayer") "-AXE"))

par

(setq calqax "AXES")

 

Voilà ça devrait faire ton affaire ( je n'ai pas refait de test).

Lien vers le commentaire
Partager sur d’autres sites

  • 1 an après...

Bonjour,

 

J'essai en vain de comprendre le fonctionnement du Lisp au niveau de la

définition des cotes de la rubrique PVC-ECOUL, j'aimerais l'adapter pour

creer un routage autre (cuivre), pourquoi le PVC-ECOUL ? bah en fait c'est

parcequ'au niveau de la forme de coude générée (coude + manchon), c'est celle qui se rapproche le plus

de la forme des coudes cuivres. J'ai reussi à rajouter une rubrique CUIVRE-PR pour cuivre petit rayon, mais

je coince au niveau du renseignement des dimensions des coudes, pourquoi L87 puisqu'une fois le coude généré c'est 90°, ou retrouve t'on la cote (sur le coude dessiné) qui est juste après L45 (210) sur le coude à 45°, j'ai essayé de prendre plusieurs cotes sur le coude (à 45°) pour la retrouvé et du coup comprendre la relation de cause à effet entre ces lignes du lisp et la génération du coude mais je n'ai pas trouvé.

 

Comment lis t'on c'est quelques lignes, et du coup pouvoir les modifier et les adapter?

 

******************************************

((= dn 315) (setq diam dn L87 309 L45 210 emboit 124))

 

(t (autrediametre) )

 

)

 

(setq L90 (/ (- (* L87 45)(* L45 2.5)) 42.5)) ;; 90-87.5=2.5 et 45-2.5=42.5

 

(setq rayo (- L90 emboit) epemboit 2 epcd 0 ecart 5)

******************************************

 

Dans tout les cas le lisp fonctionne super bien, super boulot.

 

merci

 

mikL

 

http://img4.hostingpics.net/pics/212079cuivre.png

Lien vers le commentaire
Partager sur d’autres sites

Bonjour,

En fait c'est simple, mais tu as pris le modèle le plus compliqué.

((= dn 315) (setq diam dn L87 309 L45 210 emboit 124))

 

setq diam dn -> le diamètre est égal à la valeur DN (en mm) car c'est du PVC d'écoulement

L87 309 -> 309 c'est la longueur totale du coude pour un angle de 87°

ET OUI! Car en écoulement, il y a des pentes et les coudes PVC ne sont pas à 90°

Dans ton cas remplace L87 par L90, fait la comparaison avec les autres types de tube emboité.

 

L45 210 -> 210 c'est la longueur totale du coude pour un angle de 45° (du point d'épure à l'extrémité)

Pour les valeurs angulaires intermédiaire la longueur est recalculée proportionnellement à l'angle pour l'aspect visuel.

Sauf si des valeurs sont indiquées comme ici

((= dn 40) (setq diam dn L87 58 L45 40 L30 38 L20 33.5 emboit 27))

 

emboit 124 -> c'est la longueur de la partie droite du coude

 

 

(setq L90 (/ (- (* L87 45)(* L45 2.5)) 42.5))

Ce calcul de L90 ne te sert à rien, si tu modifies comme indiqué plus haut.

 

(setq rayo (- L90 emboit) epemboit 2 epcd 0 ecart 5)

 

(setq rayo (- L90 emboit) -> rayon du coude non donné sur catalogue = longueur - emboitement

 

epemboit 2 -> surépaisseur de la longueur droite par rapport au diamètre du tuyau

 

epcd 0 -> surépaisseur du coude par rapport au diamètre du tuyau

 

ecart 5 -> distance mini entre deux coudes pour la correction automatique.

 

Voilà, j'espère que c'est clair.

Lien vers le commentaire
Partager sur d’autres sites

Bonsoir,

 

Tout d'abord merci pour les infos, ca m'a permis de mieux comprendre.

Sinon j'ai modifié le lisp comme suit pour tester :

 

	((= dn 315) (setq diam dn L90 309 L45 210 emboit 124))
       (t  (autrediametre) )
     )  
     ;;;(setq L90 (/ (- (* L87 45)(* L45 2.5)) 42.5)) ;; 90-87.5=2.5 et 45-2.5=42.5
     (setq rayo (- L90 emboit) epemboit 2 epcd 0 ecart 5)
     ;;; ecart = ecartement mini entre 2 embouts de coude

 

Donc les 309 sont bien la, pas de soucis, par contre ca se gate quand je lui demande

les 210, j'obtiens 219 comme sur l'image ci dessous, c'est quoi les 9mm d'écart, je vois

pas du tout d'ou ils viennent ceux la ??

 

http://img15.hostingpics.net/pics/221690cui.jpg

 

merci

A+

mikL

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité