Aller au contenu

cotation en pourcentage


bekibo

Messages recommandés

Alors là c'est facile :

dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.

Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.

 

 

[Edité le 8/6/2009 par Tramber]

Bureau d'études dessin.

Spécialiste Escaliers

Développement - Formation

 

./__\.
(.°=°.)
Lien vers le commentaire
Partager sur d’autres sites

BonjouTrambler,

 

j'ai effectivement appliqué un coeff pour transposer mes angles, mais je n'arrive toujours pas à indiquer sur le plan la pente en pourcentage; sinon, il faut que je l'écrive en format texte.

Lien vers le commentaire
Partager sur d’autres sites

Alors là c'est facile :

dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.

Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.

 

:casstet: Là, j'ai un doute...

 

Le "gradian" (il me semble qu'on parle plutôt de grade en français, encore une traduction "autodeskienne"....) est une unité angulaire comme le degré ou le radian.

L'expression d'une pente (angle) en pourcentage correspond à la tangente de l'angle multipliée par 100 (autrment dit : le rapport entre le dénivelé et la distance horizontale).

 

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.

 

Je ne connais pas d'autre moyen que de forcer la cote pour faire ce que bekibo demande.

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
ADSK_Expert_Elite_Icon_S_Color_Blk_125.png

Lien vers le commentaire
Partager sur d’autres sites

Bonjour à toutes et tous,

 

Entièrement d'accord avec (gile),

 

50 grades

 

Encore écris => 50 gon ou 50 gons dans le domaine de la topographie (symbole gon gônia : angle, en grec) )

 

Mais, on peut aussi appeler cette mesure angulaire "Gradian", bof ! :o

Civil 3D 2024 - COVADIS_18.2

https://www.linkedin...3%ABt-95313341/

Lien vers le commentaire
Partager sur d’autres sites

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.

 

Ok, mais il est clair que le gradian et la valeur de pente n'ont rien à voir sauf peut-être dans ce cas précis. Mais tout le monde sait que TAN 45 =1 ! Cas exceptionnel.

 

[Edité le 8/6/2009 par Tramber]

Bureau d'études dessin.

Spécialiste Escaliers

Développement - Formation

 

./__\.
(.°=°.)
Lien vers le commentaire
Partager sur d’autres sites

Oui, à moins d'un programme qui pourrait la forcer à ta place et faire la convertion en valeur de pente. Ceci dit, il me parait génant de coter une pente en % sur la base d'une cotation d'angle. D'ordinaire, c'est un texte écrit le long de la pente.

 

Veux-tu faire un programme Autolisp ?

Bureau d'études dessin.

Spécialiste Escaliers

Développement - Formation

 

./__\.
(.°=°.)
Lien vers le commentaire
Partager sur d’autres sites

(defun c:cot%()
 (vl-load-com)
 (setq vlcot(vlax-ename->vla-object(car(entsel))))
 (vla-put-TextOverride vlcot
   (strcat"Pente à"(rtos(* 100(/(sin(vla-get-Measurement vlcot))(cos(vla-get-Measurement vlcot))))2 2)"%"))
 )

 

Enregistre ce texte dans un fichier *.lsp puis charge le (glisser-déposer suffit)

 

Lance la commande COT% et dis-nous déjà si tu veux une amélio. Le principe est simple, au choix des objets, tu cliques une cotation d'angle.

 

A toi de vérifier la formule math par les résultats.

Bureau d'études dessin.

Spécialiste Escaliers

Développement - Formation

 

./__\.
(.°=°.)
Lien vers le commentaire
Partager sur d’autres sites

Un autre qui crée un objet texte le long de la pente.

Il suffit de cliquer 2 points.

 

(defun c:pente% (/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint "\nPremier point: "))
     (setq p2 (getpoint "\nDeuxième point: "))
     (setq a (angle p1 p2))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (if (minusp (cos a))
	 (+ pi a)
	 a
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))
 '(73 . 1)
      )
    )
 )
 (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
ADSK_Expert_Elite_Icon_S_Color_Blk_125.png

Lien vers le commentaire
Partager sur d’autres sites

test.LSP, par exemple !

 

Au glisser-déposer, tu devrais avoir une confirmation de chargement.

 

NB : tu peux ajouter le code de (gile) à ce fichier et aussi lancer PENTE%.

 

Mais d'abord, essaie de nous charger ce fichier, ca va marcher. (gile va te donner un lien pour son cours sur les chargments de programmes, n'est-ce pas (gile) ?)

Bureau d'études dessin.

Spécialiste Escaliers

Développement - Formation

 

./__\.
(.°=°.)
Lien vers le commentaire
Partager sur d’autres sites

(gile) s'ennuie tellement qu'il fait du ENTMAKE !

 

J'aime bien entmake, si on veux ensuite changer/ajouter certaines propriétés, il suffit de modifier/ajouter une entrée dans la liste ;)

 

bekibo,

tu trouveras sur cette page les explications concernant le chargement et l'exécution des LISP.

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
ADSK_Expert_Elite_Icon_S_Color_Blk_125.png

Lien vers le commentaire
Partager sur d’autres sites

  • 1 an après...

Salut

 

Effectivement.

Voilà deux autres versions qui ne fonctionnent qu'en 2d (plan XY du SCU courant parallèle au plan du SCG).

 

La première mesure la pente par rapport à l'axe X du SCU courant :

(defun c:pente% (/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint  "\nPremier point: "))
     (setq p2 (getpoint p1 "\nDeuxième point: "))
     (setq a (angle p1 p2))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (+ (angle '(0. 0. 0.) (getvar 'ucsxdir))
	  (if (minusp (cos a))
	    (+ pi a)
	    a
	  )
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) (trans p1 1 0) (trans p2 1 0)))
 '(73 . 1)
      )
    )
 )
 (princ)
)

 

La seconde mesure la pente par rapport au SCG mais fonctionne quelque soit le SCU courant :

(defun c:pente%	(/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint "\nPremier point: "))
     (setq p2 (getpoint p1 "\nDeuxième point: "))
     (setq a (angle (setq p1 (trans p1 1 0)) (setq p2 (trans p2 1 0))))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (if (minusp (cos a))
	 (+ pi a)
	 a
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))
 '(73 . 1)
      )
    )
 )
 (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
ADSK_Expert_Elite_Icon_S_Color_Blk_125.png

Lien vers le commentaire
Partager sur d’autres sites

  • 4 ans après...

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité